esw-conf: Move to embeddedsw and use BBCLASSEXTEND

Make sure that we have native and nativesdk versions of esw-conf.

Add a dependency on lopper and xilinx-lops, as presumably users of this
recipe will need to use lopper to process the configurations.  This will
allow someone to use oe-run-native with esw-conf-native to use lopper
to transform system to domain specific device trees and their associated
configurations.

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta-xilinx-standalone-experimental/recipes-bsp/embeddedsw/esw-conf_git.bb b/meta-xilinx-standalone-experimental/recipes-bsp/embeddedsw/esw-conf_git.bb
new file mode 100644
index 00000000..e6cf1d8b
--- /dev/null
+++ b/meta-xilinx-standalone-experimental/recipes-bsp/embeddedsw/esw-conf_git.bb
@@ -0,0 +1,34 @@
+# Can't depend on esw since this is needed for setup!
+inherit xlnx-embeddedsw
+
+# We need to override the inherit
+require conf/dtb-embeddedsw.inc
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/build"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+# Installing this recipe should install the lopper tools and such
+DEPENDS = "lopper xilinx-lops"
+
+COMPATIBLE_HOST:forcevariable = ".*"
+
+ESW_COMPONENT_SRC = "/XilinxProcessorIPLib/drivers/"
+
+do_configure[noexec] = '1'
+do_compile[noexec] = '1'
+
+do_install() {
+    # The configuration step requires only the yaml files, make them
+    # available to the SDK
+    cd ${S}${ESW_COMPONENT_SRC}
+    for each in `find . -name *.yaml` ; do
+        mkdir -p $(dirname ${D}/${datadir}/embeddedsw${ESW_COMPONENT_SRC}$each)
+        install -m 0644 $each ${D}/${datadir}/embeddedsw${ESW_COMPONENT_SRC}$each
+    done
+}
+
+FILES:${PN} += "${datadir}/embeddedsw"
+
+BBCLASSEXTEND = "native nativesdk"