OTA-2541: Use local.conf's variables to configure Primary with Secondary(ies) and vice versa

Signed-off-by: Mike Sul <ext-mykhaylo.sul@here.com>

10 files changed, 86 insertions, 13 deletions

diff --git a/recipes-sota/aktualizr/aktualizr_git.bb b/recipes-sota/aktualizr/aktualizr_git.bb
index d61b597..f4c9946 100755
--- a/recipes-sota/aktualizr/aktualizr_git.bb
+++ b/recipes-sota/aktualizr/aktualizr_git.bb
@@ -117,14 +117,6 @@ do_install_append () {
         fi
     fi
 
-    if [ -n "${SOTA_SECONDARY_NETWORK_CONFIG}" ]; then
-        if [ -f "${SOTA_SECONDARY_NETWORK_CONFIG}" ]; then
-            install -m 0644 ${SOTA_SECONDARY_NETWORK_CONFIG} ${D}/${libdir}/sota/conf.d/35-secondary-network-config.toml
-        else
-            bbwarn "SOTA_SECONDARY_NETWORK_CONFIG is set to a non-existent file (${SOTA_SECONDARY_NETWORK_CONFIG})"
-        fi
-     fi
-
     install -m 0755 -d ${D}${systemd_unitdir}/system
     aktualizr_service=${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'serialcan', '${WORKDIR}/aktualizr-serialcan.service', '${WORKDIR}/aktualizr.service', d)}
     install -m 0644 ${aktualizr_service} ${D}${systemd_unitdir}/system/aktualizr.service
diff --git a/recipes-test/demo-secondary-config/files/30-fake_pacman.toml b/recipes-test/demo-config/files/30-fake_pacman.toml
index 3fb5cf2..3fb5cf2 100644
--- a/recipes-test/demo-secondary-config/files/30-fake_pacman.toml
+++ b/recipes-test/demo-config/files/30-fake_pacman.toml
diff --git a/recipes-test/demo-config/files/30-secondary_config.toml b/recipes-test/demo-config/files/30-secondary_config.toml
new file mode 100644
index 0000000..7714240
--- /dev/null
+++ b/recipes-test/demo-config/files/30-secondary_config.toml
@@ -0,0 +1,2 @@
+[uptane]
+secondary_config_file = "@CFG_FILEPATH@"
diff --git a/recipes-test/demo-secondary-config/files/35-network_config.toml b/recipes-test/demo-config/files/35-network_config.toml
index db7a1bb..db7a1bb 100644
--- a/recipes-test/demo-secondary-config/files/35-network_config.toml
+++ b/recipes-test/demo-config/files/35-network_config.toml
diff --git a/recipes-test/demo-secondary-config/files/45-id_config.toml b/recipes-test/demo-config/files/45-id_config.toml
index 6cbd77f..6cbd77f 100644
--- a/recipes-test/demo-secondary-config/files/45-id_config.toml
+++ b/recipes-test/demo-config/files/45-id_config.toml
diff --git a/recipes-test/demo-config/files/ip_secondary_config.json b/recipes-test/demo-config/files/ip_secondary_config.json
new file mode 100644
index 0000000..690cf2e
--- /dev/null
+++ b/recipes-test/demo-config/files/ip_secondary_config.json
@@ -0,0 +1,7 @@
+{
+    "IP": {
+            "secondaries_wait_port": @PORT@,
+            "secondaries_wait_timeout": @TIMEOUT@,
+            "secondaries": @ADDR_ARRAY@ 
+    }
+}
diff --git a/recipes-test/demo-config/primary-config.bb b/recipes-test/demo-config/primary-config.bb
new file mode 100644
index 0000000..0cd9180
--- /dev/null
+++ b/recipes-test/demo-config/primary-config.bb
@@ -0,0 +1,68 @@
+DESCRIPTION = "Sample configuration for an Uptane Primary to support IP/Posix Secondary"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MPL-2.0;md5=815ca599c9df247a0c7f619bab123dad"
+
+require shared-conf.inc
+
+PRIMARY_SECONDARIES ?= "${SECONDARY_IP}:${SECONDARY_PORT}"
+
+SRC_URI = "\
+    file://30-secondary_config.toml \
+    file://ip_secondary_config.json \
+    "
+
+def get_secondary_addrs(d):
+    import json
+
+    secondaries = d.getVar('PRIMARY_SECONDARIES')
+    sec_array = []
+    for secondary in secondaries.split():
+        sec_array.append({"addr": secondary})
+
+    return json.dumps(sec_array) 
+
+do_install () {
+
+    if [ ! -n "${SOTA_SECONDARY_CONFIG}" ]; then
+        bbwarn "SOTA_SECONDARY_CONFIG hasn't been specified in the local config, generate a default one"
+
+        IP_SECONDARY_CONFIG_FILE=${WORKDIR}/ip_secondary_config.json
+        IP_SECONDARY_ADDRS='${@get_secondary_addrs(d)}'
+    else
+        bbwarn "SOTA_SECONDARY_CONFIG has been specified in the local config: ${SOTA_SECONDARY_CONFIG}"
+
+        IP_SECONDARY_CONFIG_FILE=${SOTA_SECONDARY_CONFIG}
+    fi
+
+    if [ ! -f $IP_SECONDARY_CONFIG_FILE ]; then
+        bbfatal "Secondary config file does not exist: $IP_SECONDARY_CONFIG_FILE"
+    fi
+
+    SECONDARY_CONFIG_DEST_DIR="${D}${sysconfdir}/sota/ecus"
+    SECONDARY_CONFIG_DEST_FILEPATH=$SECONDARY_CONFIG_DEST_DIR/$(basename -- $IP_SECONDARY_CONFIG_FILE)
+    SECONDARY_CONFIG_FILEPATH_ON_IMAGE="${sysconfdir}/sota/ecus/$(basename -- $IP_SECONDARY_CONFIG_FILE)"
+
+    # install the secondary configuration file (json)
+    install -m 0700 -d $SECONDARY_CONFIG_DEST_DIR
+    install -m 0644 $IP_SECONDARY_CONFIG_FILE $SECONDARY_CONFIG_DEST_DIR
+
+    # if SOTA_SECONDARY_CONFIG/secondary config file is not defined in the local conf 
+    # then a default template is used and filled with corresponding configuration variable values 
+    if [ ! -n "${SOTA_SECONDARY_CONFIG}" ]; then
+        sed -i -e "s|@PORT@|${PRIMARY_PORT}|g" \
+               -e "s|@TIMEOUT@|${PRIMARY_WAIT_TIMEOUT}|g" \
+               -e "s|@ADDR_ARRAY@|$IP_SECONDARY_ADDRS|g" $SECONDARY_CONFIG_DEST_FILEPATH
+    fi
+
+    # install aktualizr config file (toml) that points to the secondary config file, so aktualizr is aware about it
+    install -m 0700 -d ${D}${libdir}/sota/conf.d
+    install -m 0644 ${WORKDIR}/30-secondary_config.toml ${D}${libdir}/sota/conf.d
+    sed -i "s|@CFG_FILEPATH@|$SECONDARY_CONFIG_FILEPATH_ON_IMAGE|g" ${D}${libdir}/sota/conf.d/30-secondary_config.toml
+}
+
+FILES_${PN} = " \
+                ${libdir}/sota/conf.d/* \
+                ${sysconfdir}/sota/ecus/* \
+                "
+
+# vim:set ts=4 sw=4 sts=4 expandtab:
diff --git a/recipes-test/demo-secondary-config/secondary-config.bb b/recipes-test/demo-config/secondary-config.bb
index 25972d4..5b213d1 100644
--- a/recipes-test/demo-secondary-config/secondary-config.bb
+++ b/recipes-test/demo-config/secondary-config.bb
@@ -2,14 +2,12 @@ DESCRIPTION = "Sample configuration for an Uptane Secondary"
 LICENSE = "MPL-2.0"
 LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MPL-2.0;md5=815ca599c9df247a0c7f619bab123dad"
 
