blob: 0a643825eebbcc571706d519116b76f4471bc69f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
SUMMARY = "An open source remote desktop protocol(rdp) server."
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://COPYING;md5=72cfbe4e7bd33a0a1de9630c91195c21 \
"
inherit features_check autotools pkgconfig useradd systemd
DEPENDS = "openssl virtual/libx11 libxfixes libxrandr libpam nasm-native"
REQUIRED_DISTRO_FEATURES = "x11 pam"
SRC_URI = "git://github.com/neutrinolabs/xrdp.git;branch=devel \
file://xrdp.sysconfig \
file://0001-Added-req_distinguished_name-in-etc-xrdp-openssl.con.patch \
file://0001-Fix-the-compile-error.patch \
file://0001-arch-Define-NO_NEED_ALIGN-on-ppc64.patch \
"
SRCREV = "58088324956d94fd2eb5e7694a318cccec6990f1"
S = "${WORKDIR}/git"
PACKAGECONFIG ??= ""
PACKAGECONFIG[fuse] = " --enable-fuse, --disable-fuse, fuse"
USERADD_PACKAGES = "${PN}"
GROUPADD_PARAM:${PN} = "--system xrdp"
USERADD_PARAM:${PN} = "--system --home /var/run/xrdp -g xrdp \
--no-create-home --shell /bin/false xrdp"
FILES:${PN} += "${datadir}/dbus-1/services/*.service \
${datadir}/dbus-1/accessibility-services/*.service "
FILES:${PN}-dev += "${libdir}/xrdp/libcommon.so \
${libdir}/xrdp/libxrdp.so \
${libdir}/xrdp/libscp.so \
${libdir}/xrdp/libxrdpapi.so "
EXTRA_OECONF = "--enable-pam-config=suse"
do_configure:prepend() {
cd ${S}
./bootstrap
cd -
}
do_compile:prepend() {
sed -i 's/(MAKE) $(AM_MAKEFLAGS) install-exec-am install-data-am/(MAKE) $(AM_MAKEFLAGS) install-exec-am/g' ${S}/keygen/Makefile.in
}
do_install:append() {
install -d ${D}${sysconfdir}
install -d ${D}${sysconfdir}/xrdp
install -d ${D}${sysconfdir}/xrdp/pam.d
install -d ${D}${sysconfdir}/sysconfig/xrdp
# deal with systemd unit files
install -d ${D}${systemd_unitdir}/system
install -m 0644 ${S}/instfiles/xrdp.service.in ${D}${systemd_unitdir}/system/xrdp.service
install -m 0644 ${S}/instfiles/xrdp-sesman.service.in ${D}${systemd_unitdir}/system/xrdp-sesman.service
sed -i -e 's,@localstatedir@,${localstatedir},g' ${D}${systemd_unitdir}/system/xrdp.service ${D}${systemd_unitdir}/system/xrdp-sesman.service
sed -i -e 's,@sysconfdir@,${sysconfdir},g' ${D}${systemd_unitdir}/system/xrdp.service ${D}${systemd_unitdir}/system/xrdp-sesman.service
sed -i -e 's,@sbindir@,${sbindir},g' ${D}${systemd_unitdir}/system/xrdp.service ${D}${systemd_unitdir}/system/xrdp-sesman.service
install -m 0644 ${S}/instfiles/*.ini ${D}${sysconfdir}/xrdp/
install -m 0644 ${S}/sesman/sesman.ini.in ${D}${sysconfdir}/xrdp/
install -m 0644 ${S}/sesman/startwm.sh ${D}${sysconfdir}/xrdp/
install -m 0644 ${S}/xrdp/xrdp.ini.in ${D}${sysconfdir}/xrdp/
install -m 0644 ${S}/xrdp/xrdp_keyboard.ini ${D}${sysconfdir}/xrdp/
install -m 0644 ${S}/keygen/openssl.conf ${D}${sysconfdir}/xrdp/
install -m 0644 ${WORKDIR}/xrdp.sysconfig ${D}${sysconfdir}/sysconfig/xrdp/
chown xrdp:xrdp ${D}${sysconfdir}/xrdp
}
SYSTEMD_SERVICE:${PN} = "xrdp.service xrdp-sesman.service"
pkg_postinst:${PN}() {
if test -z "$D"
then
if test -x ${bindir}/xrdp-keygen
then
${bindir}/xrdp-keygen xrdp ${sysconfdir}/xrdp/rsakeys.ini >/dev/null
fi
if test ! -s ${sysconfdir}/xrdp/cert.pem
then
openssl req -x509 -newkey rsa:2048 -sha256 -nodes -days 3652 \
-keyout ${sysconfdir}/xrdp/key.pem \
-out ${sysconfdir}/xrdp/cert.pem \
-config ${sysconfdir}/xrdp/openssl.conf >/dev/null 2>&1
chmod 400 ${sysconfdir}/xrdp/key.pem
fi
fi
}
|
