ai-engine: Moved from meta-xilinx-tools

Moves from meta-xilinx-tools as of commit 91c18d664dedc5c8e66f0744ec85a4d3c8bc300a.

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

3 files changed, 91 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-bsp/ai-engine/ai-engine-driver_3.2.bb b/meta-xilinx-core/recipes-bsp/ai-engine/ai-engine-driver_3.2.bb
new file mode 100644
index 00000000..8bb9a1aa
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/ai-engine/ai-engine-driver_3.2.bb
@@ -0,0 +1,47 @@
+SUMMARY = "Xilinx AI Engine runtime"
+DESCRIPTION = "This library provides APIs for the runtime support of the Xilinx AI Engine IP"
+
+require aie-rt.inc
+
+SECTION = "libs"
+
+AIEDIR ?= "${S}/driver"
+S = "${WORKDIR}/git"
+I = "${AIEDIR}/include"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:versal-ai-core = "versal-ai-core"
+COMPATIBLE_MACHINE:versal-ai-edge = "${SOC_VARIANT_ARCH}"
+PV = "3.2"
+
+IOBACKENDS ?= "Linux"
+
+DEPENDS = "${@bb.utils.contains('IOBACKENDS', 'metal', 'libmetal', '', d)}"
+RDEPENDS:${PN} = "${@bb.utils.contains('IOBACKENDS', 'metal', 'libmetal', '', d)}"
+
+PROVIDES = "libxaiengine"
+RPROVIDES:${PN} = "libxaiengine"
+
+# The makefile isn't ready for parallel execution at the moment
+PARALLEL_MAKE = "-j 1"
+
+CFLAGS += "-Wall -Wextra"
+CFLAGS += "${@bb.utils.contains('IOBACKENDS', 'Linux', ' -D__AIELINUX__', '', d)}"
+CFLAGS += "${@bb.utils.contains('IOBACKENDS', 'metal', ' -D__AIEMETAL__', '', d)}"
+EXTRA_OEMAKE = "-C ${AIEDIR}/src -f Makefile.Linux CFLAGS='${CFLAGS}'"
+
+
+do_compile(){
+        oe_runmake
+}
+
+do_install(){
+        install -d ${D}${includedir}
+        install ${I}/*.h ${D}${includedir}/
+        install -d ${D}${includedir}/xaiengine
+        install ${I}/xaiengine/*.h ${D}${includedir}/xaiengine/
+        install -d ${D}${libdir}
+        cp -dr ${AIEDIR}/src/*.so* ${D}${libdir}
+}
+
+PACKAGE_ARCH:versal-ai-core = "${SOC_VARIANT_ARCH}"
diff --git a/meta-xilinx-core/recipes-bsp/ai-engine/aie-rt.inc b/meta-xilinx-core/recipes-bsp/ai-engine/aie-rt.inc
new file mode 100644
index 00000000..85121654
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/ai-engine/aie-rt.inc
@@ -0,0 +1,11 @@
+SECTION = "libs"
+
+REPO ?= "git://github.com/Xilinx/aie-rt.git;protocol=https"
+
+BRANCH ?= "xlnx_rel_v2022.2"
+SRCREV ?= "ae24c8ede049906323510693f37e6167a963fd0e"
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM ?= "file://license.txt;md5=b81abf1f508952331dd7d2ab36408f5b"
+
+SRC_URI = "${REPO};branch=${BRANCH}"
diff --git a/meta-xilinx-core/recipes-bsp/ai-engine/aiefal_1.0.bb b/meta-xilinx-core/recipes-bsp/ai-engine/aiefal_1.0.bb
new file mode 100644
index 00000000..641c39a9
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/ai-engine/aiefal_1.0.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Xilinx AI Engine FAL(Functional Abstraction Layer)"
+DESCRIPTION = "AIE FAL provides functional abstraction APIs for runtime support of Xilinx AI Engine IP"
+
+require aie-rt.inc
+
+SECTION = "devel"
+
+XAIEFAL_DIR ?= "fal"
+S = "${WORKDIR}/git"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:versal-ai-core = "versal-ai-core"
+COMPATIBLE_MACHINE:versal-ai-edge = "${SOC_VARIANT_ARCH}"
+
+IOBACKENDS ?= "Linux"
+
+PROVIDES = "aiefal"
+ALLOW_EMPTY:${PN} = "1"
+
+inherit pkgconfig cmake
+
+DEPENDS = "libxaiengine"
+
+OECMAKE_SOURCEPATH = "${S}/${XAIEFAL_DIR}"
+
+EXTRA_OECMAKE = "-DWITH_TESTS=OFF "
+EXTRA_OECMAKE:append = "${@'-DWITH_EXAMPLES=ON' if d.getVar('WITH_EXAMPLES') == 'y' else '-DWITH_EXAMPLES=OFF'}"
+
+FILES:${PN}-demos = " \
+    ${bindir}/* \
+"
+
+PACKAGE_ARCH:versal-ai-core = "${SOC_VARIANT_ARCH}"