ti-img-rogue-umlibs: add PowerVR Rogue GPU user mode libraries for J721E SoC

Signed-off-by: Anand Balagopalakrishnan <anandb@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>

1 files changed, 55 insertions, 0 deletions

diff --git a/recipes-graphics/libgles/ti-img-rogue-umlibs_1.10.5187610.bb b/recipes-graphics/libgles/ti-img-rogue-umlibs_1.10.5187610.bb
new file mode 100644
index 00000000..63b6ee99
--- /dev/null
+++ b/recipes-graphics/libgles/ti-img-rogue-umlibs_1.10.5187610.bb
@@ -0,0 +1,55 @@
+DESCRIPTION = "Userspace libraries for PowerVR Rogue GPU on TI SoCs"
+HOMEPAGE = "http://git.ti.com/graphics/ti-img-rogue-umlibs"
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=7232b98c1c58f99e3baa03de5207e76f"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "j7-evm"
+
+PR = "r1"
+
+BRANCH = "linux/thud/k4.19/${PV}"
+
+SRC_URI = "git://git.ti.com/graphics/ti-img-rogue-umlibs.git;branch=${BRANCH}"
+SRCREV = "4dccfbeffa6427a56bf63ab83af9d2140d95045b"
+
+PVR_SOC ?= "j721e_linux"
+PVR_BUILD ?= "release"
+
+INITSCRIPT_NAME = "rc.pvr"
+INITSCRIPT_PARAMS = "defaults 8"
+
+inherit update-rc.d
+
+PROVIDES += "virtual/egl virtual/libgles1 virtual/libgles2"
+
+DEPENDS += "libdrm"
+RDEPENDS_${PN} += "bash"
+RDEPENDS_${PN} += "python-core"
+RDEPENDS_${PN} += "ti-img-rogue-driver"
+
+RPROVIDES_${PN} = "libegl libgles1 libgles2"
+RPROVIDES_${PN}-dev = "libegl-dev libgles1-dev libgles2-dev"
+RPROVIDES_${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg"
+
+RREPLACES_${PN} = "libegl libgles1 liblges2"
+RREPLACES_${PN}-dev = "libegl-dev libgles1-dev libgles2-dev"
+RREPLACES_${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg"
+
+RCONFLICTS_${PN} = "libegl libgles1 libgles2"
+RCONFLICTS_${PN}-dev = "libegl-dev libgles1-dev libgles2-dev"
+RCONFLICTS_${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+    oe_runmake install DESTDIR=${D} TARGET_PRODUCT=${PVR_SOC} BUILD=${PVR_BUILD}
+    chown -R root:root ${D}
+}
+
+FILES_${PN} += " ${base_libdir}/firmware/"
+FILES_${PN} += " ${datadir}/"
+
+INSANE_SKIP_${PN} += "ldflags arch already-stripped"
+
+CLEANBROKEN = "1"