blob: b899684eb296d1666e078dbfae86ad38701306a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
SUMMARY = "Shows and manipulates data structure layout"
LICENSE = "GPL-2.0-only"
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
DEPENDS = "elfutils zlib libbpf"
# Depends on MACHINE_ARCH libbpf
PACKAGE_ARCH = "${MACHINE_ARCH}"
COMPATIBLE_HOST:mips = "null"
COMPATIBLE_HOST:riscv32 = "null"
SRCREV = "3e265dac5ec85b956c664464072196c37d2af4f3"
SRC_URI = "git://git.kernel.org/pub/scm/devel/pahole/pahole.git;branch=master \
file://0001-Use-usr-bin-env-python3-instead-of-just-usr-bin-pyth.patch"
S = "${WORKDIR}/git"
inherit cmake pkgconfig
PACKAGECONFIG[python3] = ",,python3-core,python3-core"
EXTRA_OECMAKE = "-D__LIB=${@os.path.relpath(d.getVar('libdir'), d.getVar('prefix') + '/')} -DCMAKE_BUILD_TYPE=Release -DLIBBPF_EMBEDDED=OFF"
FILES:${PN} = "${bindir}/pahole \
${libdir}/libdwarves.so* \
${libdir}/libdwarves_reorganize.so*"
PACKAGES += "${PN}-extra"
FILES:${PN}-extra = "${datadir} ${bindir} ${libdir}/libdwarves_emit.so*"
RDEPENDS:${PN}-extra += "bash python3-core"
BBCLASSEXTEND = "native nativesdk"
|
