Merge pull request #473 from liuming50/thud-aktualizr-pkgconfig

Thud aktualizr pkgconfig

1 files changed, 44 insertions, 52 deletions

diff --git a/recipes-sota/aktualizr/aktualizr_git.bb b/recipes-sota/aktualizr/aktualizr_git.bb
index eb65ae0..fbc1bca 100755
--- a/recipes-sota/aktualizr/aktualizr_git.bb
+++ b/recipes-sota/aktualizr/aktualizr_git.bb
@@ -5,16 +5,12 @@ SECTION = "base"
 LICENSE = "MPL-2.0"
 LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
 
-DEPENDS = "boost curl openssl libarchive libsodium asn1c-native sqlite3 "
-DEPENDS_append_class-target = "ostree ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' libp11', '', d)} "
-DEPENDS_append_class-native = "glib-2.0-native "
-
-RDEPENDS_${PN}_class-target = "lshw "
-RDEPENDS_${PN}_append_class-target = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'serialcan', ' slcand-start', '', d)} "
-RDEPENDS_${PN}_append_class-target = " ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'ubootenv', ' u-boot-fw-utils aktualizr-uboot-env-rollback', '', d)} "
+require garage-sign-version.inc
 
-RDEPENDS_${PN}_append_class-target = " ${PN}-tools "
-RDEPENDS_${PN}-secondary_append_class-target = " ${PN}-tools "
+DEPENDS = "boost curl openssl libarchive libsodium sqlite3 asn1c-native"
+RDEPENDS_${PN}_class-target = "aktualizr-check-discovery aktualizr-configs lshw"
+RDEPENDS_${PN}-secondary = "aktualizr-check-discovery"
+RDEPENDS_${PN}-host-tools = "aktualizr aktualizr-repo aktualizr-cert-provider ${@bb.utils.contains('PACKAGECONFIG', 'sota-tools', 'garage-deploy garage-push', '', d)}"
 
 PV = "1.0+git${SRCPV}"
 PR = "7"
@@ -32,29 +28,28 @@ BRANCH ?= "master"
 
 S = "${WORKDIR}/git"
 
-inherit cmake
-
-inherit systemd
+inherit pkgconfig cmake systemd
 
 SYSTEMD_PACKAGES = "${PN} ${PN}-secondary"
 SYSTEMD_SERVICE_${PN} = "aktualizr.service"
 SYSTEMD_SERVICE_${PN}-secondary = "aktualizr-secondary.socket"
 
-BBCLASSEXTEND =+ "native"
+EXTRA_OECMAKE = "-DCMAKE_BUILD_TYPE=Release -DAKTUALIZR_VERSION=${PV}"
 
-require garage-sign-version.inc
+GARAGE_SIGN_OPS = "${@ '-DGARAGE_SIGN_VERSION=%s' % d.getVar('GARAGE_SIGN_VERSION') if d.getVar('GARAGE_SIGN_VERSION') is not None else ''} \
+                   ${@ '-DGARAGE_SIGN_SHA256=%s' % d.getVar('GARAGE_SIGN_SHA256') if d.getVar('GARAGE_SIGN_SHA256') is not None else ''} \
+                  "
 
-EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF \
-                 -DCMAKE_BUILD_TYPE=Release \
-                 -DAKTUALIZR_VERSION=${PV} \
-                 -DBUILD_LOAD_TESTS=OFF"
-EXTRA_OECMAKE_append_class-target = " -DBUILD_OSTREE=ON \
-                                      ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', '-DBUILD_P11=ON', '', d)} "
-EXTRA_OECMAKE_append_class-native = " -DBUILD_SOTA_TOOLS=ON \
-                                      -DBUILD_OSTREE=OFF \
-                                      -DBUILD_SYSTEMD=OFF \
-                                      -DGARAGE_SIGN_VERSION=${GARAGE_SIGN_VERSION} \
-                                      -DGARAGE_SIGN_SHA256=${GARAGE_SIGN_SHA256}"
+PACKAGECONFIG ?= "ostree ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} ${@bb.utils.filter('SOTA_CLIENT_FEATURES', 'hsm serialcan ubootenv', d)}"
+PACKAGECONFIG_class-native = "sota-tools"
+PACKAGECONFIG[warning-as-error] = "-DWARNING_AS_ERROR=ON,-DWARNING_AS_ERROR=OFF,"
+PACKAGECONFIG[ostree] = "-DBUILD_OSTREE=ON,-DBUILD_OSTREE=OFF,ostree,"
+PACKAGECONFIG[hsm] = "-DBUILD_P11=ON,-DBUILD_P11=OFF,libp11,"
+PACKAGECONFIG[sota-tools] = "-DBUILD_SOTA_TOOLS=ON ${GARAGE_SIGN_OPS},-DBUILD_SOTA_TOOLS=OFF,glib-2.0,"
+PACKAGECONFIG[systemd] = "-DBUILD_SYSTEMD=ON,-DBUILD_SYSTEMD=OFF,systemd,"
+PACKAGECONFIG[load-tests] = "-DBUILD_LOAD_TESTS=ON,-DBUILD_LOAD_TESTS=OFF,"
+PACKAGECONFIG[serialcan] = ",,,slcand-start"
+PACKAGECONFIG[ubootenv] = ",,,u-boot-fw-utils aktualizr-uboot-env-rollback"
 
 do_install_append () {
     install -d ${D}${libdir}/sota
@@ -84,49 +79,45 @@ do_install_append () {
         fi
     fi
 
-}
-
-do_install_append_class-target () {
     install -m 0755 -d ${D}${systemd_unitdir}/system
     aktualizr_service=${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'serialcan', '${WORKDIR}/aktualizr-serialcan.service', '${WORKDIR}/aktualizr.service', d)}
     install -m 0644 ${aktualizr_service} ${D}${systemd_unitdir}/system/aktualizr.service
+
+    if ${@bb.utils.contains('PACKAGECONFIG', 'sota-tools', 'true', 'false', d)}; then
+        install -m 0755 ${B}/src/sota_tools/garage-sign/bin/* ${D}${bindir}
+        install -m 0644 ${B}/src/sota_tools/garage-sign/lib/* ${D}${libdir}
+    fi
 }
 
-do_install_append_class-native () {
-    install -m 0755 ${B}/src/sota_tools/garage-sign/bin/* ${D}${bindir}
-    install -m 0644 ${B}/src/sota_tools/garage-sign/lib/* ${D}${libdir}
+PACKAGESPLITFUNCS_prepend = "split_hosttools_packages "
+
+python split_hosttools_packages () {
+    bindir = d.getVar('bindir')
+
+    # Split all binaries to their own packages except aktualizr-info,
+    # aktualizr-info should stay in main package aktualizr.
+    do_split_packages(d, bindir, r'^((?!(aktualizr-info)).*)$', '%s', 'Aktualizr tool - %s', extra_depends='aktualizr-configs', prepend=False)
 }
 
-PACKAGES =+ " ${PN}-examples ${PN}-host-tools ${PN}-tools ${PN}-secondary "
+PACKAGES_DYNAMIC = "^aktualizr-.* ^garage-.*"
+
+PACKAGES =+ "${PN}-examples ${PN}-secondary ${PN}-configs ${PN}-host-tools"
+
+ALLOW_EMPTY_${PN}-host-tools = "1"
 
 FILES_${PN} = " \
                 ${bindir}/aktualizr \
                 ${bindir}/aktualizr-info \
-                ${bindir}/aktualizr-check-discovery \
                 ${systemd_unitdir}/system/aktualizr.service \
-                ${libdir}/sota/conf.d \
-                ${sysconfdir}/sota/conf.d \
-                ${sysconfdir}/sota/ecus/* \
                 "
 
-FILES_${PN}-examples = " \
-                ${bindir}/hmi-stub \
+FILES_${PN}-configs = " \
+                ${sysconfdir}/sota/* \
+                ${libdir}/sota/* \
                 "
 
-FILES_${PN}-host-tools = " \
-                ${bindir}/aktualizr-repo \
-                ${bindir}/aktualizr-cert-provider \
-                ${bindir}/garage-deploy \
-                ${bindir}/garage-push \
-                ${libdir}/sota/sota_autoprov.toml \
-                ${libdir}/sota/sota_autoprov_primary.toml \
-                ${libdir}/sota/sota_hsm_prov.toml \
-                ${libdir}/sota/sota_implicit_prov_ca.toml \
-                ${libdir}/sota/sota_uboot_env.toml \
-                "
-
-FILES_${PN}-tools = " \
-                ${bindir}/aktualizr-check-discovery \
+FILES_${PN}-examples = " \
+                ${bindir}/hmi-stub \
                 "
 
 FILES_${PN}-secondary = " \
@@ -135,5 +126,6 @@ FILES_${PN}-secondary = " \
                 ${systemd_unitdir}/system/aktualizr-secondary.socket \
                 ${systemd_unitdir}/system/aktualizr-secondary.service \
                 "
+BBCLASSEXTEND = "native"
 
 # vim:set ts=4 sw=4 sts=4 expandtab: