u-boot-xlnx: Add u-boot-tools-xlnx

Update the PREFERRED VERSION to select the new u-boot version, add preferred
provider for u-boot-tools to be u-boot-tools-xlnx.

Split the microblaze configs to support older and newer versions as well.

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

14 files changed, 123 insertions, 55 deletions

diff --git a/meta-xilinx-core/conf/layer.conf b/meta-xilinx-core/conf/layer.conf
index 616530d9..2da26edd 100644
--- a/meta-xilinx-core/conf/layer.conf
+++ b/meta-xilinx-core/conf/layer.conf
@@ -63,6 +63,7 @@ XILINX_UBOOT_VERSION[v2022.1] = "v2021.01-xilinx-v2022.1%"
 XILINX_UBOOT_VERSION[v2022.2] = "v2021.01-xilinx-v2022.2%"
 
 PREFERRED_VERSION_u-boot-xlnx ?= "${@d.getVarFlag('XILINX_UBOOT_VERSION', d.getVar('XILINX_RELEASE_VERSION')) or 'undefined'}"
+PREFERRED_VERSION_u-boot-tools-xlnx ?= "${@d.getVarFlag('XILINX_UBOOT_VERSION', d.getVar('XILINX_RELEASE_VERSION')) or 'undefined'}"
 
 XILINX_LINUX_VERSION[v2022.1] = "5.15.19-xilinx-v2022.1%"
 XILINX_LINUX_VERSION[v2022.2] = "5.15.36-xilinx-v2022.2%"
diff --git a/meta-xilinx-core/conf/machine/include/machine-xilinx-default.inc b/meta-xilinx-core/conf/machine/include/machine-xilinx-default.inc
index dc6ab05c..0cbd4249 100644
--- a/meta-xilinx-core/conf/machine/include/machine-xilinx-default.inc
+++ b/meta-xilinx-core/conf/machine/include/machine-xilinx-default.inc
@@ -16,6 +16,9 @@ PREFERRED_PROVIDER_virtual/kernel ??= "linux-xlnx"
 # U-Boot Configuration
 PREFERRED_PROVIDER_virtual/bootloader ??= "u-boot-xlnx"
 PREFERRED_PROVIDER_virtual/boot-bin ??= "xilinx-bootbin"
+PREFERRED_PROVIDER_u-boot-tools ??= "u-boot-tools-xlnx"
+PREFERRED_PROVIDER_u-boot-tools-native ??= "u-boot-tools-xlnx-native"
+PREFERRED_PROVIDER_nativesdk-u-boot-tools ??= "nativesdk-u-boot-tools-xlnx"
 
 do_image_wic[depends] += "${@' '.join('%s:do_deploy' % r for r in (d.getVar('WIC_DEPENDS') or "").split())}"
 
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools%.bbappend b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools%.bbappend
new file mode 100644
index 00000000..65b6ad9d
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools%.bbappend
@@ -0,0 +1,23 @@
+# Skip processing of this recipe if it is not explicitly specified as the
+# PREFERRED_PROVIDER for libmetal. This avoids network access required by
+# the use of AUTOREV SRCREVs, which may be the default for some recipes.
+python () {
+    if bb.data.inherits_class('native', d):
+        if (not d.getVar("PREFERRED_PROVIDER_u-boot-tools-native") and "u-boot-tools-native" != d.getVar("PN")) or \
+           (d.getVar("PREFERRED_PROVIDER_u-boot-tools-native") and d.getVar("PREFERRED_PROVIDER_u-boot-tools-native") != d.getVar("PN")):
+            d.delVar("BB_DONT_CACHE")
+            raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_u-boot-tools-native to %s to enable it" % (d.getVar("PN")))
+
+    elif bb.data.inherits_class('nativesdk', d):
+        if (not d.getVar("PREFERRED_PROVIDER_nativesdk-u-boot-tools") and "nativesdk-u-boot-tools" != d.getVar("PN")) or \
+           (d.getVar("PREFERRED_PROVIDER_nativesdk-u-boot-tools") and d.getVar("PREFERRED_PROVIDER_nativesdk-u-boot-tools") != d.getVar("PN")):
+            d.delVar("BB_DONT_CACHE")
+            raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_nativesdk-u-boot-tools to %s to enable it" % (d.getVar("PN")))
+
+    else:
+        if (not d.getVar("PREFERRED_PROVIDER_u-boot-tools") and "u-boot-tools" != d.getVar("PN")) or \
+           (d.getVar("PREFERRED_PROVIDER_u-boot-tools") and d.getVar("PREFERRED_PROVIDER_u-boot-tools") != d.getVar("PN")):
+            d.delVar("BB_DONT_CACHE")
+            raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_u-boot-tools to %s to enable it" % (d.getVar("PN")))
+}
+
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx.inc b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx.inc
new file mode 100644
index 00000000..af26594c
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx.inc
@@ -0,0 +1,7 @@
+require recipes-bsp/u-boot/u-boot-common.inc
+require recipes-bsp/u-boot/u-boot-tools.inc
+
+require u-boot-xlnx-common.inc
+
+PROVIDES:append = " u-boot-tools"
+RPROVIDES:${PN}:append = " u-boot-tools"
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx_2022.1.bb b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx_2022.1.bb
new file mode 100644
index 00000000..eaf8d4ce
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx_2022.1.bb
@@ -0,0 +1,21 @@
+require u-boot-tools-xlnx.inc
+require u-boot-xlnx-2022.1.inc
+
+# MUST clear CONFIG_VIDEO to avoid a compilation failure trying to construct
+# bmp_logo.h
+SED_CONFIG_EFI:append = ' -e "s/CONFIG_VIDEO=.*/# CONFIG_VIDEO is not set/"'
+
+# Default do_compile fails with:
+# | error: object directory ../downloads/git2/github.com.Xilinx.u-boot-xlnx.git/objects does not exist; check .git/objects/info/alternates.
+# The regular workaround of calling 'git diff' seems to be problematic.
+do_compile () {
+        oe_runmake -C ${S} tools-only_defconfig O=${B}
+
+        # Disable CONFIG_CMD_LICENSE, license.h is not used by tools and
+        # generating it requires bin2header tool, which for target build
+        # is built with target tools and thus cannot be executed on host.
+        sed -i -e "s/CONFIG_CMD_LICENSE=.*/# CONFIG_CMD_LICENSE is not set/" ${SED_CONFIG_EFI} ${B}/.config
+
+        oe_runmake -C ${S} cross_tools NO_SDL=1 O=${B}
+}
+
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx_2022.2.bb b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx_2022.2.bb
new file mode 100644
index 00000000..e4a2403a
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-tools-xlnx_2022.2.bb
@@ -0,0 +1,6 @@
+require u-boot-tools-xlnx.inc
+require u-boot-xlnx-2022.2.inc
+
+# MUST clear CONFIG_VIDEO to avoid a compilation failure trying to construct
+# bmp_logo.h
+SED_CONFIG_EFI:append = ' -e "s/CONFIG_VIDEO=.*/# CONFIG_VIDEO is not set/"'
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot/microblaze-generic-top.h b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-v2021.01/microblaze-generic-top.h
index 08c1c16c..08c1c16c 100644
--- a/meta-xilinx-core/recipes-bsp/u-boot/u-boot/microblaze-generic-top.h
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-v2021.01/microblaze-generic-top.h
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot/microblaze-generic.cfg b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-v2021.01/microblaze-generic.cfg
index 0f784f73..0f784f73 100644
--- a/meta-xilinx-core/recipes-bsp/u-boot/u-boot/microblaze-generic.cfg
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-v2021.01/microblaze-generic.cfg
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-2022.1.inc b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-2022.1.inc
new file mode 100644
index 00000000..a0c0b50d
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-2022.1.inc
@@ -0,0 +1,17 @@
+UBOOT_VERSION = "v2021.01"
+
+UBRANCH ?= "xlnx_rebase_v2022.01_2022.1_update"
+
+SRCREV = "91ad7924e7f59584d597353e1bb86794341e0a7e"
+
+LICENSE = "GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=4;md5=744e7e3bb0c94b4b9f6b3db3bf893897"
+
+# u-boot-xlnx has support for these
+HAS_PLATFORM_INIT ?= " \
+                xilinx_zynqmp_virt_config \
+                xilinx_zynq_virt_defconfig \
+                xilinx_versal_vc_p_a2197_revA_x_prc_01_revA \
+                "
+
+DEPENDS += "bc-native dtc-native python3-setuptools-native gnutls-native"
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-2022.2.inc b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-2022.2.inc
new file mode 100644
index 00000000..6415861d
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-2022.2.inc
@@ -0,0 +1,17 @@
+UBOOT_VERSION = "v2021.01"
+
+UBRANCH ?= "xlnx_rebase_v2022.01"
+
+SRCREV = "b31476685debf5512ed0d4e8000fa5167a22f530"
+
+LICENSE = "GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=4;md5=744e7e3bb0c94b4b9f6b3db3bf893897"
+
+# u-boot-xlnx has support for these
+HAS_PLATFORM_INIT ?= " \
+                xilinx_zynqmp_virt_config \
+                xilinx_zynq_virt_defconfig \
+                xilinx_versal_vc_p_a2197_revA_x_prc_01_revA \
+                "
+
+DEPENDS += "bc-native dtc-native python3-setuptools-native gnutls-native"
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-common.inc b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-common.inc
new file mode 100644
index 00000000..b447c92a
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx-common.inc
@@ -0,0 +1,19 @@
+# Use the name of the .bb for the extension
+UBOOT_VERSION_EXTENSION ?= "-xilinx-v${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[1] or ''}"
+PV = "${UBOOT_VERSION}${UBOOT_VERSION_EXTENSION}+git${SRCPV}"
+
+UBOOTURI ?= "git://github.com/Xilinx/u-boot-xlnx.git;protocol=https"
+UBRANCH ?= ""
+UBRANCHARG = "${@['nobranch=1', 'branch=${UBRANCH}'][d.getVar('UBRANCH', True) != '']}"
+
+SRC_URI = "${UBOOTURI};${UBRANCHARG}"
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/build"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/u-boot-${UBOOT_VERSION}:"
+
+UBOOT_MB_INC = ""
+UBOOT_MB_INC:microblaze = "u-boot-xlnx-microblaze.inc"
+require ${UBOOT_MB_INC}
+
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx.inc b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx.inc
index 183ebe31..38d8e492 100644
--- a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx.inc
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx.inc
@@ -1,25 +1,9 @@
+require recipes-bsp/u-boot/u-boot-common.inc
 require recipes-bsp/u-boot/u-boot.inc
 
-DEPENDS += "bc-native dtc-native bison-native xxd-native"
+DEPENDS += "bc-native dtc-native python3-setuptools-native bison-native xxd-native"
 
-# Use the name of the .bb for the extension
-UBOOT_VERSION_EXTENSION ?= "-xilinx-v${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[1] or ''}"
-PV = "${UBOOT_VERSION}${UBOOT_VERSION_EXTENSION}+git${SRCPV}"
-
-UBOOTURI ?= "git://github.com/Xilinx/u-boot-xlnx.git;protocol=https"
-UBRANCH ?= ""
-UBRANCHARG = "${@['nobranch=1', 'branch=${UBRANCH}'][d.getVar('UBRANCH', True) != '']}"
-
-SRC_URI = "${UBOOTURI};${UBRANCHARG}"
-
-S = "${WORKDIR}/git"
-B = "${WORKDIR}/build"
-
-FILESEXTRAPATHS:prepend := "${THISDIR}/u-boot:"
-
-UBOOT_MB_INC = ""
-UBOOT_MB_INC:microblaze = "u-boot-xlnx-microblaze.inc"
-require ${UBOOT_MB_INC}
+require u-boot-xlnx-common.inc
 
 SYSROOT_DIRS += "/boot"
 
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.1.bb b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.1.bb
index 7b109f50..c1c45e56 100644
--- a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.1.bb
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.1.bb
@@ -1,19 +1,4 @@
-UBOOT_VERSION = "v2021.01"
-
-UBRANCH ?= "xlnx_rebase_v2022.01_2022.1_update"
-
-SRCREV = "91ad7924e7f59584d597353e1bb86794341e0a7e"
-
-include u-boot-xlnx.inc
-include u-boot-spl-zynq-init.inc
-
-LICENSE = "GPL-2.0-or-later"
-LIC_FILES_CHKSUM = "file://README;beginline=1;endline=4;md5=744e7e3bb0c94b4b9f6b3db3bf893897"
-
-# u-boot-xlnx has support for these
-HAS_PLATFORM_INIT ?= " \
-                xilinx_zynqmp_virt_config \
-                xilinx_zynq_virt_defconfig \
-                xilinx_versal_vc_p_a2197_revA_x_prc_01_revA \
-                "
 
+require u-boot-xlnx.inc
+require u-boot-spl-zynq-init.inc
+require u-boot-xlnx-2022.1.inc
diff --git a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.2.bb b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.2.bb
index 3fdc3840..b10f321b 100644
--- a/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.2.bb
+++ b/meta-xilinx-core/recipes-bsp/u-boot/u-boot-xlnx_2022.2.bb
@@ -1,19 +1,4 @@
-UBOOT_VERSION = "v2021.01"
-
-UBRANCH ?= "xlnx_rebase_v2022.01"
-
-SRCREV = "b31476685debf5512ed0d4e8000fa5167a22f530"
-
-include u-boot-xlnx.inc
-include u-boot-spl-zynq-init.inc
-
-LICENSE = "GPL-2.0-or-later"
-LIC_FILES_CHKSUM = "file://README;beginline=1;endline=4;md5=744e7e3bb0c94b4b9f6b3db3bf893897"
-
-# u-boot-xlnx has support for these
-HAS_PLATFORM_INIT ?= " \
-                xilinx_zynqmp_virt_config \
-                xilinx_zynq_virt_defconfig \
-                xilinx_versal_vc_p_a2197_revA_x_prc_01_revA \
-                "
 
+require u-boot-xlnx.inc
+require u-boot-spl-zynq-init.inc
+require u-boot-xlnx-2022.2.inc