blob: 9068d341f7b9433b71fb2d81536490bcdde1a8ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
DESCRIPTION = "Userspace libraries for PowerVR Rogue GPU on TI SoCs"
HOMEPAGE = "http://git.ti.com/graphics/ti-img-rogue-umlibs"
LICENSE = "TI-TFL"
LIC_FILES_CHKSUM = "file://${WORKDIR}/git/LICENSE;md5=7232b98c1c58f99e3baa03de5207e76f"
inherit bin_package
PACKAGE_ARCH = "${MACHINE_ARCH}"
COMPATIBLE_MACHINE = "j721e|j721s2|j784s4|am62xx"
PR = "r2"
BRANCH = "linuxws/kirkstone/k6.1/${PV}"
SRC_URI = "git://git.ti.com/git/graphics/ti-img-rogue-umlibs.git;protocol=https;branch=${BRANCH}"
SRCREV = "452b0f50d2984171c81d5a0d3b22198177d919ad"
S = "${WORKDIR}/git/targetfs/${TARGET_PRODUCT}/${PVR_WS}/${PVR_BUILD}"
TARGET_PRODUCT:j721e = "j721e_linux"
TARGET_PRODUCT:j721s2 = "j721s2_linux"
TARGET_PRODUCT:j784s4 = "j784s4_linux"
TARGET_PRODUCT:am62xx = "am62_linux"
PVR_BUILD = "release"
PVR_WS = "lws-generic"
RDEPENDS:${PN} += "mesa-megadriver libdrm ti-img-rogue-driver"
do_install:append() {
if ${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', 'true', 'false', d)}; then
mv ${D}/lib/firmware ${D}${nonarch_base_libdir}
rmdir ${D}/lib
fi
rm -rf "${D}/etc/init.d"
}
PACKAGES = "${PN}-vulkan ${PN}-tools ${PN}"
FILES:${PN}-vulkan = " \
${datadir}/vulkan \
${libdir}/libVK_IMG.so* \
"
RDEPENDS:${PN}-vulkan += " \
mesa-vulkan-drivers \
libdrm \
ti-img-rogue-driver \
libx11-xcb \
wayland \
"
INSANE_SKIP:${PN}-vulkan += " \
already-stripped \
dev-so \
"
FILES:${PN}-tools = "${bindir}/"
RDEPENDS:${PN}-tools = "python3-core"
RRECOMMENDS:${PN} += "${PN}-vulkan ${PN}-tools"
INSANE_SKIP:${PN} += "ldflags arch already-stripped dev-so"
|