+require shared-conf.inc
+
 SECONDARY_SERIAL_ID ?= ""
 SOTA_HARDWARE_ID ?= "${MACHINE}-sndry"
 SECONDARY_HARDWARE_ID ?= "${SOTA_HARDWARE_ID}"
 
-SECONDARY_PORT ?= "9050"
-PRIMARY_IP ?= "10.0.3.1"
-PRIMARY_PORT ?= "9040"
-
 SRC_URI = "\
     file://30-fake_pacman.toml \
     file://35-network_config.toml \
diff --git a/recipes-test/demo-config/shared-conf.inc b/recipes-test/demo-config/shared-conf.inc
new file mode 100644
index 0000000..ce2bb44
--- /dev/null
+++ b/recipes-test/demo-config/shared-conf.inc
@@ -0,0 +1,5 @@
+SECONDARY_IP ?= "10.0.3.2"
+SECONDARY_PORT ?= "9050"
+PRIMARY_IP ?= "10.0.3.1"
+PRIMARY_PORT ?= "9040"
+PRIMARY_WAIT_TIMEOUT ?= "120"
diff --git a/recipes-test/images/primary-image.bb b/recipes-test/images/primary-image.bb
index 935f7ac..ba1dc1f 100644
--- a/recipes-test/images/primary-image.bb
+++ b/recipes-test/images/primary-image.bb
@@ -9,7 +9,8 @@ IMAGE_INSTALL_remove = " \
                         "
 
 IMAGE_INSTALL_append = " \
-                        primary-network-config \
+                         primary-network-config \
+                         primary-config \
                        "
 
 # vim:set ts=4 sw=4 sts=4 expandtab: