summaryrefslogtreecommitdiffstats
path: root/conf
diff options
context:
space:
mode:
authorManjukumar Matha <manjukumar.harthikote-matha@xilinx.com>2017-12-06 16:06:35 -0800
committerManjukumar Matha <manjukumar.harthikote-matha@xilinx.com>2017-12-13 16:11:14 -0800
commita18947c20dba2c0c38db8bde1ad4684995df4bbd (patch)
tree917bf2abbe439a6f99ede8cfafb25812dca54a9a /conf
parent6ddc5873b0ede30e6542f0ab151a6236acc37944 (diff)
downloadmeta-xilinx-a18947c20dba2c0c38db8bde1ad4684995df4bbd.tar.gz
meta-xilinx: Restructuring meta-xilinx to support multiple layers
As discussed previously on mailing list, we are proceeding with layer restructuring. For rocko release we will have the following layers meta-xilinx ->meta-xilinx-bsp (current meta-xilinx) ->meta-xilinx-contrib In the subsequent releases we will add other layers from Xilinx meta-xilinx ->meta-xilinx-bsp (current meta-xilinx) ->meta-petalinux ->meta-xilinx-tools ->meta-xilinx-contrib This will provide one clone to get all the required meta layers from Xilinx for a complete solution, and the users can blacklist any layer which they don't want to use using bblayer.conf. This will enables us to help our vendors/partners to add their reference designs, board definitions etc. Recipe changes : * Move reference design zybo-linux-bd.bb to meta-xilinx-contrib * Move kernel patches realted to zybo-linux-bd-zynq7 board to meta-xilinx-contrib * Update README Signed-off-by: Manjukumar Matha <manjukumar.harthikote-matha@xilinx.com>
Diffstat (limited to 'conf')
-rw-r--r--conf/layer.conf12
-rw-r--r--conf/machine/include/machine-xilinx-board.inc6
-rw-r--r--conf/machine/include/machine-xilinx-default.inc41
-rw-r--r--conf/machine/include/machine-xilinx-qemu.inc49
-rw-r--r--conf/machine/include/microblaze/arch-microblaze.inc53
-rw-r--r--conf/machine/include/microblaze/feature-microblaze-math.inc33
-rw-r--r--conf/machine/include/microblaze/feature-microblaze-versions.inc67
-rw-r--r--conf/machine/include/tune-microblaze.inc19
-rw-r--r--conf/machine/include/tune-zynq.inc12
-rw-r--r--conf/machine/include/tune-zynqmp.inc11
-rw-r--r--conf/machine/include/zynqmp-pmu-config.inc20
-rw-r--r--conf/machine/kc705-microblazeel.conf20
-rw-r--r--conf/machine/microzed-zynq7.conf30
-rw-r--r--conf/machine/ml605-qemu-microblazeel.conf25
-rw-r--r--conf/machine/picozed-zynq7.conf34
-rw-r--r--conf/machine/qemu-zynq7.conf25
-rw-r--r--conf/machine/s3adsp1800-qemu-microblazeeb.conf24
-rw-r--r--conf/machine/zc702-zynq7.conf45
-rw-r--r--conf/machine/zc706-zynq7.conf49
-rw-r--r--conf/machine/zcu102-zynqmp.conf77
-rw-r--r--conf/machine/zedboard-zynq7.conf29
-rw-r--r--conf/machine/zybo-linux-bd-zynq7.conf40
-rw-r--r--conf/machine/zybo-zynq7.conf34
23 files changed, 0 insertions, 755 deletions
diff --git a/conf/layer.conf b/conf/layer.conf
deleted file mode 100644
index dac3e246..00000000
--- a/conf/layer.conf
+++ /dev/null
@@ -1,12 +0,0 @@
1# We have a conf and classes directory, add to BBPATH
2BBPATH .= ":${LAYERDIR}"
3
4# We have a packages directory, add to BBFILES
5BBFILES += "${LAYERDIR}/recipes-*/*/*.bb"
6BBFILES += "${LAYERDIR}/recipes-*/*/*.bbappend"
7
8BBFILE_COLLECTIONS += "xilinx"
9BBFILE_PATTERN_xilinx = "^${LAYERDIR}/"
10BBFILE_PRIORITY_xilinx = "5"
11
12LAYERDEPENDS_xilinx = "core"
diff --git a/conf/machine/include/machine-xilinx-board.inc b/conf/machine/include/machine-xilinx-board.inc
deleted file mode 100644
index ba9a36be..00000000
--- a/conf/machine/include/machine-xilinx-board.inc
+++ /dev/null
@@ -1,6 +0,0 @@
1# Default Xilinx Board settings
2
3EXTRA_IMAGEDEPENDS += "virtual/bootloader"
4
5IMAGE_BOOT_FILES ?= "${KERNEL_IMAGETYPE} ${UBOOT_BINARY}"
6
diff --git a/conf/machine/include/machine-xilinx-default.inc b/conf/machine/include/machine-xilinx-default.inc
deleted file mode 100644
index 522e0081..00000000
--- a/conf/machine/include/machine-xilinx-default.inc
+++ /dev/null
@@ -1,41 +0,0 @@
1# Default Xilinx BSP Machine settings
2
3MACHINE_FEATURES_BACKFILL_CONSIDERED += "rtc"
4
5# MicroBlaze cannot handle the execution of qemu-linux-user for gobject-introspection-data
6MACHINE_FEATURES_BACKFILL_CONSIDERED_append_microblaze = " qemu-usermode"
7
8# File System Configuration
9IMAGE_FSTYPES ?= "tar.gz cpio cpio.gz.u-boot"
10
11# Kernel Configuration
12XILINX_DEFAULT_KERNEL := "linux-xlnx"
13XILINX_DEFAULT_KERNEL_microblaze := "linux-yocto"
14XILINX_DEFAULT_KERNEL_zynqmp := "linux-yocto"
15PREFERRED_PROVIDER_virtual/kernel ??= "${XILINX_DEFAULT_KERNEL}"
16
17# U-Boot Configuration
18XILINX_DEFAULT_UBOOT := "u-boot-xlnx"
19XILINX_DEFAULT_UBOOT_zynqmp := "u-boot"
20PREFERRED_PROVIDER_virtual/bootloader ??= "${XILINX_DEFAULT_UBOOT}"
21PREFERRED_PROVIDER_virtual/boot-bin ??= "${PREFERRED_PROVIDER_virtual/bootloader}"
22
23UBOOT_SUFFIX ?= "img"
24UBOOT_SUFFIX_zynqmp ?= "bin"
25UBOOT_SUFFIX_microblaze ?= "bin"
26
27UBOOT_BINARY ?= "u-boot.${UBOOT_SUFFIX}"
28UBOOT_ELF ?= "u-boot"
29UBOOT_ELF_aarch64 ?= "u-boot.elf"
30
31XSERVER ?= " \
32 xserver-xorg \
33 xf86-input-evdev \
34 xf86-input-mouse \
35 xf86-input-keyboard \
36 xf86-video-fbdev \
37 ${XSERVER_EXT} \
38 "
39
40XSERVER_EXT ?= ""
41XSERVER_EXT_zynqmp ?= "xf86-video-armsoc"
diff --git a/conf/machine/include/machine-xilinx-qemu.inc b/conf/machine/include/machine-xilinx-qemu.inc
deleted file mode 100644
index dd275f3b..00000000
--- a/conf/machine/include/machine-xilinx-qemu.inc
+++ /dev/null
@@ -1,49 +0,0 @@
1# This include is used to setup default QEMU and qemuboot config for meta-xilinx
2# machines.
3
4# depend on qemu-helper-native, which will depend on QEMU
5EXTRA_IMAGEDEPENDS += "qemu-helper-native"
6
7def qemu_default_dtb(d):
8 if d.getVar("IMAGE_BOOT_FILES", True):
9 dtbs = d.getVar("IMAGE_BOOT_FILES", True).split(" ")
10 # IMAGE_BOOT_FILES has extra renaming info in the format '<source>;<target>'
11 dtbs = [f.split(";")[0] for f in dtbs]
12 dtbs = [f for f in dtbs if f.endswith(".dtb")]
13 if len(dtbs) != 0:
14 return dtbs[0]
15 if d.getVar("KERNEL_DEVICETREE", True):
16 dtbs = d.getVar("KERNEL_DEVICETREE", True).split(" ")
17 dtbs = [os.path.basename(d) for d in dtbs]
18 if len(dtbs) != 0:
19 return d.getVar("KERNEL_IMAGETYPE", True) + "-" + dtbs[0]
20 return ""
21
22def qemu_default_serial(d):
23 if d.getVar("SERIAL_CONSOLE", True):
24 speed, console = d.getVar("SERIAL_CONSOLE", True).split(" ", 1)
25 # zynqmp uses earlycon and stdout (in dtb)
26 if "zynqmp" in d.getVar("MACHINEOVERRIDES", True).split(":"):
27 return ""
28 return "console=%s,%s earlyprintk" % (console, speed)
29 return ""
30
31def qemu_target_binary(d):
32 ta = d.getVar("TARGET_ARCH", True)
33 if ta == "microblazeeb":
34 ta = "microblaze"
35 elif ta == "arm":
36 ta = "aarch64"
37 return "qemu-system-%s" % ta
38
39def qemu_zynqmp_unhalt(d, multiarch):
40 if multiarch:
41 return "-global xlnx,zynqmp-boot.cpu-num=0 -global xlnx,zynqmp-boot.use-pmufw=true"
42 return "-device loader,addr=0xfd1a0104,data=0x8000000e,data-len=4 -device loader,addr=0xfd1a0104,data=0x8000000e,data-len=4"
43
44# For qemuboot, default setup across all machines in meta-xilinx
45QB_SYSTEM_NAME ?= "${@qemu_target_binary(d)}"
46QB_DEFAULT_FSTYPE ?= "cpio"
47QB_DTB ?= "${@qemu_default_dtb(d)}"
48QB_KERNEL_CMDLINE_APPEND ?= "${@qemu_default_serial(d)}"
49
diff --git a/conf/machine/include/microblaze/arch-microblaze.inc b/conf/machine/include/microblaze/arch-microblaze.inc
deleted file mode 100644
index d79269cc..00000000
--- a/conf/machine/include/microblaze/arch-microblaze.inc
+++ /dev/null
@@ -1,53 +0,0 @@
1# MicroBlaze architecture tune feature configuration
2
3# Architecture feature and override
4TUNEVALID[microblaze] = "MicroBlaze"
5MACHINEOVERRIDES =. "${@bb.utils.contains("TUNE_FEATURES", "microblaze", "microblaze:", "" ,d)}"
6
7# Endian
8TUNEVALID[bigendian] = "Use Microblaze Big Endian"
9TUNECONFLICTS[bigendian] += "v10.0"
10
11MBPKGARCH_ENDIAN = "${@bb.utils.contains("TUNE_FEATURES", "bigendian", "eb", "el" ,d)}"
12
13TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "bigendian", "-mbig-endian", "-mlittle-endian" ,d)}"
14
15# General features
16TUNEVALID[barrel-shift] = "Enable Hardware Barrel Shifter"
17TUNEVALID[pattern-compare] = "Enable Pattern Compare Instructions"
18TUNEVALID[reorder] = "Enable Reorder Instructions"
19TUNECONFLICTS[reorder] += "v8.00 v8.10 v8.20"
20
21# Core configuration tune optimizations
22TUNEVALID[frequency-optimized] = "Enabling tuning for frequency optimized core (AREA_OPTIMIZED_2)"
23TUNECONFLICTS[frequency-optimized] += "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4 v9.5 v9.6"
24
25# Feature compiler args
26TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-mxl-barrel-shift", "-mno-xl-barrel-shift" ,d)}"
27TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-mxl-pattern-compare", "-mno-xl-pattern-compare" ,d)}"
28TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "frequency-optimized", "-mxl-frequency", "", d)}"
29
30# Disable reorder for v8.30 if pattern-compare is not enabled
31TUNE_CCARGS += "${@bb.utils.contains("TUNE_FEATURES", "reorder", \
32 bb.utils.contains("TUNE_FEATURES", "v8.30", \
33 bb.utils.contains("TUNE_FEATURES", "pattern-compare", \
34 "-mxl-reorder", "-mno-xl-reorder", d), \
35 "-mxl-reorder", d), "-mno-xl-reorder", d)}"
36
37# Feature package architecture formatting
38MBPKGARCH_TUNE = ""
39MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-bs", "" ,d)}"
40MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-cmp", "" ,d)}"
41MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "reorder", "-re", "" ,d)}"
42MBPKGARCH_TUNE .= "${@bb.utils.contains("TUNE_FEATURES", "frequency-optimized", "-fo", "" ,d)}"
43
44# Additional features
45require conf/machine/include/microblaze/feature-microblaze-versions.inc
46require conf/machine/include/microblaze/feature-microblaze-math.inc
47
48# Architecture name, either 'microblazeeb' or 'microblazeel' depending on endianess
49TUNE_ARCH = "microblaze${@bb.utils.contains("TUNE_FEATURES", "bigendian", "eb", "el" ,d)}"
50
51# Package Architecture formatting
52TUNE_PKGARCH = "microblaze${MBPKGARCH_ENDIAN}${MBPKGARCH_VERSION}${MBPKGARCH_TUNE}${MBPKGARCH_MATH}"
53
diff --git a/conf/machine/include/microblaze/feature-microblaze-math.inc b/conf/machine/include/microblaze/feature-microblaze-math.inc
deleted file mode 100644
index b2c7f071..00000000
--- a/conf/machine/include/microblaze/feature-microblaze-math.inc
+++ /dev/null
@@ -1,33 +0,0 @@
1# This include describes the math features (integer and floating point) that
2# are available for the MicroBlaze ISA
3
4TUNEVALID[multiply-low] = "Hardware multipler with 32 bit result"
5TUNEVALID[multiply-high] = "Hardware multipler with 64 bit result"
6TUNEVALID[divide-hard] = "Hardware divider"
7TUNEVALID[fpu-soft] = "Software FPU"
8TUNEVALID[fpu-hard] = "Hardware FPU in basic mode"
9TUNEVALID[fpu-hard-extended] = "Hardware FPU in extended mode (conversion and square root instructions)"
10
11TUNECONFLICTS[fpu-soft] = "fpu-hard fpu-hard-extended"
12TUNECONFLICTS[fpu-hard] = "fpu-soft"
13TUNECONFLICTS[fpu-hard-extended] = "fpu-soft"
14
15# Compiler args
16TUNE_CCARGS += "${@bb.utils.contains_any('TUNE_FEATURES', ['multiply-low', 'multiply-high'], '-mno-xl-soft-mul', '-mxl-soft-mul', d)}"
17TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'multiply-high', '-mxl-multiply-high', '', d)}"
18
19TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'divide-hard', '-mno-xl-soft-div', '-mxl-soft-div' ,d)}"
20
21TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'fpu-soft', '', '', d)}"
22TUNE_CCARGS += "${@bb.utils.contains_any('TUNE_FEATURES', ['fpu-hard', 'fpu-hard-extended'], '-mhard-float', '', d)}"
23TUNE_CCARGS += "${@bb.utils.contains('TUNE_FEATURES', 'fpu-hard-extended', '-mxl-float-convert -mxl-float-sqrt', '', d)}"
24
25# Set target fpu (bitbake known target) to soft or hard (basic or extended)
26TARGET_FPU = "${@bb.utils.contains_any('TUNE_FEATURES', 'fpu-hard fpu-hard-extended', 'fpu-hard', 'fpu-soft', d)}"
27
28# Package Architecture formatting
29MBPKGARCH_MATH = ""
30MBPKGARCH_MATH .= "${@bb.utils.contains('TUNE_FEATURES', 'multiply-high', '-mh', bb.utils.contains('TUNE_FEATURES', 'multiply-low', '-ml', '', d), d)}"
31MBPKGARCH_MATH .= "${@bb.utils.contains('TUNE_FEATURES', 'divide-hard', '-div', '' ,d)}"
32MBPKGARCH_MATH .= "${@bb.utils.contains('TUNE_FEATURES', 'fpu-hard-extended', '-fe', bb.utils.contains('TUNE_FEATURES', 'fpu-hard', '-fb', '', d), d)}"
33
diff --git a/conf/machine/include/microblaze/feature-microblaze-versions.inc b/conf/machine/include/microblaze/feature-microblaze-versions.inc
deleted file mode 100644
index 955674ff..00000000
--- a/conf/machine/include/microblaze/feature-microblaze-versions.inc
+++ /dev/null
@@ -1,67 +0,0 @@
1# MicroBlaze versions are defined as features, the features are setup to
2# conflict with other versions as well as unavailable features for particular
3# versions.
4#
5# Versions before v9.0 of MicroBlaze use a versioning scheme of "vX.YY.Z"
6# (where Z = [abc]). For v8.* versions of MicroBlaze the revision (Z) changes
7# did not affect ABI and are ignored by this tune configuration. Though this
8# format is expected by GCC including the revision, but this is defaulted to
9# ".a".
10#
11# Since v9.0 of MicroBlaze the revision (Z) part of versions was entirely
12# dropped and the version scheme was changed to "vX.Y".
13
14def microblaze_current_version(d, gcc = False):
15 import re
16 # find the current version, and convert it to major/minor integers
17 version = None
18 for t in (d.getVar("TUNE_FEATURES") or "").split():
19 m = re.search("^v(\d+)\.(\d+)", t)
20 if m:
21 version = int(m.group(1)), int(m.group(2))
22 break
23
24 # format the version string in generic or GCC specific formats
25 if version:
26 if version[0] <= 8:
27 return ("v%d.%02d" % version[0:2]) + (".a" if gcc else "")
28 else:
29 return "v%d.%d" % version[0:2]
30 return ""
31
32# MicroBlaze versions
33TUNEVALID[v8.00] = "MicroBlaze version 8.00"
34TUNEVALID[v8.10] = "MicroBlaze version 8.10"
35TUNEVALID[v8.20] = "MicroBlaze version 8.20"
36TUNEVALID[v8.30] = "MicroBlaze version 8.30"
37TUNEVALID[v8.40] = "MicroBlaze version 8.40"
38TUNEVALID[v8.50] = "MicroBlaze version 8.50"
39TUNEVALID[v9.0] = "MicroBlaze version 9.0"
40TUNEVALID[v9.1] = "MicroBlaze version 9.1"
41TUNEVALID[v9.2] = "MicroBlaze version 9.2"
42TUNEVALID[v9.3] = "MicroBlaze version 9.3"
43TUNEVALID[v9.4] = "MicroBlaze version 9.4"
44TUNEVALID[v9.5] = "MicroBlaze version 9.5"
45TUNEVALID[v9.6] = "MicroBlaze version 9.6"
46TUNEVALID[v10.0] = "MicroBlaze version 10.0"
47
48# Version conflict matrix
49TUNECONFLICTS[v8.00] = ""
50TUNECONFLICTS[v8.10] = "v8.00"
51TUNECONFLICTS[v8.20] = "v8.00 v8.10"
52TUNECONFLICTS[v8.30] = "v8.00 v8.10 v8.20"
53TUNECONFLICTS[v8.40] = "v8.00 v8.10 v8.20 v8.30"
54TUNECONFLICTS[v8.50] = "v8.00 v8.10 v8.20 v8.30 v8.40"
55TUNECONFLICTS[v9.0] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50"
56TUNECONFLICTS[v9.1] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0"
57TUNECONFLICTS[v9.2] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1"
58TUNECONFLICTS[v9.3] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2"
59TUNECONFLICTS[v9.4] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3"
60TUNECONFLICTS[v9.5] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4"
61TUNECONFLICTS[v9.6] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4 v9.5"
62TUNECONFLICTS[v10.0] = "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.1 v9.2 v9.3 v9.4 v9.5 v9.6"
63
64# Version flags
65TUNE_CCARGS += "-mcpu=${@microblaze_current_version(d, True)}"
66MBPKGARCH_VERSION = "-${@microblaze_current_version(d)}"
67
diff --git a/conf/machine/include/tune-microblaze.inc b/conf/machine/include/tune-microblaze.inc
deleted file mode 100644
index 835de41b..00000000
--- a/conf/machine/include/tune-microblaze.inc
+++ /dev/null
@@ -1,19 +0,0 @@
1DEFAULTTUNE ?= "microblaze"
2
3require conf/machine/include/microblaze/arch-microblaze.inc
4
5AVAILTUNES += "microblaze"
6TUNE_FEATURES_tune-microblaze = "microblaze"
7PACKAGE_EXTRA_ARCHS_tune-microblaze = "${TUNE_PKGARCH}"
8
9# Linux Configuration
10KERNEL_IMAGETYPE ?= "linux.bin.ub"
11
12# U-Boot Configuration
13UBOOT_MACHINE ?= "microblaze-generic_config"
14
15# default to use the gdb 7.7.1
16PREFERRED_VERSION_gdb ?= "7.7.1"
17PREFERRED_VERSION_gdb-cross ?= "7.7.1"
18PREFERRED_VERSION_gdb-cross-canadian ?= "7.7.1"
19
diff --git a/conf/machine/include/tune-zynq.inc b/conf/machine/include/tune-zynq.inc
deleted file mode 100644
index 19e73412..00000000
--- a/conf/machine/include/tune-zynq.inc
+++ /dev/null
@@ -1,12 +0,0 @@
1DEFAULTTUNE ?= "cortexa9thf-neon"
2SOC_FAMILY ?= "zynq"
3
4require conf/machine/include/tune-cortexa9.inc
5require conf/machine/include/soc-family.inc
6
7# Linux Configuration
8KERNEL_IMAGETYPE ?= "uImage"
9
10# Set default load address.
11# Override with KERNEL_EXTRA_ARGS_<board> += "..." in machine file if required
12KERNEL_EXTRA_ARGS_zynq += "UIMAGE_LOADADDR=0x8000"
diff --git a/conf/machine/include/tune-zynqmp.inc b/conf/machine/include/tune-zynqmp.inc
deleted file mode 100644
index 8d1f9537..00000000
--- a/conf/machine/include/tune-zynqmp.inc
+++ /dev/null
@@ -1,11 +0,0 @@
1DEFAULTTUNE ?= "aarch64"
2SOC_FAMILY ?= "zynqmp"
3
4require conf/machine/include/arm/arch-armv8.inc
5require conf/machine/include/soc-family.inc
6
7# Linux Configuration
8KERNEL_IMAGETYPE ?= "Image"
9
10# Support multilib on zynqmp
11DEFAULTTUNE_virtclass-multilib-lib32 ?= "armv7vethf-neon-vfpv4"
diff --git a/conf/machine/include/zynqmp-pmu-config.inc b/conf/machine/include/zynqmp-pmu-config.inc
deleted file mode 100644
index fd9e9809..00000000
--- a/conf/machine/include/zynqmp-pmu-config.inc
+++ /dev/null
@@ -1,20 +0,0 @@
1
2# Enable the use of zynqmp-pmu for specific recipes only
3def zynqmp_pmu_enable_for_bpns(d):
4 bpn = d.getVar("BPN")
5 crossbpns = ["binutils", "gcc"]
6 targetbpns = ["libgcc", "newlib", "libgloss"]
7 if bpn in targetbpns:
8 return True
9 if bpn in crossbpns and bb.data.inherits_class('cross', d):
10 return True
11 return False
12
13BBCLASSEXTEND_append = "${@' zynqmp-pmu' if zynqmp_pmu_enable_for_bpns(d) else ''}"
14
15# Add the pkgarch to the extra list, this is done to avoid warnings about
16# missing manifests due to implicit dependency chains on populate_sysroot when
17# a recipe/task depends on a IMAGE_EXTRADEPENDS/do_deploy task which is
18# provided by a zynqmp-pmu-* target.
19PACKAGE_EXTRA_ARCHS_append = " microblazeel-v9.2-bs-cmp"
20
diff --git a/conf/machine/kc705-microblazeel.conf b/conf/machine/kc705-microblazeel.conf
deleted file mode 100644
index 658b75be..00000000
--- a/conf/machine/kc705-microblazeel.conf
+++ /dev/null
@@ -1,20 +0,0 @@
1#@TYPE: Machine
2#@NAME: kc705-microblazeel
3#@DESCRIPTION: Machine support for Xilinx KC705 Embedded Kit.
4#
5
6require conf/machine/include/tune-microblaze.inc
7require conf/machine/include/machine-xilinx-default.inc
8require conf/machine/include/machine-xilinx-board.inc
9
10TUNE_FEATURES_tune-microblaze += "v10.0 barrel-shift reorder pattern-compare multiply-high divide-hard"
11
12MACHINE_FEATURES = ""
13
14USE_VT = ""
15SERIAL_CONSOLE = "115200 ttyS0"
16
17MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "device-tree"
18
19EXTRA_IMAGEDEPENDS += "virtual/bitstream"
20
diff --git a/conf/machine/microzed-zynq7.conf b/conf/machine/microzed-zynq7.conf
deleted file mode 100644
index 815bf474..00000000
--- a/conf/machine/microzed-zynq7.conf
+++ /dev/null
@@ -1,30 +0,0 @@
1#@TYPE: Machine
2#@NAME: microzed-zynq7
3#@DESCRIPTION: Machine support for microZed. (http://www.microzed.org/)
4
5require conf/machine/include/tune-zynq.inc
6require conf/machine/include/machine-xilinx-default.inc
7require conf/machine/include/machine-xilinx-board.inc
8
9MACHINE_FEATURES = "ext2 vfat usbhost"
10
11# u-boot configuration
12PREFERRED_PROVIDER_virtual/bootloader = "u-boot"
13UBOOT_MACHINE = "zynq_microzed_config"
14SPL_BINARY = "spl/boot.bin"
15
16EXTRA_IMAGEDEPENDS += " \
17 u-boot-zynq-uenv \
18 virtual/boot-bin \
19 "
20
21SERIAL_CONSOLE = "115200 ttyPS0"
22
23MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "device-tree"
24
25IMAGE_BOOT_FILES += " \
26 boot.bin \
27 ${MACHINE}.dtb \
28 uEnv.txt \
29 "
30
diff --git a/conf/machine/ml605-qemu-microblazeel.conf b/conf/machine/ml605-qemu-microblazeel.conf
deleted file mode 100644
index 2092801e..00000000
--- a/conf/machine/ml605-qemu-microblazeel.conf
+++ /dev/null
@@ -1,25 +0,0 @@
1#@TYPE: Machine
2#@NAME: ml605-qemu-microblazeel
3#@DESCRIPTION: MicroBlaze QEMU machine support ('petalogix-ml605' model)
4
5require conf/machine/include/tune-microblaze.inc
6require conf/machine/include/machine-xilinx-default.inc
7require conf/machine/include/machine-xilinx-qemu.inc
8
9TUNE_FEATURES_tune-microblaze += "v8.50 barrel-shift reorder pattern-compare divide-hard multiply-high fpu-hard"
10
11MACHINE_FEATURES = ""
12
13USE_VT = ""
14SERIAL_CONSOLE = "115200 ttyS0"
15
16# Use the networking setup from qemuarm
17FILESOVERRIDES_append_pn-init-ifupdown = ":qemuarm"
18
19# This machine is a targeting a QEMU model, runqemu setup:
20IMAGE_CLASSES += "qemuboot"
21QB_MEM = "-m 256"
22QB_MACHINE = "-machine petalogix-ml605"
23QB_OPT_APPEND = "-nographic -serial mon:stdio"
24QB_NETWORK_DEVICE = "-net nic,netdev=net0,macaddr=@MAC@"
25
diff --git a/conf/machine/picozed-zynq7.conf b/conf/machine/picozed-zynq7.conf
deleted file mode 100644
index 59b4a6cb..00000000
--- a/conf/machine/picozed-zynq7.conf
+++ /dev/null
@@ -1,34 +0,0 @@
1#@TYPE: Machine
2#@NAME: picozed-zynq7
3#@DESCRIPTION: Machine support for picoZed. (http://www.picozed.org/)
4#
5# Note: This machine configuration is intended as a generic config for
6# the picozed SOM. It also covers the multiple SKUs for the picoZed
7# including 7010, 7020, 7015 and 7030.
8
9require conf/machine/include/tune-zynq.inc
10require conf/machine/include/machine-xilinx-default.inc
11require conf/machine/include/machine-xilinx-board.inc
12
13MACHINE_FEATURES = "ext2 vfat usbhost usbgadget"
14
15# u-boot configuration
16PREFERRED_PROVIDER_virtual/bootloader = "u-boot"
17UBOOT_MACHINE = "zynq_picozed_config"
18SPL_BINARY = "spl/boot.bin"
19
20EXTRA_IMAGEDEPENDS += " \
21 u-boot-zynq-uenv \
22 virtual/boot-bin \
23 "
24
25SERIAL_CONSOLE = "115200 ttyPS0"
26
27MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "device-tree"
28
29IMAGE_BOOT_FILES += " \
30 boot.bin \
31 ${MACHINE}.dtb \
32 uEnv.txt \
33 "
34
diff --git a/conf/machine/qemu-zynq7.conf b/conf/machine/qemu-zynq7.conf
deleted file mode 100644
index 0fe99e27..00000000
--- a/conf/machine/qemu-zynq7.conf
+++ /dev/null
@@ -1,25 +0,0 @@
1#@TYPE: Machine
2#@NAME: qemu-zynq7
3#@DESCRIPTION: Zynq QEMU machine support ('xilinx-zynq-a9' model)
4
5require conf/machine/include/tune-zynq.inc
6require conf/machine/include/machine-xilinx-default.inc
7require conf/machine/include/machine-xilinx-qemu.inc
8
9MACHINE_FEATURES = "ext2 vfat"
10
11SERIAL_CONSOLE = "115200 ttyPS0"
12
13MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "device-tree"
14IMAGE_BOOT_FILES += "${MACHINE}.dtb"
15
16# Use the networking setup from qemuarm
17FILESOVERRIDES_append_pn-init-ifupdown = ":qemuarm"
18
19# This machine is a targeting a QEMU model, runqemu setup:
20IMAGE_CLASSES += "qemuboot"
21QB_MEM = "-m 1024"
22QB_MACHINE = "-machine xilinx-zynq-a9"
23QB_OPT_APPEND = "-nographic -serial null -serial mon:stdio"
24QB_NETWORK_DEVICE = "-net nic,netdev=net0,macaddr=@MAC@"
25
diff --git a/conf/machine/s3adsp1800-qemu-microblazeeb.conf b/conf/machine/s3adsp1800-qemu-microblazeeb.conf
deleted file mode 100644
index 6bd75417..00000000
--- a/conf/machine/s3adsp1800-qemu-microblazeeb.conf
+++ /dev/null
@@ -1,24 +0,0 @@
1#@TYPE: Machine
2#@NAME: s3adsp1800-qemu-microblazeeb
3#@DESCRIPTION: MicroBlaze QEMU machine support ('petalogix-s3adsp1800' model)
4
5require conf/machine/include/tune-microblaze.inc
6require conf/machine/include/machine-xilinx-default.inc
7require conf/machine/include/machine-xilinx-qemu.inc
8
9TUNE_FEATURES_tune-microblaze += "v8.00 bigendian barrel-shift pattern-compare multiply-low"
10
11MACHINE_FEATURES = ""
12
13USE_VT = ""
14SERIAL_CONSOLE = "115200 ttyUL0"
15
16MACHINE_ESSENTIAL_EXTRA_RDEPENDS_remove = "device-tree"
17
18# This machine is a targeting a QEMU model, runqemu setup:
19IMAGE_CLASSES += "qemuboot"
20QB_MEM = "-m 256"
21QB_MACHINE = "-machine petalogix-s3adsp1800"
22QB_OPT_APPEND = "-nographic -serial mon:stdio"
23QB_NETWORK_DEVICE = "-net nic,netdev=net0,macaddr=@MAC@"
24
diff --git a/conf/machine/zc702-zynq7.conf b/conf/machine/zc702-zynq7.conf
deleted file mode 100644
index 57877bfa..00000000
--- a/conf/machine/zc702-zynq7.conf
+++ /dev/null
@@ -1,45 +0,0 @@
1#@TYPE: Machine
2#@NAME: zc702-zynq7
3#@DESCRIPTION: Machine support for ZC702 Evaluation Board.
4#
5# For details on the Evaluation board:
6# http://www.xilinx.com/products/boards-and-kits/EK-Z7-ZC702-G.htm
7# For documentation and design files for the ZC702:
8# http://www.xilinx.com/support/index.html/content/xilinx/en/supportNav/boards_and_kits/zynq-7000_soc_boards_and_kits/zynq-7000_soc_zc702_evaluation_kit.html
9# For the FSBL 'zynq_fsbl_0.elf' refer to UG873 and the associated design files.
10#
11
12require conf/machine/include/tune-zynq.inc
13require conf/machine/include/machine-xilinx-default.inc
14require conf/machine/include/machine-xilinx-board.inc
15require conf/machine/include/machine-xilinx-qemu.inc
16
17MACHINE_FEATURES = "rtc ext2 ext3 vfat usbhost"
18
19# u-boot configuration
20UBOOT_MACHINE = "zynq_zc702_config"
21SPL_BINARY = "spl/boot.bin"
22
23EXTRA_IMAGEDEPENDS += " \
24 u-boot-zynq-uenv \
25 virtual/boot-bin \
26 "
27
28SERIAL_CONSOLE = "115200 ttyPS0"
29
30KERNEL_DEVICETREE = "zynq-zc702.dtb"
31
32IMAGE_BOOT_FILES += "boot.bin uEnv.txt ${KERNEL_IMAGETYPE}-zynq-zc702.dtb"
33
34# Although not fully supported you can run this machine on the mainline QEMU 'xilinx-zynq-a9' machine
35IMAGE_CLASSES += "qemuboot"
36QB_MEM = "-m 1024"
37QB_MACHINE = "-machine xilinx-zynq-a9"
38QB_OPT_APPEND = "-nographic -serial null -serial mon:stdio"
39QB_NETWORK_DEVICE = "-net nic,netdev=net0,macaddr=@MAC@"
40
41# Xilinx's fork of QEMU has much better results, so let's default to that
42# Use qemu-xilinx instead of mainline
43PREFERRED_PROVIDER_qemu-helper-native = "qemu-xilinx-helper-native"
44
45IMAGE_CLASSES += "qemuboot-xilinx"
diff --git a/conf/machine/zc706-zynq7.conf b/conf/machine/zc706-zynq7.conf
deleted file mode 100644
index d2fbf1b1..00000000
--- a/conf/machine/zc706-zynq7.conf
+++ /dev/null
@@ -1,49 +0,0 @@
1#@TYPE: Machine
2#@NAME: zc706-zynq7
3#@DESCRIPTION: Machine support for ZC706 Evaluation Board.
4#
5# For details on the Evaluation board:
6# http://www.xilinx.com/products/boards-and-kits/EK-Z7-ZC706-G.htm
7# For documentation and design files for the ZC702:
8# http://www.xilinx.com/support/index.html/content/xilinx/en/supportNav/boards_and_kits/zynq-7000_soc_boards_and_kits/zynq-7000_soc_zc706_evaluation_kit.html
9# For the FSBL 'zynq_fsbl_0.elf' refer to UG873 and the associated design files.
10#
11
12require conf/machine/include/tune-zynq.inc
13require conf/machine/include/machine-xilinx-default.inc
14require conf/machine/include/machine-xilinx-board.inc
15require conf/machine/include/machine-xilinx-qemu.inc
16
17MACHINE_FEATURES = "rtc ext2 ext3 vfat usbhost usbgadget"
18
19# u-boot configuration
20UBOOT_MACHINE = "zynq_zc706_config"
21SPL_BINARY = "spl/boot.bin"
22
23EXTRA_IMAGEDEPENDS += " \
24 u-boot-zynq-uenv \
25 virtual/boot-bin \
26 "
27
28SERIAL_CONSOLE = "115200 ttyPS0"
29
30KERNEL_DEVICETREE = "zynq-zc706.dtb"
31
32IMAGE_BOOT_FILES += " \
33 boot.bin \
34 ${KERNEL_IMAGETYPE}-zynq-zc706.dtb \
35 uEnv.txt \
36 "
37
38# Although not fully supported you can run this machine on the mainline QEMU 'xilinx-zynq-a9' machine
39IMAGE_CLASSES += "qemuboot"
40QB_MEM = "-m 1024"
41QB_MACHINE = "-machine xilinx-zynq-a9"
42QB_OPT_APPEND = "-nographic -serial null -serial mon:stdio"
43QB_NETWORK_DEVICE = "-net nic,netdev=net0,macaddr=@MAC@"
44
45# Xilinx's fork of QEMU has much better results, so let's default to that
46# Use qemu-xilinx instead of mainline
47PREFERRED_PROVIDER_qemu-helper-native = "qemu-xilinx-helper-native"
48
49IMAGE_CLASSES += "qemuboot-xilinx"
diff --git a/conf/machine/zcu102-zynqmp.conf b/conf/machine/zcu102-zynqmp.conf
deleted file mode 100644
index fe411483..00000000
--- a/conf/machine/zcu102-zynqmp.conf
+++ /dev/null
@@ -1,77 +0,0 @@
1#@TYPE: Machine
2#@NAME: zcu102-zynqmp
3#@DESCRIPTION: Machine support for ZCU102 Evaluation Board.
4
5require conf/machine/include/tune-zynqmp.inc
6require conf/machine/include/machine-xilinx-default.inc
7require conf/machine/include/machine-xilinx-board.inc
8require conf/machine/include/machine-xilinx-qemu.inc
9include conf/machine/include/zynqmp-pmu-config.inc
10
11MACHINE_FEATURES = "rtc ext2 ext3 vfat usbhost"
12
13UBOOT_MACHINE = "xilinx_zynqmp_zcu102_rev1_0_defconfig"
14SPL_BINARY = "spl/boot.bin"
15
16# Default SD image build onfiguration, use qemu-sd to pad
17IMAGE_CLASSES += "image-types-xilinx-qemu"
18IMAGE_FSTYPES += "wic.qemu-sd"
19WKS_FILES ?= "sdimage-bootpart.wks"
20
21SERIAL_CONSOLE = "115200 ttyPS0"
22SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
23
24KERNEL_DEVICETREE = "xilinx/zynqmp-zcu102-rev1.0.dtb"
25
26PREFERRED_PROVIDER_virtual/kernel ?= "linux-xlnx"
27PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot-xlnx"
28PREFERRED_PROVIDER_virtual/pmu-firmware ?= "zynqmp-pmu-pmu-firmware"
29
30EXTRA_IMAGEDEPENDS += " \
31 u-boot-zynq-uenv \
32 arm-trusted-firmware \
33 qemu-devicetrees \
34 virtual/pmu-firmware \
35 virtual/boot-bin \
36 "
37
38IMAGE_BOOT_FILES += "uEnv.txt atf-uboot.ub ${KERNEL_IMAGETYPE}-zynqmp-zcu102-rev1.0.dtb"
39
40# This machine has a QEMU model, runqemu setup:
41IMAGE_CLASSES += "qemuboot-xilinx"
42QB_MACHINE = "-machine xlnx-zcu102"
43QB_MEM = "-m 4096"
44QB_OPT_APPEND = "-nographic -serial mon:stdio -serial null"
45QB_NETWORK_DEVICE = "-net nic -net nic -net nic -net nic,netdev=net0,macaddr=@MAC@"
46
47# Use qemu-xilinx instead of mainline
48PREFERRED_PROVIDER_qemu-helper-native = "qemu-xilinx-helper-native"
49
50# Use the multiarch script instead of launching QEMU directly
51QB_SYSTEM_NAME_append = "-multiarch"
52
53# Replicate BootROM like behaviour, having loaded SPL and PMU(ROM+FW)
54QB_OPT_APPEND_append_qemuboot-xilinx = " \
55 -hw-dtb ${DEPLOY_DIR_IMAGE}/qemu-hw-devicetrees/multiarch/zcu102-arm.dtb \
56 ${@qemu_zynqmp_unhalt(d, True)} \
57 -device loader,addr=0xfffc0000,file=${DEPLOY_DIR_IMAGE}/u-boot-spl.bin,cpu-num=0 \
58 "
59
60# Attach the rootfs disk image to the second SD interface of QEMU (which is SD0)
61QB_DEFAULT_FSTYPE_qemuboot-xilinx = "wic.qemu-sd"
62QB_OPT_APPEND_append_qemuboot-xilinx = " -boot mode=3"
63QB_ROOTFS_OPT_qemuboot-xilinx = " -drive if=sd,index=1,file=@ROOTFS@,format=raw"
64
65# PMU instance args
66PMU_ROM ?= "${DEPLOY_DIR_IMAGE}/pmu-rom.elf"
67QB_PMU_OPT = " \
68 -M microblaze-fdt \
69 -display none \
70 -hw-dtb ${DEPLOY_DIR_IMAGE}/qemu-hw-devicetrees/multiarch/zynqmp-pmu.dtb \
71 -kernel ${PMU_ROM} \
72 -device loader,file=${DEPLOY_DIR_IMAGE}/pmu-${MACHINE}.elf \
73 -device loader,addr=0xfd1a0074,data=0x1011003,data-len=4 \
74 -device loader,addr=0xfd1a007C,data=0x1010f03,data-len=4 \
75 "
76QB_OPT_APPEND_append_qemuboot-xilinx = " -pmu-args '${QB_PMU_OPT}'"
77
diff --git a/conf/machine/zedboard-zynq7.conf b/conf/machine/zedboard-zynq7.conf
deleted file mode 100644
index 114927de..00000000
--- a/conf/machine/zedboard-zynq7.conf
+++ /dev/null
@@ -1,29 +0,0 @@
1#@TYPE: Machine
2#@NAME: zedboard-zynq7
3#@DESCRIPTION: Machine support for ZedBoard. (http://www.zedboard.org/)
4#
5# For details on the Evaluation board:
6# http://www.zedboard.org/content/overview
7# For design files (including 'zynq_fsbl_0.elf') for the ZedBoard:
8# http://www.zedboard.org/reference-designs-categories/zynq-concepts-tools-and-techniques-zedboard
9#
10
11require conf/machine/include/tune-zynq.inc
12require conf/machine/include/machine-xilinx-default.inc
13require conf/machine/include/machine-xilinx-board.inc
14
15# u-boot configuration
16UBOOT_MACHINE = "zynq_zed_config"
17SPL_BINARY = "spl/boot.bin"
18
19EXTRA_IMAGEDEPENDS += " \
20 u-boot-zynq-uenv \
21 virtual/boot-bin \
22 "
23
24SERIAL_CONSOLE = "115200 ttyPS0"
25
26KERNEL_DEVICETREE = "zynq-zed.dtb"
27
28IMAGE_BOOT_FILES += "boot.bin uEnv.txt ${KERNEL_IMAGETYPE}-zynq-zed.dtb"
29
diff --git a/conf/machine/zybo-linux-bd-zynq7.conf b/conf/machine/zybo-linux-bd-zynq7.conf
deleted file mode 100644
index b916a209..00000000
--- a/conf/machine/zybo-linux-bd-zynq7.conf
+++ /dev/null
@@ -1,40 +0,0 @@
1#@TYPE: Machine
2#@NAME: zybo-linux-bd-zynq7
3#@DESCRIPTION: Machine support for zybo-linux-bd project.
4#
5# generated base on ZYBO linux-bd project
6#
7
8require conf/machine/include/tune-zynq.inc
9require conf/machine/include/machine-xilinx-default.inc
10require conf/machine/include/machine-xilinx-board.inc
11
12PREFERRED_PROVIDER_virtual/kernel ?= "linux-xlnx"
13PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot"
14
15MACHINE_FEATURES = "ext2 vfat usbhost usbgadget keyboard screen alsa sdio"
16SERIAL_CONSOLE = "115200 ttyPS0"
17
18MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "device-tree"
19
20UBOOT_MACHINE = "zynq_zybo_config"
21SPL_BINARY = "spl/boot.bin"
22FORCE_PLATFORM_INIT = "1"
23
24EXTRA_IMAGEDEPENDS += " \
25 u-boot-zynq-uenv \
26 virtual/boot-bin \
27 virtual/bitstream \
28 "
29
30IMAGE_BOOT_FILES += " \
31 boot.bin \
32 ${MACHINE}.dtb \
33 bitstream \
34 uEnv.txt \
35 "
36
37KERNEL_FEATURES += " \
38 bsp/zybo-linux-bd-zynq7/zybo-linux-bd-zynq7.scc \
39 features/v4l2/v4l2-xilinx.scc \
40 "
diff --git a/conf/machine/zybo-zynq7.conf b/conf/machine/zybo-zynq7.conf
deleted file mode 100644
index e94ad6b9..00000000
--- a/conf/machine/zybo-zynq7.conf
+++ /dev/null
@@ -1,34 +0,0 @@
1#@TYPE: Machine
2#@NAME: zybo-zynq7
3#@DESCRIPTION: Machine support for ZYBO.
4#
5# For details on the ZYBO board:
6# https://www.digilentinc.com/Products/Detail.cfm?Prod=ZYBO
7#
8
9require conf/machine/include/tune-zynq.inc
10require conf/machine/include/machine-xilinx-default.inc
11require conf/machine/include/machine-xilinx-board.inc
12
13MACHINE_FEATURES = "ext2 vfat usbhost usbgadget"
14
15# u-boot configuration
16PREFERRED_PROVIDER_virtual/bootloader = "u-boot"
17UBOOT_MACHINE = "zynq_zybo_config"
18SPL_BINARY = "spl/boot.bin"
19
20EXTRA_IMAGEDEPENDS += " \
21 u-boot-zynq-uenv \
22 virtual/boot-bin \
23 "
24
25SERIAL_CONSOLE = "115200 ttyPS0"
26
27KERNEL_DEVICETREE = "zynq-zybo.dtb"
28
29IMAGE_BOOT_FILES += " \
30 boot.bin \
31 ${KERNEL_IMAGETYPE}-zynq-zybo.dtb \
32 uEnv.txt \
33 "
34
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-05-07 23:15:10 +0000