blob: d917a324724b737cfc71caeefabadcccfa77449a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
DESCRIPTION = "Libraries providing API for reporting different problems in applications \
to different bug targets like Bugzilla, ftp, trac, etc..."
SUMMARY = "Generic library for reporting various problems"
HOMEPAGE = "https://abrt.readthedocs.org/"
LICENSE = "GPL-2.0-or-later"
DEPENDS = "xmlrpc-c xmlrpc-c-native intltool-native \
json-c libtar libnewt libproxy rpm \
augeas satyr systemd \
"
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
SRC_URI = "git://github.com/abrt/libreport.git;protocol=https;branch=master"
SRC_URI += "file://0001-Makefile.am-remove-doc-and-apidoc.patch \
file://0002-configure.ac-remove-prog-test-of-xmlto-and-asciidoc.patch \
file://0003-without-build-plugins.patch \
file://0004-configure.ac-remove-prog-test-of-augparse.patch \
"
SRCREV = "eaff08f38d771d9362923765bb404b1514c5ca0a"
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
S = "${WORKDIR}/git"
inherit features_check
REQUIRED_DISTRO_FEATURES = "systemd"
inherit gettext autotools python3native pkgconfig
PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES','x11','gtk','',d)}"
PACKAGECONFIG[gtk] = "--with-gtk, --without-gtk, gtk+3,"
EXTRA_OECONF += "--without-python2 --with-python3"
RDEPENDS:python3-libreport += "${PN}"
do_patch[prefuncs] += "do_gen_version"
do_gen_version() {
cd ${S}
./gen-version
}
PACKAGES += "python3-libreport"
FILES:${PN} += "${datadir}/*"
FILES:${PN}-dbg += "${PYTHON_SITEPACKAGES_DIR}/*/.debug"
FILES:python3-libreport = "${PYTHON_SITEPACKAGES_DIR}/*"
|
