blob: 25b03c8e32cd2a22379c163c56772841a559f535 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
SUMMARY = "pandas library for high-performance data analysis tools"
DESCRIPTION = "pandas is an open source, BSD-licensed library providing \
high-performance, easy-to-use data structures and data analysis tools for \
the Python programming language."
HOMEPAGE = "http://pandas.pydata.org/"
LICENSE = "BSD-3-Clause"
LIC_FILES_CHKSUM = "file://LICENSE;md5=cb819092901ddb13a7d0a4f5e05f098a"
SRC_URI += " \
file://0001-pyproject.toml-don-t-pin-dependency-versions.patch \
file://0001-pyproject.toml-Downgrade-numpy-version-needs-to-1.x.patch \
"
SRC_URI[sha256sum] = "9e79019aba43cb4fda9e4d983f8e88ca0373adbb697ae9c6c43093218de28b54"
inherit pypi python_mesonpy
DEPENDS += " \
python3-cython-native \
python3-numpy-native \
python3-versioneer-native \
"
PACKAGESPLITFUNCS =+ "fix_cythonized_sources"
fix_cythonized_sources() {
for f in `grep -l -r -e '\/* Generated by Cython.*/$' ${PKGD}${TARGET_DBGSRC_DIR}`; do
if [ -e $f ]; then
sed -i -e 's#${RECIPE_SYSROOT_NATIVE}##g' $f
fi
done
}
CFLAGS:append:toolchain-clang = " -Wno-error=deprecated-declarations"
RDEPENDS:${PN} += " \
python3-json \
python3-numpy \
python3-dateutil \
python3-dateutil-zoneinfo \
python3-pytz \
python3-profile \
"
|
