summaryrefslogtreecommitdiffstats
path: root/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.10.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.10.bb')
-rw-r--r--meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.10.bb79
1 files changed, 79 insertions, 0 deletions
diff --git a/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.10.bb b/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.10.bb
new file mode 100644
index 0000000000..950c1ff52d
--- /dev/null
+++ b/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.10.bb
@@ -0,0 +1,79 @@
1SUMMARY = "Lightweight crypto and SSL/TLS library"
2DESCRIPTION = "mbedtls is a lean open source crypto library \
3for providing SSL and TLS support in your programs. It offers \
4an intuitive API and documented header files, so you can actually \
5understand what the code does. It features: \
6 \
7 - Symmetric algorithms, like AES, Blowfish, Triple-DES, DES, ARC4, \
8 Camellia and XTEA \
9 - Hash algorithms, like SHA-1, SHA-2, RIPEMD-160 and MD5 \
10 - Entropy pool and random generators, like CTR-DRBG and HMAC-DRBG \
11 - Public key algorithms, like RSA, Elliptic Curves, Diffie-Hellman, \
12 ECDSA and ECDH \
13 - SSL v3 and TLS 1.0, 1.1 and 1.2 \
14 - Abstraction layers for ciphers, hashes, public key operations, \
15 platform abstraction and threading \
16"
17
18HOMEPAGE = "https://tls.mbed.org/"
19
20LICENSE = "Apache-2.0 | GPL-2.0-or-later"
21LIC_FILES_CHKSUM = "file://LICENSE;md5=379d5819937a6c2f1ef1630d341e026d"
22
23SECTION = "libs"
24
25SRCREV = "2fc8413bfcb51354c8e679141b17b3f1a5942561"
26SRC_URI = "git://github.com/Mbed-TLS/mbedtls.git;protocol=https;branch=mbedtls-2.28 \
27 file://run-ptest \
28 "
29
30inherit cmake update-alternatives ptest
31
32PACKAGECONFIG ??= "shared-libs programs ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
33PACKAGECONFIG[shared-libs] = "-DUSE_SHARED_MBEDTLS_LIBRARY=ON,-DUSE_SHARED_MBEDTLS_LIBRARY=OFF"
34PACKAGECONFIG[programs] = "-DENABLE_PROGRAMS=ON,-DENABLE_PROGRAMS=OFF"
35PACKAGECONFIG[werror] = "-DMBEDTLS_FATAL_WARNINGS=ON,-DMBEDTLS_FATAL_WARNINGS=OFF"
36# Make X.509 and TLS calls use PSA
37# https://github.com/Mbed-TLS/mbedtls/blob/development/docs/use-psa-crypto.md
38PACKAGECONFIG[psa] = ""
39PACKAGECONFIG[tests] = "-DENABLE_TESTING=ON,-DENABLE_TESTING=OFF"
40
41EXTRA_OECMAKE = "-DLIB_INSTALL_DIR:STRING=${libdir}"
42
43# For now the only way to enable PSA is to explicitly pass a -D via CFLAGS
44CFLAGS:append = "${@bb.utils.contains('PACKAGECONFIG', 'psa', ' -DMBEDTLS_USE_PSA_CRYPTO', '', d)}"
45
46PROVIDES += "polarssl"
47RPROVIDES:${PN} = "polarssl"
48
49PACKAGES =+ "${PN}-programs"
50FILES:${PN}-programs = "${bindir}/"
51
52ALTERNATIVE:${PN}-programs = "${@bb.utils.contains('PACKAGECONFIG', 'programs', 'hello', '', d)}"
53ALTERNATIVE_LINK_NAME[hello] = "${bindir}/hello"
54
55BBCLASSEXTEND = "native nativesdk"
56
57CVE_PRODUCT = "mbed_tls"
58
59CVE_STATUS[CVE-2021-43666] = "backported-patch: Fix merged upstream https://github.com/Mbed-TLS/mbedtls/pull/5310"
60CVE_STATUS[CVE-2021-45451] = "backported-patch: Fix merged upstream https://github.com/Mbed-TLS/mbedtls/commit/9a4a9c66a48edfe9ece03c7e4a53310adf73a86c"
61
62# Strip host paths from autogenerated test files
63do_compile:append() {
64 sed -i 's+${S}/++g' ${B}/tests/*.c 2>/dev/null || :
65 sed -i 's+${B}/++g' ${B}/tests/*.c 2>/dev/null || :
66}
67
68# Export source files/headers needed by Arm Trusted Firmware
69sysroot_stage_all:append() {
70 sysroot_stage_dir "${S}/library" "${SYSROOT_DESTDIR}/usr/share/mbedtls-source/library"
71 sysroot_stage_dir "${S}/include" "${SYSROOT_DESTDIR}/usr/share/mbedtls-source/include"
72}
73
74do_install_ptest () {
75 install -d ${D}${PTEST_PATH}/tests
76 cp -f ${B}/tests/test_suite_* ${D}${PTEST_PATH}/tests/
77 find ${D}${PTEST_PATH}/tests/ -type f -name "*.c" -delete
78 cp -fR ${S}/tests/data_files ${D}${PTEST_PATH}/tests/
79}