conf/machine/microblaze: Remove MicroBlaze tunes

The MicroBlaze tunes are now part of oe-core. This removes the need for
the meta-xilinx-bsp layer to provide architecture tunes.

The tunes in oe-core are almost identical (with the exception of
tune-microblaze.inc which had machine configuration in meta-xilinx).

Signed-off-by: Nathan Rossi <nathan@nathanrossi.com>
Signed-off-by: Manjukumar Matha <manjukumar.harthikote-matha@xilinx.com>

4 files changed, 0 insertions, 164 deletions

diff --git a/meta-xilinx-bsp/conf/machine/include/microblaze/arch-microblaze.inc b/meta-xilinx-bsp/conf/machine/include/microblaze/arch-microblaze.inc
deleted file mode 100644
index d79269cc..00000000
--- a/meta-xilinx-bsp/conf/machine/include/microblaze/arch-microblaze.inc
+++ /dev/null
@@ -1,53 +0,0 @@
-# MicroBlaze architecture tune feature configuration
-
-# Architecture feature and override
-TUNEVALID[microblaze] = "MicroBlaze"
-MACHINEOVERRIDES =. "${@bb.utils.contains("TUNE_FEATURES", "microblaze", "microblaze:", "" ,d)}"
-
-# Endian
-TUNEVALID[bigendian] = "Use Microblaze Big Endian"
-TUNECONFLICTS[bigendian] += "v10.0"
-
-MBPKGARCH_ENDIAN = "${@bb.utils.contains("TUNE_FEATURES", "bigendian", "eb", "el" ,d)}"
-
-TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "bigendian", "-mbig-endian", "-mlittle-endian" ,d)}"
-
-# General features
-TUNEVALID[barrel-shift] = "Enable Hardware Barrel Shifter"
-TUNEVALID[pattern-compare] = "Enable Pattern Compare Instructions"
-TUNEVALID[reorder] = "Enable Reorder Instructions"
-TUNECONFLICTS[reorder] += "v8.00 v8.10 v8.20"
-
-# Core configuration tune optimizations
-TUNEVALID[frequency-optimized] = "Enabling tuning for frequency optimized core (AREA_OPTIMIZED_2)"
-TUNECONFLICTS[frequency-optimized] += "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4 v9.5 v9.6"
-
-# Feature compiler args
-TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-mxl-barrel-shift", "-mno-xl-barrel-shift" ,d)}"
-TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-mxl-pattern-compare", "-mno-xl-pattern-compare" ,d)}"
-TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "frequency-optimized", "-mxl-frequency", "", d)}"
-
-# Disable reorder for v8.30 if pattern-compare is not enabled
-TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "reorder", \
-        bb.utils.contains("TUNE_FEATURES", "v8.30", \
-            bb.utils.contains("TUNE_FEATURES", "pattern-compare", \
-                "-mxl-reorder", "-mno-xl-reorder", d), \
-            "-mxl-reorder", d), "-mno-xl-reorder", d)}"
-
-# Feature package architecture formatting
-MBPKGARCH_TUNE = ""
-MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-bs", "" ,d)}"
-MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-cmp", "" ,d)}"
-MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "reorder", "-re", "" ,d)}"
-MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "frequency-optimized", "-fo", "" ,d)}"
-
-# Additional features
-require conf/machine/include/microblaze/feature-microblaze-versions.inc
-require conf/machine/include/microblaze/feature-microblaze-math.inc
-
-# Architecture name, either 'microblazeeb' or 'microblazeel' depending on endianess
-TUNE_ARCH = "microblaze${@bb.utils.contains("TUNE_FEATURES", "bigendian", "eb", "el" ,d)}"
-
-# Package Architecture formatting
-TUNE_PKGARCH = "microblaze${MBPKGARCH_ENDIAN}${MBPKGARCH_VERSION}${MBPKGARCH_TUNE}${MBPKGARCH_MATH}"
-
diff --git a/meta-xilinx-bsp/conf/machine/include/microblaze/feature-microblaze-math.inc b/meta-xilinx-bsp/conf/machine/include/microblaze/feature-microblaze-math.inc
deleted file mode 100644
index b2c7f071..00000000
--- a/meta-xilinx-bsp/conf/machine/include/microblaze/feature-microblaze-math.inc
+++ /dev/null
@@ -1,33 +0,0 @@
-# This include describes the math features (integer and floating point) that
-# are available for the MicroBlaze ISA
-
-TUNEVALID[multiply-low] = "Hardware multipler with 32 bit result"
-TUNEVALID[multiply-high] = "Hardware multipler with 64 bit result"
-TUNEVALID[divide-hard] = "Hardware divider"
-TUNEVALID[fpu-soft] = "Software FPU"
-TUNEVALID[fpu-hard] = "Hardware FPU in basic mode"
-TUNEVALID[fpu-hard-extended] = "Hardware FPU in extended mode (conversion and square root instructions)"
-
-TUNECONFLICTS[fpu-soft] = "fpu-hard fpu-hard-extended"
-TUNECONFLICTS[fpu-hard] = "fpu-soft"
-TUNECONFLICTS[fpu-hard-extended] = "fpu-soft"
-
-# Compiler args
-TUNE_CCARGS += "${@bb.utils.contains_any('TUNE_FEATURES', ['multiply-low', 'multiply-high'], '-mno-xl-soft-mul', '-mxl-soft-mul', d)}"
-TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'multiply-high', '-mxl-multiply-high', '', d)}"
-
-TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'divide-hard', '-mno-xl-soft-div', '-mxl-soft-div' ,d)}"
-
-TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'fpu-soft', '', '', d)}"
-TUNE_CCARGS += "${@bb.utils.contains_any('TUNE_FEATURES', ['fpu-hard', 'fpu-hard-extended'], '-mhard-float', '', d)}"
-TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'fpu-hard-extended', '-mxl-float-convert -mxl-float-sqrt', '', d)}"
-
-# Set target fpu (bitbake known target) to soft or hard (basic or extended)
-TARGET_FPU = "${@bb.utils.contains_any('TUNE_FEATURES', 'fpu-hard fpu-hard-extended', 'fpu-hard', 'fpu-soft', d)}"
-
-# Package Architecture formatting
-MBPKGARCH_MATH = ""
-MBPKGARCH_MATH .= "${@bb.utils.contains('TUNE_FEATURES', 'multiply-high', '-mh', bb.utils.contains('TUNE_FEATURES', 'multiply-low', '-ml', '', d), d)}"
-MBPKGARCH_MATH .= "${@bb.utils.contains('TUNE_FEATURES', 'divide-hard', '-div', '' ,d)}"
-MBPKGARCH_MATH .= "${@bb.utils.contains('TUNE_FEATURES', 'fpu-hard-extended', '-fe', bb.utils.contains('TUNE_FEATURES', 'fpu-hard', '-fb', '', d), d)}"
-
diff --git a/meta-xilinx-bsp/conf/machine/include/microblaze/feature-microblaze-versions.inc b/meta-xilinx-bsp/conf/machine/include/microblaze/feature-microblaze-versions.inc
deleted file mode 100644
index 955674ff..00000000
--- a/meta-xilinx-bsp/conf/machine/include/microblaze/feature-microblaze-versions.inc
+++ /dev/null
@@ -1,67 +0,0 @@
-# MicroBlaze versions are defined as features, the features are setup to
-# conflict with other versions as well as unavailable features for particular
-# versions.
-#
-# Versions before v9.0 of MicroBlaze use a versioning scheme of "vX.YY.Z"
-# (where Z = [abc]). For v8.* versions of MicroBlaze the revision (Z) changes
-# did not affect ABI and are ignored by this tune configuration. Though this
-# format is expected by GCC including the revision, but this is defaulted to
-# ".a".
-#
-# Since v9.0 of MicroBlaze the revision (Z) part of versions was entirely
-# dropped and the version scheme was changed to "vX.Y".
-
-def microblaze_current_version(d, gcc = False):
-    import re
-    # find the current version, and convert it to major/minor integers
-    version = None
-    for t in (d.getVar("TUNE_FEATURES") or "").split():
-        m = re.search("^v(\d+)\.(\d+)", t)
-        if m:
-            version = int(m.group(1)), int(m.group(2))
-            break
-
-    # format the version string in generic or GCC specific formats
-    if version:
-        if version[0] <= 8:
-            return ("v%d.%02d" % version[0:2]) + (".a" if gcc else "")
-        else:
-            return "v%d.%d" % version[0:2]
-    return ""
-
-# MicroBlaze versions
-TUNEVALID[v8.00] = "MicroBlaze version 8.00"
-TUNEVALID[v8.10] = "MicroBlaze version 8.10"
-TUNEVALID[v8.20] = "MicroBlaze version 8.20"
-TUNEVALID[v8.30] = "MicroBlaze version 8.30"
-TUNEVALID[v8.40] = "MicroBlaze version 8.40"
-TUNEVALID[v8.50] = "MicroBlaze version 8.50"
-TUNEVALID[v9.0]  = "MicroBlaze version 9.0"
-TUNEVALID[v9.1]  = "MicroBlaze version 9.1"
-TUNEVALID[v9.2]  = "MicroBlaze version 9.2"
-TUNEVALID[v9.3]  = "MicroBlaze version 9.3"
-TUNEVALID[v9.4]  = "MicroBlaze version 9.4"
-TUNEVALID[v9.5]  = "MicroBlaze version 9.5"
-TUNEVALID[v9.6]  = "MicroBlaze version 9.6"
-TUNEVALID[v10.0] = "MicroBlaze version 10.0"
-
-# Version conflict matrix
-TUNECONFLICTS[v8.00] = ""
-TUNECONFLICTS[v8.10] = "v8.00"
-TUNECONFLICTS[v8.20] = "v8.00 v8.10"
-TUNECONFLICTS[v8.30] = "v8.00 v8.10 v8.20"
-TUNECONFLICTS[v8.40] = "v8.00 v8.10 v8.20 v8.30"
-TUNECONFLICTS[v8.50] = "v8.00 v8.10 v8.20 v8.30 v8.40"
-TUNECONFLICTS[v9.0]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50"
-TUNECONFLICTS[v9.1]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0"
-TUNECONFLICTS[v9.2]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1"
-TUNECONFLICTS[v9.3]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2"
-TUNECONFLICTS[v9.4]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3"
-TUNECONFLICTS[v9.5]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4"
-TUNECONFLICTS[v9.6]  = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4 v9.5"
-TUNECONFLICTS[v10.0] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4 v9.5 v9.6"
-
-# Version flags
-TUNE_CCARGS += "-mcpu=${@microblaze_current_version(d, True)}"
-MBPKGARCH_VERSION = "-${@microblaze_current_version(d)}"
-
diff --git a/meta-xilinx-bsp/conf/machine/include/tune-microblaze.inc b/meta-xilinx-bsp/conf/machine/include/tune-microblaze.inc
deleted file mode 100644
index 73512fc6..00000000
--- a/meta-xilinx-bsp/conf/machine/include/tune-microblaze.inc
+++ /dev/null
@@ -1,11 +0,0 @@
-DEFAULTTUNE ?= "microblaze"
-
-require conf/machine/include/microblaze/arch-microblaze.inc
-
-AVAILTUNES += "microblaze"
-TUNE_FEATURES_tune-microblaze = "microblaze"
-PACKAGE_EXTRA_ARCHS_tune-microblaze = "${TUNE_PKGARCH}"
-
-# U-Boot Configuration
-UBOOT_MACHINE ?= "microblaze-generic_config"
-