Initial restructure/split of meta-xilinx-bsp

Create a new meta-xilinx-core, move core functionality to the core, keeping
board specific files in the bsp layer.

zynqmp-generic changed from require <board> to include, so if meta-xilinx-bsp
is not available it will not fail.

Signed-off-by: Mark Hatle <mark.hatle@xilinx.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-bsp/platform-init/platform-init.bb b/meta-xilinx-core/recipes-bsp/platform-init/platform-init.bb
new file mode 100644
index 00000000..cac8bbfc
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/platform-init/platform-init.bb
@@ -0,0 +1,38 @@
+SUMMARY = "Xilinx Platform Headers"
+DESCRPTION = "Xilinx ps*_init_gpl.c/h platform init code, used for building u-boot-spl and fsbl"
+HOMEPAGE = "http://www.xilinx.com"
+SECTION = "bsp"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit xilinx-platform-init
+
+COMPATIBLE_MACHINE = "$^"
+COMPATIBLE_MACHINE_picozed-zynq7 = "picozed-zynq7"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+
+PROVIDES += "virtual/xilinx-platform-init"
+
+SRC_URI = "${@" ".join(["file://%s" % f for f in (d.getVar('PLATFORM_INIT_FILES') or "").split()])}"
+
+S = "${WORKDIR}"
+
+SYSROOT_DIRS += "${PLATFORM_INIT_DIR}"
+
+do_compile() {
+        :
+}
+
+do_install() {
+        install -d ${D}${PLATFORM_INIT_DIR}
+        for i in ${PLATFORM_INIT_FILES}; do
+                install -m 0644 ${S}/$i ${D}${PLATFORM_INIT_DIR}/
+        done
+}
+
+FILES:${PN} += "${PLATFORM_INIT_DIR}/*"
+