diff options
author | Bruce Ashfield <bruce.ashfield@gmail.com> | 2024-03-14 18:08:37 +0000 |
---|---|---|
committer | Bruce Ashfield <bruce.ashfield@gmail.com> | 2024-03-15 17:17:20 +0000 |
commit | c20d1585243e04a29d30c16f9ba7f6e592194321 (patch) | |
tree | 1ea4dcb8bf9f8942ba6a6531050bad7a1153952f /recipes-extended/ceph/ceph_18.2.2.bb | |
parent | 21b439042b2e3d715e21f6777127f2ee6f58ea95 (diff) | |
download | meta-virtualization-c20d1585243e04a29d30c16f9ba7f6e592194321.tar.gz |
ceph: update to 18.2.2
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Diffstat (limited to 'recipes-extended/ceph/ceph_18.2.2.bb')
-rw-r--r-- | recipes-extended/ceph/ceph_18.2.2.bb | 177 |
1 files changed, 177 insertions, 0 deletions
diff --git a/recipes-extended/ceph/ceph_18.2.2.bb b/recipes-extended/ceph/ceph_18.2.2.bb new file mode 100644 index 00000000..e6c44188 --- /dev/null +++ b/recipes-extended/ceph/ceph_18.2.2.bb | |||
@@ -0,0 +1,177 @@ | |||
1 | SUMMARY = "User space components of the Ceph file system" | ||
2 | LICENSE = "LGPL-2.1-only & GPL-2.0-only & Apache-2.0 & MIT" | ||
3 | LIC_FILES_CHKSUM = "file://COPYING-LGPL2.1;md5=fbc093901857fcd118f065f900982c24 \ | ||
4 | file://COPYING-GPL2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ | ||
5 | file://COPYING;md5=5351120989d78252e65dc1a2a92e3617 \ | ||
6 | " | ||
7 | inherit cmake pkgconfig python3native python3-dir systemd useradd | ||
8 | # Disable python pybind support for ceph temporary, when corss compiling pybind, | ||
9 | # pybind mix cmake and python setup environment, would case a lot of errors. | ||
10 | |||
11 | SRC_URI = "http://download.ceph.com/tarballs/ceph-${PV}.tar.gz \ | ||
12 | file://0001-fix-host-library-paths-were-used.patch \ | ||
13 | file://ceph.conf \ | ||
14 | file://0001-avoid-to_string-error.patch \ | ||
15 | file://0001-delete-install-layout-deb.patch \ | ||
16 | file://0001-cephadm-build.py-avoid-using-python3-from-sysroot-wh.patch \ | ||
17 | " | ||
18 | |||
19 | SRC_URI[sha256sum] = "e70bb5246b4a5d7aa78eb548677a05cc21d0d47945ba2937fddc7511134ffb57" | ||
20 | |||
21 | DEPENDS = "boost bzip2 curl cryptsetup expat gperf-native \ | ||
22 | keyutils libaio libibverbs lua lz4 \ | ||
23 | nspr nss ninja-native \ | ||
24 | oath openldap openssl \ | ||
25 | python3 python3-native python3-cython-native python3-pyyaml-native \ | ||
26 | rabbitmq-c rocksdb snappy thrift udev \ | ||
27 | valgrind xfsprogs zlib libgcc zstd re2 \ | ||
28 | " | ||
29 | |||
30 | |||
31 | OECMAKE_C_COMPILER = "${@oecmake_map_compiler('CC', d)[0]} --sysroot=${RECIPE_SYSROOT}" | ||
32 | OECMAKE_CXX_COMPILER = "${@oecmake_map_compiler('CXX', d)[0]} --sysroot=${RECIPE_SYSROOT}" | ||
33 | |||
34 | USERADD_PACKAGES = "${PN}" | ||
35 | USERADD_PARAM:${PN} = "--system --user-group --home-dir /var/lib/ceph --shell /sbin/nologin ceph" | ||
36 | |||
37 | SYSTEMD_SERVICE:${PN} = " \ | ||
38 | ceph-radosgw@.service \ | ||
39 | ceph-radosgw.target \ | ||
40 | ceph-mon@.service \ | ||
41 | ceph-mon.target \ | ||
42 | ceph-mds@.service \ | ||
43 | ceph-mds.target \ | ||
44 | ceph-osd@.service \ | ||
45 | ceph-osd.target \ | ||
46 | cephfs-mirror@.service \ | ||
47 | cephfs-mirror.target \ | ||
48 | ceph.target \ | ||
49 | ceph-rbd-mirror@.service \ | ||
50 | ceph-rbd-mirror.target \ | ||
51 | ceph-volume@.service \ | ||
52 | ceph-mgr@.service \ | ||
53 | ceph-mgr.target \ | ||
54 | ceph-crash.service \ | ||
55 | rbdmap.service \ | ||
56 | ceph-immutable-object-cache@.service \ | ||
57 | ceph-immutable-object-cache.target \ | ||
58 | " | ||
59 | |||
60 | EXTRA_OECMAKE += "-DWITH_MANPAGE=OFF \ | ||
61 | -DWITH_JAEGER=OFF \ | ||
62 | -DWITH_SYSTEM_ZSTD=ON \ | ||
63 | -DWITH_FUSE=OFF \ | ||
64 | -DWITH_SPDK=OFF \ | ||
65 | -DWITH_LEVELDB=OFF \ | ||
66 | -DWITH_LTTNG=OFF \ | ||
67 | -DWITH_BABELTRACE=OFF \ | ||
68 | -DWITH_TESTS=OFF \ | ||
69 | -DWITH_RADOSGW_SELECT_PARQUET=OFF \ | ||
70 | -DWITH_RADOSGW_ARROW_FLIGHT=OFF \ | ||
71 | -DWITH_MGR=OFF \ | ||
72 | -DWITH_MGR_DASHBOARD_FRONTEND=OFF \ | ||
73 | -DWITH_SYSTEM_BOOST=ON \ | ||
74 | -DWITH_SYSTEM_ROCKSDB=ON \ | ||
75 | -DWITH_RDMA=OFF \ | ||
76 | -DWITH_RADOSGW_AMQP_ENDPOINT=OFF \ | ||
77 | -DWITH_RADOSGW_KAFKA_ENDPOINT=OFF \ | ||
78 | -DWITH_REENTRANT_STRSIGNAL=ON \ | ||
79 | -DWITH_PYTHON3=3.12 \ | ||
80 | -DPYTHON_DESIRED=3 \ | ||
81 | -DCMAKE_TOOLCHAIN_FILE:FILEPATH=${WORKDIR}/toolchain.cmake \ | ||
82 | " | ||
83 | |||
84 | do_configure:prepend () { | ||
85 | echo "set( CMAKE_SYSROOT \"${RECIPE_SYSROOT}\" )" >> ${WORKDIR}/toolchain.cmake | ||
86 | echo "set( CMAKE_DESTDIR \"${D}\" )" >> ${WORKDIR}/toolchain.cmake | ||
87 | echo "set( PYTHON_SITEPACKAGES_DIR \"${PYTHON_SITEPACKAGES_DIR}\" )" >> ${WORKDIR}/toolchain.cmake | ||
88 | # echo "set( CMAKE_C_COMPILER_WORKS TRUE)" >> ${WORKDIR}/toolchain.cmake | ||
89 | # echo "set( CMAKE_CXX_COMPILER_FORCED TRUE)" >> ${WORKDIR}/toolchain.cmake | ||
90 | echo "set( CMAKE_C_COMPILER_FORCED TRUE )" >> ${WORKDIR}/toolchain.cmake | ||
91 | } | ||
92 | |||
93 | do_compile:prepend() { | ||
94 | export BUILD_DOC=1 | ||
95 | } | ||
96 | |||
97 | do_install:prepend() { | ||
98 | export BUILD_DOC=1 | ||
99 | } | ||
100 | |||
101 | do_install:append () { | ||
102 | sed -i -e 's:^#!/usr/bin/python$:&3:' \ | ||
103 | -e 's:${WORKDIR}.*python3:${bindir}/python3:' \ | ||
104 | ${D}${bindir}/ceph ${D}${bindir}/ceph-crash \ | ||
105 | ${D}${bindir}/cephfs-top \ | ||
106 | ${D}${sbindir}/ceph-volume ${D}${sbindir}/ceph-volume-systemd | ||
107 | find ${D} -name SOURCES.txt | xargs sed -i -e 's:${WORKDIR}::' | ||
108 | install -d ${D}${sysconfdir}/ceph | ||
109 | install -m 644 ${WORKDIR}/ceph.conf ${D}${sysconfdir}/ceph/ | ||
110 | install -d ${D}${systemd_unitdir} | ||
111 | mv ${D}${libexecdir}/ceph/ceph-osd-prestart.sh ${D}${libdir}/ceph | ||
112 | mv ${D}${libexecdir}/ceph/ceph_common.sh ${D}${libdir}/ceph | ||
113 | # WITH_FUSE is set to OFF, remove ceph-fuse related units | ||
114 | rm ${D}${systemd_unitdir}/system/ceph-fuse.target ${D}${systemd_unitdir}/system/ceph-fuse@.service | ||
115 | } | ||
116 | |||
117 | do_install:append:class-target () { | ||
118 | if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then | ||
119 | install -d ${D}${sysconfdir}/tmpfiles.d | ||
120 | echo "d /var/lib/ceph/crash/posted 0755 root root - -" > ${D}${sysconfdir}/tmpfiles.d/ceph-placeholder.conf | ||
121 | fi | ||
122 | |||
123 | if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then | ||
124 | install -d ${D}${sysconfdir}/default/volatiles | ||
125 | echo "d root root 0755 /var/lib/ceph/crash/posted none" > ${D}${sysconfdir}/default/volatiles/99_ceph-placeholder | ||
126 | fi | ||
127 | } | ||
128 | |||
129 | pkg_postinst:${PN}() { | ||
130 | if [ -z "$D" ] && [ -e ${sysconfdir}/init.d/populate-volatile.sh ] ; then | ||
131 | ${sysconfdir}/init.d/populate-volatile.sh update | ||
132 | fi | ||
133 | } | ||
134 | |||
135 | FILES:${PN} += "\ | ||
136 | ${libdir}/rados-classes/*.so.* \ | ||
137 | ${libdir}/ceph/compressor/*.so \ | ||
138 | ${libdir}/rados-classes/*.so \ | ||
139 | ${libdir}/ceph/*.so \ | ||
140 | ${libdir}/libcephsqlite.so \ | ||
141 | " | ||
142 | |||
143 | FILES:${PN} += " \ | ||
144 | /etc/tmpfiles.d/ceph-placeholder.conf \ | ||
145 | /etc/default/volatiles/99_ceph-placeholder \ | ||
146 | " | ||
147 | |||
148 | FILES:${PN}-dev = " \ | ||
149 | ${includedir} \ | ||
150 | ${libdir}/libcephfs.so \ | ||
151 | ${libdir}/librados*.so \ | ||
152 | ${libdir}/librbd.so \ | ||
153 | ${libdir}/librgw.so \ | ||
154 | " | ||
155 | |||
156 | FILES:${PN}-python = "\ | ||
157 | ${PYTHON_SITEPACKAGES_DIR}/* \ | ||
158 | " | ||
159 | RDEPENDS:${PN} += "\ | ||
160 | python3-core \ | ||
161 | python3-misc \ | ||
162 | python3-modules \ | ||
163 | python3-prettytable \ | ||
164 | ${PN}-python \ | ||
165 | gawk \ | ||
166 | bash \ | ||
167 | " | ||
168 | COMPATIBLE_HOST = "(x86_64).*" | ||
169 | PACKAGES += " \ | ||
170 | ${PN}-python \ | ||
171 | " | ||
172 | INSANE_SKIP:${PN}-python += "ldflags buildpaths" | ||
173 | INSANE_SKIP:${PN} += "dev-so" | ||
174 | INSANE_SKIP:${PN}-dbg += "buildpaths" | ||
175 | CCACHE_DISABLE = "1" | ||
176 | |||
177 | CVE_PRODUCT = "ceph ceph_storage ceph_storage_mon ceph_storage_osd" | ||