diff options
author | Richard Purdie <richard.purdie@linuxfoundation.org> | 2022-08-10 14:35:29 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2022-08-12 15:27:17 +0100 |
commit | fd1517e2b51a170f2427122c6b95396db251d827 (patch) | |
tree | dabfe3e631339c2fc99a9ee7febb0f9c128e325e /meta/classes/image_types.bbclass | |
parent | 10317912ee319ccf7f83605d438b5cbf9663f296 (diff) | |
download | poky-fd1517e2b51a170f2427122c6b95396db251d827.tar.gz |
classes: Update classes to match new bitbake class scope functionality
Move classes to classes-global or classes-recipe as appropriate to take
advantage of new bitbake functionality to check class scope/usage.
(From OE-Core rev: f5c128008365e141082c129417eb72d2751e8045)
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/classes/image_types.bbclass')
-rw-r--r-- | meta/classes/image_types.bbclass | 355 |
1 files changed, 0 insertions, 355 deletions
diff --git a/meta/classes/image_types.bbclass b/meta/classes/image_types.bbclass deleted file mode 100644 index a731e585b2..0000000000 --- a/meta/classes/image_types.bbclass +++ /dev/null | |||
@@ -1,355 +0,0 @@ | |||
1 | # | ||
2 | # Copyright OpenEmbedded Contributors | ||
3 | # | ||
4 | # SPDX-License-Identifier: MIT | ||
5 | # | ||
6 | |||
7 | # The default aligment of the size of the rootfs is set to 1KiB. In case | ||
8 | # you're using the SD card emulation of a QEMU system simulator you may | ||
9 | # set this value to 2048 (2MiB alignment). | ||
10 | IMAGE_ROOTFS_ALIGNMENT ?= "1" | ||
11 | |||
12 | def imagetypes_getdepends(d): | ||
13 | def adddep(depstr, deps): | ||
14 | for d in (depstr or "").split(): | ||
15 | # Add task dependency if not already present | ||
16 | if ":" not in d: | ||
17 | d += ":do_populate_sysroot" | ||
18 | deps.add(d) | ||
19 | |||
20 | # Take a type in the form of foo.bar.car and split it into the items | ||
21 | # needed for the image deps "foo", and the conversion deps ["bar", "car"] | ||
22 | def split_types(typestring): | ||
23 | types = typestring.split(".") | ||
24 | return types[0], types[1:] | ||
25 | |||
26 | fstypes = set((d.getVar('IMAGE_FSTYPES') or "").split()) | ||
27 | fstypes |= set((d.getVar('IMAGE_FSTYPES_DEBUGFS') or "").split()) | ||
28 | |||
29 | deprecated = set() | ||
30 | deps = set() | ||
31 | for typestring in fstypes: | ||
32 | basetype, resttypes = split_types(typestring) | ||
33 | |||
34 | var = "IMAGE_DEPENDS_%s" % basetype | ||
35 | if d.getVar(var) is not None: | ||
36 | deprecated.add(var) | ||
37 | |||
38 | for typedepends in (d.getVar("IMAGE_TYPEDEP:%s" % basetype) or "").split(): | ||
39 | base, rest = split_types(typedepends) | ||
40 | resttypes += rest | ||
41 | |||
42 | var = "IMAGE_DEPENDS_%s" % base | ||
43 | if d.getVar(var) is not None: | ||
44 | deprecated.add(var) | ||
45 | |||
46 | for ctype in resttypes: | ||
47 | adddep(d.getVar("CONVERSION_DEPENDS_%s" % ctype), deps) | ||
48 | adddep(d.getVar("COMPRESS_DEPENDS_%s" % ctype), deps) | ||
49 | |||
50 | if deprecated: | ||
51 | bb.fatal('Deprecated variable(s) found: "%s". ' | ||
52 | 'Use do_image_<type>[depends] += "<recipe>:<task>" instead' % ', '.join(deprecated)) | ||
53 | |||
54 | # Sort the set so that ordering is consistant | ||
55 | return " ".join(sorted(deps)) | ||
56 | |||
57 | XZ_COMPRESSION_LEVEL ?= "-9" | ||
58 | XZ_INTEGRITY_CHECK ?= "crc32" | ||
59 | |||
60 | ZIP_COMPRESSION_LEVEL ?= "-9" | ||
61 | |||
62 | ZSTD_COMPRESSION_LEVEL ?= "-3" | ||
63 | |||
64 | JFFS2_SUM_EXTRA_ARGS ?= "" | ||
65 | IMAGE_CMD:jffs2 = "mkfs.jffs2 --root=${IMAGE_ROOTFS} --faketime --output=${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.jffs2 ${EXTRA_IMAGECMD}" | ||
66 | |||
67 | IMAGE_CMD:cramfs = "mkfs.cramfs ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.cramfs ${EXTRA_IMAGECMD}" | ||
68 | |||
69 | oe_mkext234fs () { | ||
70 | fstype=$1 | ||
71 | extra_imagecmd="" | ||
72 | |||
73 | if [ $# -gt 1 ]; then | ||
74 | shift | ||
75 | extra_imagecmd=$@ | ||
76 | fi | ||
77 | |||
78 | # If generating an empty image the size of the sparse block should be large | ||
79 | # enough to allocate an ext4 filesystem using 4096 bytes per inode, this is | ||
80 | # about 60K, so dd needs a minimum count of 60, with bs=1024 (bytes per IO) | ||
81 | eval local COUNT=\"0\" | ||
82 | eval local MIN_COUNT=\"60\" | ||
83 | if [ $ROOTFS_SIZE -lt $MIN_COUNT ]; then | ||
84 | eval COUNT=\"$MIN_COUNT\" | ||
85 | fi | ||
86 | # Create a sparse image block | ||
87 | bbdebug 1 Executing "dd if=/dev/zero of=${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.$fstype seek=$ROOTFS_SIZE count=$COUNT bs=1024" | ||
88 | dd if=/dev/zero of=${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.$fstype seek=$ROOTFS_SIZE count=$COUNT bs=1024 | ||
89 | bbdebug 1 "Actual Rootfs size: `du -s ${IMAGE_ROOTFS}`" | ||
90 | bbdebug 1 "Actual Partition size: `stat -c '%s' ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.$fstype`" | ||
91 | bbdebug 1 Executing "mkfs.$fstype -F $extra_imagecmd ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.$fstype -d ${IMAGE_ROOTFS}" | ||
92 | mkfs.$fstype -F $extra_imagecmd ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.$fstype -d ${IMAGE_ROOTFS} | ||
93 | # Error codes 0-3 indicate successfull operation of fsck (no errors or errors corrected) | ||
94 | fsck.$fstype -pvfD ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.$fstype || [ $? -le 3 ] | ||
95 | } | ||
96 | |||
97 | IMAGE_CMD:ext2 = "oe_mkext234fs ext2 ${EXTRA_IMAGECMD}" | ||
98 | IMAGE_CMD:ext3 = "oe_mkext234fs ext3 ${EXTRA_IMAGECMD}" | ||
99 | IMAGE_CMD:ext4 = "oe_mkext234fs ext4 ${EXTRA_IMAGECMD}" | ||
100 | |||
101 | MIN_BTRFS_SIZE ?= "16384" | ||
102 | IMAGE_CMD:btrfs () { | ||
103 | size=${ROOTFS_SIZE} | ||
104 | if [ ${size} -lt ${MIN_BTRFS_SIZE} ] ; then | ||
105 | size=${MIN_BTRFS_SIZE} | ||
106 | bbwarn "Rootfs size is too small for BTRFS. Filesystem will be extended to ${size}K" | ||
107 | fi | ||
108 | dd if=/dev/zero of=${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.btrfs seek=${size} count=0 bs=1024 | ||
109 | mkfs.btrfs ${EXTRA_IMAGECMD} -r ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.btrfs | ||
110 | } | ||
111 | |||
112 | IMAGE_CMD:squashfs = "mksquashfs ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.squashfs ${EXTRA_IMAGECMD} -noappend" | ||
113 | IMAGE_CMD:squashfs-xz = "mksquashfs ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.squashfs-xz ${EXTRA_IMAGECMD} -noappend -comp xz" | ||
114 | IMAGE_CMD:squashfs-lzo = "mksquashfs ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.squashfs-lzo ${EXTRA_IMAGECMD} -noappend -comp lzo" | ||
115 | IMAGE_CMD:squashfs-lz4 = "mksquashfs ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.squashfs-lz4 ${EXTRA_IMAGECMD} -noappend -comp lz4" | ||
116 | IMAGE_CMD:squashfs-zst = "mksquashfs ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.squashfs-zst ${EXTRA_IMAGECMD} -noappend -comp zstd" | ||
117 | |||
118 | IMAGE_CMD:erofs = "mkfs.erofs ${EXTRA_IMAGECMD} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.erofs ${IMAGE_ROOTFS}" | ||
119 | IMAGE_CMD:erofs-lz4 = "mkfs.erofs -zlz4 ${EXTRA_IMAGECMD} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.erofs-lz4 ${IMAGE_ROOTFS}" | ||
120 | IMAGE_CMD:erofs-lz4hc = "mkfs.erofs -zlz4hc ${EXTRA_IMAGECMD} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.erofs-lz4hc ${IMAGE_ROOTFS}" | ||
121 | |||
122 | |||
123 | IMAGE_CMD_TAR ?= "tar" | ||
124 | # ignore return code 1 "file changed as we read it" as other tasks(e.g. do_image_wic) may be hardlinking rootfs | ||
125 | IMAGE_CMD:tar = "${IMAGE_CMD_TAR} --sort=name --format=posix --numeric-owner -cf ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.tar -C ${IMAGE_ROOTFS} . || [ $? -eq 1 ]" | ||
126 | |||
127 | do_image_cpio[cleandirs] += "${WORKDIR}/cpio_append" | ||
128 | IMAGE_CMD:cpio () { | ||
129 | (cd ${IMAGE_ROOTFS} && find . | sort | cpio --reproducible -o -H newc >${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.cpio) | ||
130 | # We only need the /init symlink if we're building the real | ||
131 | # image. The -dbg image doesn't need it! By being clever | ||
132 | # about this we also avoid 'touch' below failing, as it | ||
133 | # might be trying to touch /sbin/init on the host since both | ||
134 | # the normal and the -dbg image share the same WORKDIR | ||
135 | if [ "${IMAGE_BUILDING_DEBUGFS}" != "true" ]; then | ||
136 | if [ ! -L ${IMAGE_ROOTFS}/init ] && [ ! -e ${IMAGE_ROOTFS}/init ]; then | ||
137 | if [ -L ${IMAGE_ROOTFS}/sbin/init ] || [ -e ${IMAGE_ROOTFS}/sbin/init ]; then | ||
138 | ln -sf /sbin/init ${WORKDIR}/cpio_append/init | ||
139 | else | ||
140 | touch ${WORKDIR}/cpio_append/init | ||
141 | fi | ||
142 | (cd ${WORKDIR}/cpio_append && echo ./init | cpio -oA -H newc -F ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.cpio) | ||
143 | fi | ||
144 | fi | ||
145 | } | ||
146 | |||
147 | UBI_VOLNAME ?= "${MACHINE}-rootfs" | ||
148 | UBI_VOLTYPE ?= "dynamic" | ||
149 | UBI_IMGTYPE ?= "ubifs" | ||
150 | |||
151 | write_ubi_config() { | ||
152 | if [ -z "$1" ]; then | ||
153 | local vname="" | ||
154 | else | ||
155 | local vname="_$1" | ||
156 | fi | ||
157 | |||
158 | cat <<EOF > ubinize${vname}-${IMAGE_NAME}.cfg | ||
159 | [ubifs] | ||
160 | mode=ubi | ||
161 | image=${IMGDEPLOYDIR}/${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.${UBI_IMGTYPE} | ||
162 | vol_id=0 | ||
163 | vol_type=${UBI_VOLTYPE} | ||
164 | vol_name=${UBI_VOLNAME} | ||
165 | vol_flags=autoresize | ||
166 | EOF | ||
167 | } | ||
168 | |||
169 | multiubi_mkfs() { | ||
170 | local mkubifs_args="$1" | ||
171 | local ubinize_args="$2" | ||
172 | |||
173 | # Added prompt error message for ubi and ubifs image creation. | ||
174 | if [ -z "$mkubifs_args" ] || [ -z "$ubinize_args" ]; then | ||
175 | bbfatal "MKUBIFS_ARGS and UBINIZE_ARGS have to be set, see http://www.linux-mtd.infradead.org/faq/ubifs.html for details" | ||
176 | fi | ||
177 | |||
178 | write_ubi_config "$3" | ||
179 | |||
180 | if [ -n "$vname" ]; then | ||
181 | mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${IMGDEPLOYDIR}/${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.ubifs ${mkubifs_args} | ||
182 | fi | ||
183 | ubinize -o ${IMGDEPLOYDIR}/${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.ubi ${ubinize_args} ubinize${vname}-${IMAGE_NAME}.cfg | ||
184 | |||
185 | # Cleanup cfg file | ||
186 | mv ubinize${vname}-${IMAGE_NAME}.cfg ${IMGDEPLOYDIR}/ | ||
187 | |||
188 | # Create own symlinks for 'named' volumes | ||
189 | if [ -n "$vname" ]; then | ||
190 | cd ${IMGDEPLOYDIR} | ||
191 | if [ -e ${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.ubifs ]; then | ||
192 | ln -sf ${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.ubifs \ | ||
193 | ${IMAGE_LINK_NAME}${vname}.ubifs | ||
194 | fi | ||
195 | if [ -e ${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.ubi ]; then | ||
196 | ln -sf ${IMAGE_NAME}${vname}${IMAGE_NAME_SUFFIX}.ubi \ | ||
197 | ${IMAGE_LINK_NAME}${vname}.ubi | ||
198 | fi | ||
199 | cd - | ||
200 | fi | ||
201 | } | ||
202 | |||
203 | IMAGE_CMD:multiubi () { | ||
204 | # Split MKUBIFS_ARGS_<name> and UBINIZE_ARGS_<name> | ||
205 | for name in ${MULTIUBI_BUILD}; do | ||
206 | eval local mkubifs_args=\"\$MKUBIFS_ARGS_${name}\" | ||
207 | eval local ubinize_args=\"\$UBINIZE_ARGS_${name}\" | ||
208 | |||
209 | multiubi_mkfs "${mkubifs_args}" "${ubinize_args}" "${name}" | ||
210 | done | ||
211 | } | ||
212 | |||
213 | IMAGE_CMD:ubi () { | ||
214 | multiubi_mkfs "${MKUBIFS_ARGS}" "${UBINIZE_ARGS}" | ||
215 | } | ||
216 | IMAGE_TYPEDEP:ubi = "${UBI_IMGTYPE}" | ||
217 | |||
218 | IMAGE_CMD:ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.ubifs ${MKUBIFS_ARGS}" | ||
219 | |||
220 | MIN_F2FS_SIZE ?= "524288" | ||
221 | IMAGE_CMD:f2fs () { | ||
222 | # We need to add additional smarts here form devices smaller than 1.5G | ||
223 | # Need to scale appropriately between 40M -> 1.5G as the "overprovision | ||
224 | # ratio" goes down as the device gets bigger (70% -> 4.5%), below about | ||
225 | # 500M the standard IMAGE_OVERHEAD_FACTOR does not work, so add additional | ||
226 | # space here when under 500M | ||
227 | size=${ROOTFS_SIZE} | ||
228 | if [ ${size} -lt ${MIN_F2FS_SIZE} ] ; then | ||
229 | size=${MIN_F2FS_SIZE} | ||
230 | bbwarn "Rootfs size is too small for F2FS. Filesystem will be extended to ${size}K" | ||
231 | fi | ||
232 | dd if=/dev/zero of=${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.f2fs seek=${size} count=0 bs=1024 | ||
233 | mkfs.f2fs ${EXTRA_IMAGECMD} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.f2fs | ||
234 | sload.f2fs -f ${IMAGE_ROOTFS} ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.f2fs | ||
235 | } | ||
236 | |||
237 | EXTRA_IMAGECMD = "" | ||
238 | |||
239 | inherit siteinfo kernel-arch image-artifact-names | ||
240 | |||
241 | JFFS2_ENDIANNESS ?= "${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', '-l', '-b', d)}" | ||
242 | JFFS2_ERASEBLOCK ?= "0x40000" | ||
243 | EXTRA_IMAGECMD:jffs2 ?= "--pad ${JFFS2_ENDIANNESS} --eraseblock=${JFFS2_ERASEBLOCK} --no-cleanmarkers" | ||
244 | |||
245 | # Change these if you want default mkfs behavior (i.e. create minimal inode number) | ||
246 | EXTRA_IMAGECMD:ext2 ?= "-i 4096" | ||
247 | EXTRA_IMAGECMD:ext3 ?= "-i 4096" | ||
248 | EXTRA_IMAGECMD:ext4 ?= "-i 4096" | ||
249 | EXTRA_IMAGECMD:btrfs ?= "-n 4096 --shrink" | ||
250 | EXTRA_IMAGECMD:f2fs ?= "" | ||
251 | |||
252 | do_image_cpio[depends] += "cpio-native:do_populate_sysroot" | ||
253 | do_image_jffs2[depends] += "mtd-utils-native:do_populate_sysroot" | ||
254 | do_image_cramfs[depends] += "util-linux-native:do_populate_sysroot" | ||
255 | do_image_ext2[depends] += "e2fsprogs-native:do_populate_sysroot" | ||
256 | do_image_ext3[depends] += "e2fsprogs-native:do_populate_sysroot" | ||
257 | do_image_ext4[depends] += "e2fsprogs-native:do_populate_sysroot" | ||
258 | do_image_btrfs[depends] += "btrfs-tools-native:do_populate_sysroot" | ||
259 | do_image_squashfs[depends] += "squashfs-tools-native:do_populate_sysroot" | ||
260 | do_image_squashfs_xz[depends] += "squashfs-tools-native:do_populate_sysroot" | ||
261 | do_image_squashfs_lzo[depends] += "squashfs-tools-native:do_populate_sysroot" | ||
262 | do_image_squashfs_lz4[depends] += "squashfs-tools-native:do_populate_sysroot" | ||
263 | do_image_squashfs_zst[depends] += "squashfs-tools-native:do_populate_sysroot" | ||
264 | do_image_ubi[depends] += "mtd-utils-native:do_populate_sysroot" | ||
265 | do_image_ubifs[depends] += "mtd-utils-native:do_populate_sysroot" | ||
266 | do_image_multiubi[depends] += "mtd-utils-native:do_populate_sysroot" | ||
267 | do_image_f2fs[depends] += "f2fs-tools-native:do_populate_sysroot" | ||
268 | do_image_erofs[depends] += "erofs-utils-native:do_populate_sysroot" | ||
269 | do_image_erofs_lz4[depends] += "erofs-utils-native:do_populate_sysroot" | ||
270 | do_image_erofs_lz4hc[depends] += "erofs-utils-native:do_populate_sysroot" | ||
271 | |||
272 | # This variable is available to request which values are suitable for IMAGE_FSTYPES | ||
273 | IMAGE_TYPES = " \ | ||
274 | jffs2 jffs2.sum \ | ||
275 | cramfs \ | ||
276 | ext2 ext2.gz ext2.bz2 ext2.lzma \ | ||
277 | ext3 ext3.gz \ | ||
278 | ext4 ext4.gz \ | ||
279 | btrfs \ | ||
280 | squashfs squashfs-xz squashfs-lzo squashfs-lz4 squashfs-zst \ | ||
281 | ubi ubifs multiubi \ | ||
282 | tar tar.gz tar.bz2 tar.xz tar.lz4 tar.zst \ | ||
283 | cpio cpio.gz cpio.xz cpio.lzma cpio.lz4 cpio.zst \ | ||
284 | wic wic.gz wic.bz2 wic.lzma wic.zst \ | ||
285 | container \ | ||
286 | f2fs \ | ||
287 | erofs erofs-lz4 erofs-lz4hc \ | ||
288 | " | ||
289 | # These image types are x86 specific as they need syslinux | ||
290 | IMAGE_TYPES:append:x86 = " hddimg iso" | ||
291 | IMAGE_TYPES:append:x86-64 = " hddimg iso" | ||
292 | |||
293 | # Compression is a special case of conversion. The old variable | ||
294 | # names are still supported for backward-compatibility. When defining | ||
295 | # new compression or conversion commands, use CONVERSIONTYPES and | ||
296 | # CONVERSION_CMD/DEPENDS. | ||
297 | COMPRESSIONTYPES ?= "" | ||
298 | |||
299 | CONVERSIONTYPES = "gz bz2 lzma xz lz4 lzo zip zst sum md5sum sha1sum sha224sum sha256sum sha384sum sha512sum bmap u-boot vmdk vhd vhdx vdi qcow2 base64 gzsync zsync ${COMPRESSIONTYPES}" | ||
300 | CONVERSION_CMD:lzma = "lzma -k -f -7 ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}" | ||
301 | CONVERSION_CMD:gz = "gzip -f -9 -n -c --rsyncable ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.gz" | ||
302 | CONVERSION_CMD:bz2 = "pbzip2 -f -k ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}" | ||
303 | CONVERSION_CMD:xz = "xz -f -k -c ${XZ_COMPRESSION_LEVEL} ${XZ_DEFAULTS} --check=${XZ_INTEGRITY_CHECK} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.xz" | ||
304 | CONVERSION_CMD:lz4 = "lz4 -9 -z -l ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.lz4" | ||
305 | CONVERSION_CMD:lzo = "lzop -9 ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}" | ||
306 | CONVERSION_CMD:zip = "zip ${ZIP_COMPRESSION_LEVEL} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.zip ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}" | ||
307 | CONVERSION_CMD:zst = "zstd -f -k -T0 -c ${ZSTD_COMPRESSION_LEVEL} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.zst" | ||
308 | CONVERSION_CMD:sum = "sumtool -i ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} -o ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.sum ${JFFS2_SUM_EXTRA_ARGS}" | ||
309 | CONVERSION_CMD:md5sum = "md5sum ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.md5sum" | ||
310 | CONVERSION_CMD:sha1sum = "sha1sum ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.sha1sum" | ||
311 | CONVERSION_CMD:sha224sum = "sha224sum ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.sha224sum" | ||
312 | CONVERSION_CMD:sha256sum = "sha256sum ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.sha256sum" | ||
313 | CONVERSION_CMD:sha384sum = "sha384sum ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.sha384sum" | ||
314 | CONVERSION_CMD:sha512sum = "sha512sum ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.sha512sum" | ||
315 | CONVERSION_CMD:bmap = "bmaptool create ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} -o ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.bmap" | ||
316 | CONVERSION_CMD:u-boot = "mkimage -A ${UBOOT_ARCH} -O linux -T ramdisk -C none -n ${IMAGE_NAME} -d ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.u-boot" | ||
317 | CONVERSION_CMD:vmdk = "qemu-img convert -O vmdk ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.vmdk" | ||
318 | CONVERSION_CMD:vhdx = "qemu-img convert -O vhdx -o subformat=dynamic ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.vhdx" | ||
319 | CONVERSION_CMD:vhd = "qemu-img convert -O vpc -o subformat=fixed ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.vhd" | ||
320 | CONVERSION_CMD:vdi = "qemu-img convert -O vdi ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.vdi" | ||
321 | CONVERSION_CMD:qcow2 = "qemu-img convert -O qcow2 ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.qcow2" | ||
322 | CONVERSION_CMD:base64 = "base64 ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type} > ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}.base64" | ||
323 | CONVERSION_CMD:zsync = "zsyncmake_curl ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}" | ||
324 | CONVERSION_CMD:gzsync = "zsyncmake_curl -z ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${type}" | ||
325 | CONVERSION_DEPENDS_lzma = "xz-native" | ||
326 | CONVERSION_DEPENDS_gz = "pigz-native" | ||
327 | CONVERSION_DEPENDS_bz2 = "pbzip2-native" | ||
328 | CONVERSION_DEPENDS_xz = "xz-native" | ||
329 | CONVERSION_DEPENDS_lz4 = "lz4-native" | ||
330 | CONVERSION_DEPENDS_lzo = "lzop-native" | ||
331 | CONVERSION_DEPENDS_zip = "zip-native" | ||
332 | CONVERSION_DEPENDS_zst = "zstd-native" | ||
333 | CONVERSION_DEPENDS_sum = "mtd-utils-native" | ||
334 | CONVERSION_DEPENDS_bmap = "bmap-tools-native" | ||
335 | CONVERSION_DEPENDS_u-boot = "u-boot-tools-native" | ||
336 | CONVERSION_DEPENDS_vmdk = "qemu-system-native" | ||
337 | CONVERSION_DEPENDS_vdi = "qemu-system-native" | ||
338 | CONVERSION_DEPENDS_qcow2 = "qemu-system-native" | ||
339 | CONVERSION_DEPENDS_base64 = "coreutils-native" | ||
340 | CONVERSION_DEPENDS_vhdx = "qemu-system-native" | ||
341 | CONVERSION_DEPENDS_vhd = "qemu-system-native" | ||
342 | CONVERSION_DEPENDS_zsync = "zsync-curl-native" | ||
343 | CONVERSION_DEPENDS_gzsync = "zsync-curl-native" | ||
344 | |||
345 | RUNNABLE_IMAGE_TYPES ?= "ext2 ext3 ext4" | ||
346 | RUNNABLE_MACHINE_PATTERNS ?= "qemu" | ||
347 | |||
348 | DEPLOYABLE_IMAGE_TYPES ?= "hddimg iso" | ||
349 | |||
350 | # The IMAGE_TYPES_MASKED variable will be used to mask out from the IMAGE_FSTYPES, | ||
351 | # images that will not be built at do_rootfs time: vmdk, vhd, vhdx, vdi, qcow2, hddimg, iso, etc. | ||
352 | IMAGE_TYPES_MASKED ?= "" | ||
353 | |||
354 | # bmap requires python3 to be in the PATH | ||
355 | EXTRANATIVEPATH += "${@'python3-native' if d.getVar('IMAGE_FSTYPES').find('.bmap') else ''}" | ||