blob: 4deedbfbcad16d815007b750f2dac4ecaec60449 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
DESCRIPTION = "Application library for the Xfce desktop environment"
SECTION = "x11"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
DEPENDS = "gtk+3 libxfce4ui virtual/libx11 liburi-perl-native cairo"
DEPENDS_class-native = "glib-2.0-native xfce4-dev-tools-native intltool-native"
inherit xfce perlnative gtk-doc features_check
REQUIRED_DISTRO_FEATURES = "x11"
REQUIRED_DISTRO_FEATURES_class-native = ""
# SRC_URI must follow inherited one
SRC_URI += " \
file://exo-no-tests-0.8.patch \
file://configure.patch \
"
SRC_URI_append_class-native = " \
file://reduce-build-to-exo-csource-only.patch \
"
SRC_URI[md5sum] = "ef1db71eb24cf24f6870444ccfc2345d"
SRC_URI[sha256sum] = "848fd65175118786e994fcf8b28f8c804f58d21cc9d961e00897cd97dc257cac"
PACKAGECONFIG ??= ""
PACKAGECONFIG_class-target ??= "gtk"
PACKAGECONFIG[gtk] = "--enable-gtk2,--disable-gtk2,gtk+"
PACKAGES =+ "exo-csource"
# Note: python bindings did not work in oe-dev and are about to be moved to
# pyxfce see http://comments.gmane.org/gmane.comp.desktop.xfce.devel.version4/19560
FILES_${PN} += " \
${datadir}/xfce4/ \
${libdir}/xfce4/exo* \
"
FILES_exo-csource += "${bindir}/exo-csource"
BBCLASSEXTEND = "native"
|
