diff options
Diffstat (limited to 'meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.10.bb')
-rw-r--r-- | meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.10.bb | 68 |
1 files changed, 68 insertions, 0 deletions
diff --git a/meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.10.bb b/meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.10.bb new file mode 100644 index 000000000..33fae0619 --- /dev/null +++ b/meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.10.bb | |||
@@ -0,0 +1,68 @@ | |||
1 | SUMMARY = "Diagnostic Log and Trace" | ||
2 | DESCRIPTION = "This component provides a standardised log and trace interface, \ | ||
3 | based on the standardised protocol specified in the AUTOSAR standard 4.0 DLT. \ | ||
4 | This component can be used by COVESA components and other applications as \ | ||
5 | logging facility providing: \ | ||
6 | - the DLT shared library \ | ||
7 | - the DLT daemon, including startup scripts \ | ||
8 | - the DLT daemon adaptors- the DLT client console utilities \ | ||
9 | - the DLT test applications" | ||
10 | HOMEPAGE = "https://www.covesa.global/" | ||
11 | SECTION = "console/utils" | ||
12 | LICENSE = "MPL-2.0" | ||
13 | LIC_FILES_CHKSUM = "file://LICENSE;md5=8184208060df880fe3137b93eb88aeea" | ||
14 | |||
15 | DEPENDS = "zlib gzip-native json-c" | ||
16 | |||
17 | SRC_URI = "git://github.com/COVESA/${BPN}.git;protocol=https;branch=master \ | ||
18 | file://0002-Don-t-execute-processes-as-a-specific-user.patch \ | ||
19 | file://0004-Modify-systemd-config-directory.patch \ | ||
20 | " | ||
21 | SRCREV = "0f2d4cfffada6f8448a2cb27995b38eb4271044f" | ||
22 | |||
23 | S = "${WORKDIR}/git" | ||
24 | |||
25 | PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', ' systemd systemd-watchdog systemd-journal dlt-examples dlt-adaptor dlt-adaptor-stdin dlt-adaptor-udp dlt-console ', '', d)} \ | ||
26 | udp-connection dlt-system dlt-filetransfer " | ||
27 | # dlt-dbus | ||
28 | |||
29 | # General options | ||
30 | PACKAGECONFIG[dlt-examples] = "-DWITH_DLT_EXAMPLES=ON,-DWITH_DLT_EXAMPLES=OFF,,dlt-daemon-systemd" | ||
31 | |||
32 | # Linux options | ||
33 | PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF -DWITH_DLT_SYSTEM=OFF,systemd" | ||
34 | PACKAGECONFIG[systemd-watchdog] = "-DWITH_SYSTEMD_WATCHDOG=ON,-DWITH_SYSTEMD_WATCHDOG=OFF,systemd,libsystemd" | ||
35 | PACKAGECONFIG[systemd-journal] = "-DWITH_SYSTEMD_JOURNAL=ON,-DWITH_SYSTEMD_JOURNAL=OFF,systemd,libsystemd" | ||
36 | PACKAGECONFIG[dlt-dbus] = "-DWITH_DLT_DBUS=ON,-DWITH_DLT_DBUS=OFF,dbus,dbus-lib" | ||
37 | PACKAGECONFIG[udp-connection] = "-DWITH_UDP_CONNECTION=ON,-DWITH_UDP_CONNECTION=OFF" | ||
38 | |||
39 | # Command line options | ||
40 | PACKAGECONFIG[dlt-system] = "-DWITH_DLT_SYSTEM=ON,-DWITH_DLT_SYSTEM=OFF" | ||
41 | PACKAGECONFIG[dlt-adaptor] = "-DWITH_DLT_ADAPTOR=ON,-DWITH_DLT_ADAPTOR=OFF,,dlt-daemon-systemd" | ||
42 | PACKAGECONFIG[dlt-adaptor-stdin] = "-DWITH_DLT_ADAPTOR_STDIN=ON,-DWITH_DLT_ADAPTOR_STDIN=OFF,,dlt-daemon-systemd" | ||
43 | PACKAGECONFIG[dlt-adaptor-udp] = "-DWITH_DLT_ADAPTOR_UDP=ON,-DWITH_DLT_ADAPTOR_UDP=OFF,,dlt-daemon-systemd" | ||
44 | PACKAGECONFIG[dlt-filetransfer] = "-DWITH_DLT_FILETRANSFER=ON,-DWITH_DLT_FILETRANSFER=OFF" | ||
45 | PACKAGECONFIG[dlt-console] = "-DWITH_DLT_CONSOLE=ON,-DWITH_DLT_CONSOLE=OFF,,dlt-daemon-systemd" | ||
46 | |||
47 | inherit autotools gettext cmake pkgconfig systemd | ||
48 | |||
49 | EXTRA_OECMAKE += "-DWITH_DLT_LOGSTORAGE_GZIP=ON -DWITH_EXTENDED_FILTERING=ON -DSYSTEMD_UNITDIR=${systemd_system_unitdir}" | ||
50 | |||
51 | PACKAGES += "${PN}-systemd" | ||
52 | SYSTEMD_PACKAGES = "${PN} ${PN}-systemd" | ||
53 | SYSTEMD_SERVICE:${PN} = " ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'dlt.service', '', d)} \ | ||
54 | ${@bb.utils.contains('PACKAGECONFIG', 'dlt-system', 'dlt-system.service', '', d)} \ | ||
55 | ${@bb.utils.contains('PACKAGECONFIG', 'dlt-dbus', 'dlt-dbus.service', '', d)}" | ||
56 | SYSTEMD_AUTO_ENABLE:${PN} = "enable" | ||
57 | SYSTEMD_SERVICE:${PN}-systemd = " \ | ||
58 | ${@bb.utils.contains('PACKAGECONFIG', 'dlt-adaptor-udp', 'dlt-adaptor-udp.service', '', d)} \ | ||
59 | ${@bb.utils.contains('PACKAGECONFIG', 'dlt-examples', 'dlt-example-user.service', '', d)} \ | ||
60 | ${@bb.utils.contains('PACKAGECONFIG', 'dlt-examples dlt-console', 'dlt-receive.service', '', d)} \ | ||
61 | " | ||
62 | SYSTEMD_AUTO_ENABLE:${PN}-systemd = "disable" | ||
63 | |||
64 | FILES:${PN}-doc += "${datadir}/dlt-filetransfer" | ||
65 | |||
66 | do_install:append() { | ||
67 | rm -f ${D}${bindir}/dlt-test-* | ||
68 | } | ||