4 files changed, 142 insertions, 0 deletions

diff --git a/meta-oe/recipes-graphics/libsdl3/libsdl2-compat_2.32.56.bb b/meta-oe/recipes-graphics/libsdl3/libsdl2-compat_2.32.56.bb
new file mode 100644
index 0000000000..3b17f350df
--- /dev/null
+++ b/meta-oe/recipes-graphics/libsdl3/libsdl2-compat_2.32.56.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Simple DirectMedia Layer (SDL) sdl2-compat"
+DESCRIPTION = "This code is a compatibility layer; it provides a binary and source compatible \
+API for programs written against SDL2, but it uses SDL3 behind the scenes. If you are \
+writing new code, please target SDL3 directly and do not use this layer."
+HOMEPAGE = "http://www.libsdl.org"
+BUGTRACKER = "http://bugzilla.libsdl.org/"
+
+SECTION = "libs"
+
+LICENSE = "Zlib"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=98241180d857fe975e4b60d44d6c01a5"
+
+SRC_URI = "http://www.libsdl.org/release/sdl2-compat-${PV}.tar.gz"
+SRC_URI[sha256sum] = "27e845b1b7dc0a91a85f1a1f18892ed205adb38caf767741eb258008d8264de0"
+S = "${UNPACKDIR}/sdl2-compat-${PV}"
+
+DEPENDS += "libsdl3"
+
+PROVIDES = "virtual/libsdl2"
+
+inherit cmake pkgconfig upstream-version-is-even features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl x11"
+
+do_install:append() {
+        mv ${D}${libdir}/pkgconfig/sdl2-compat.pc ${D}${libdir}/pkgconfig/sdl2.pc
+}
+
+FILES:${PN} += "${datadir}/licenses"
+
+RCONFLICTS:${PN} = "libsdl2"
+RPROVIDES:${PN} = "libsdl2"
+
+BBCLASSEXTEND = "nativesdk native"
diff --git a/meta-oe/recipes-graphics/libsdl3/libsdl3-image_3.2.4.bb b/meta-oe/recipes-graphics/libsdl3/libsdl3-image_3.2.4.bb
new file mode 100644
index 0000000000..ac425f6ad2
--- /dev/null
+++ b/meta-oe/recipes-graphics/libsdl3/libsdl3-image_3.2.4.bb
@@ -0,0 +1,15 @@
+SUMMARY = "Simple DirectMedia Layer image library v2"
+SECTION = "libs"
+
+LICENSE = "Zlib"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=fbb0010b2f7cf6e8a13bcac1ef4d2455"
+
+DEPENDS = "tiff zlib libpng jpeg libsdl3 libwebp"
+
+SRC_URI = "git://github.com/libsdl-org/SDL_image.git;protocol=https;branch=release-3.2.x"
+SRCREV = "11154afb7855293159588b245b446a4ef09e574f"
+
+
+inherit cmake pkgconfig
+
+FILES:${PN} += "${datadir}/licenses"
diff --git a/meta-oe/recipes-graphics/libsdl3/libsdl3-ttf_3.2.2.bb b/meta-oe/recipes-graphics/libsdl3/libsdl3-ttf_3.2.2.bb
new file mode 100644
index 0000000000..1f82f95d65
--- /dev/null
+++ b/meta-oe/recipes-graphics/libsdl3/libsdl3-ttf_3.2.2.bb
@@ -0,0 +1,15 @@
+SUMMARY = "Simple DirectMedia Layer truetype font library"
+SECTION = "libs"
+DEPENDS = "libsdl3 freetype"
+LICENSE = "Zlib"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=fbb0010b2f7cf6e8a13bcac1ef4d2455"
+
+SRC_URI = "http://www.libsdl.org/projects/SDL_ttf/release/SDL3_ttf-${PV}.tar.gz \
+"
+SRC_URI[sha256sum] = "63547d58d0185c833213885b635a2c0548201cc8f301e6587c0be1a67e1e045d"
+
+S = "${UNPACKDIR}/SDL3_ttf-${PV}"
+
+inherit cmake pkgconfig
+
+FILES:${PN} += "${datadir}/licenses"
diff --git a/meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.16.bb b/meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.16.bb
new file mode 100644
index 0000000000..9579cb73a1
--- /dev/null
+++ b/meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.16.bb
@@ -0,0 +1,78 @@
+SUMMARY = "Simple DirectMedia Layer"
+DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
+library designed to provide low level access to audio, keyboard, mouse, \
+joystick, 3D hardware via OpenGL, and 2D video framebuffer."
+HOMEPAGE = "http://www.libsdl.org"
+BUGTRACKER = "http://bugzilla.libsdl.org/"
+
+SECTION = "libs"
+
+LICENSE = "Zlib & BSD-2-Clause"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE.txt;md5=cbf0e3161523f9a9315b6b915c5c4457 \
+    file://src/hidapi/LICENSE.txt;md5=7c3949a631240cb6c31c50f3eb696077 \
+    file://src/hidapi/LICENSE-bsd.txt;md5=b5fa085ce0926bb50d0621620a82361f \
+    file://src/video/yuv2rgb/LICENSE;md5=79f8f3418d91531e05f0fc94ca67e071 \
+"
+
+SRC_URI = "http://www.libsdl.org/release/SDL3-${PV}.tar.gz"
+
+S = "${UNPACKDIR}/SDL3-${PV}"
+
+SRC_URI[sha256sum] = "6340e58879b2d15830c8460d2f589a385c444d1faa2a4828a9626c7322562be8"
+
+inherit cmake lib_package binconfig-disabled pkgconfig upstream-version-is-even
+
+CVE_PRODUCT = "simple_directmedia_layer sdl"
+
+EXTRA_OECMAKE = " \
+        -DSDL_OSS_DEFAULT=OFF \
+        -DSDL_DISKAUDIO=OFF \
+        -DSDL_DUMMYVIDEO=OFF \
+        -DSDL_RPI=OFF \
+        -DSDL_PTHREADS=ON \
+        -DSDL_RPATH=OFF \
+        -DSDL_SNDIO=OFF \
+        -DSDL_X11_XCURSOR=OFF \
+        -DSDL_X11_XDBE=OFF \
+        -DSDL_X11_XFIXES=OFF \
+        -DSDL_X11_XINPUT=OFF \
+        -DSDL_X11_XSCRNSAVER=OFF \
+        -DSDL_X11_XSHAPE=OFF \
+"
+
+# opengl packageconfig factored out to make it easy for distros
+# and BSP layers to pick either (desktop) opengl, gles2, or no GL
+PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
+
+PACKAGECONFIG:class-native = "x11 ${PACKAGECONFIG_GL}"
+PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} ${PACKAGECONFIG_GL}"
+PACKAGECONFIG ??= " \
+        ${PACKAGECONFIG_GL} \
+        ${@bb.utils.filter('DISTRO_FEATURES', 'alsa pulseaudio pipewire x11 vulkan', d)} \
+        ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \
+        ${@bb.utils.contains("TUNE_FEATURES", "neon","arm-neon","",d)} \
+        ${@bb.utils.contains_any("DISTRO_FEATURES", "x11 wayland","","console-build",d)} \
+"
+PACKAGECONFIG[alsa]       = "-DSDL_ALSA=ON,-DSDL_ALSA=OFF,alsa-lib,"
+PACKAGECONFIG[arm-neon]   = "-DSDL_ARMNEON=ON,-DSDL_ARMNEON=OFF"
+PACKAGECONFIG[console-build] = "-DSDL_UNIX_CONSOLE_BUILD=ON"
+PACKAGECONFIG[gles2]      = "-DSDL_OPENGLES=ON,-DSDL_OPENGLES=OFF,virtual/libgles2"
+PACKAGECONFIG[jack]       = "-DSDL_JACK=ON,-DSDL_JACK=OFF,jack"
+PACKAGECONFIG[kmsdrm]     = "-DSDL_KMSDRM=ON,-DSDL_KMSDRM=OFF,libdrm virtual/libgbm"
+# The hidraw support doesn't catch Xbox, PS4 and Nintendo controllers,
+#  so we'll just use libusb when it's available.
+PACKAGECONFIG[libusb] = "-DSDL_HIDAPI_LIBUSB=ON,-DSDL_HIDAPI_LIBUSB=OFF,libusb1"
+PACKAGECONFIG[libdecor] = "-DSDL_WAYLAND_LIBDECOR=ON,-DSDL_WAYLAND_LIBDECOR=OFF,libdecor,libdecor"
+PACKAGECONFIG[opengl]     = "-DSDL_OPENGL=ON,-DSDL_OPENGL=OFF,virtual/egl"
+PACKAGECONFIG[pipewire] = "-DSDL_PIPEWIRE_SHARED=ON,-DSDL_PIPEWIRE_SHARED=OFF,pipewire"
+PACKAGECONFIG[pulseaudio] = "-DSDL_PULSEAUDIO=ON,-DSDL_PULSEAUDIO=OFF,pulseaudio"
+PACKAGECONFIG[vulkan]    = "-DSDL_VULKAN=ON -DSDL_RENDER_VULKAN=ON,-DSDL_VULKAN=OFF -DSDL_RENDER_VULKAN=OFF"
+PACKAGECONFIG[wayland]    = "-DSDL_WAYLAND=ON,-DSDL_WAYLAND=OFF,wayland-native wayland wayland-protocols libxkbcommon"
+PACKAGECONFIG[x11]        = "-DSDL_X11=ON,-DSDL_X11=OFF,virtual/libx11 libxext libxrandr libxrender"
+
+CFLAGS:append:class-native = " -DNO_SHARED_MEMORY"
+
+FILES:${PN} += "${datadir}/licenses/SDL3/LICENSE.txt"
+
+BBCLASSEXTEND = "native nativesdk"