meta-python: move recipes from meta-oe

* Move recipes from meta-openembedded/meta-oe that are not
       depended upon by recipes already in meta-oe (e.g. gateone,
       anki)

     * Recipes NOT moved:
     	 python-futures
	 python-pyopenssl
	 python-simplejson
	 python-tornado
	 python-pyqt
	 python-sip

Signed-off-by: Tim Orling <TicoTimo@gmail.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 44 insertions, 0 deletions

diff --git a/meta-python/recipes-python/python/python-m2crypto_0.21.1.bb b/meta-python/recipes-python/python/python-m2crypto_0.21.1.bb
new file mode 100644
index 0000000000..67ec9214ad
--- /dev/null
+++ b/meta-python/recipes-python/python/python-m2crypto_0.21.1.bb
@@ -0,0 +1,44 @@
+SUMMARY = "A Python crypto and SSL toolkit"
+HOMEPAGE = "http://chandlerproject.org/bin/view/Projects/MeTooCrypto"
+
+DEPENDS = "openssl swig-native python"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=b0e1f0b7d0ce8a62c18b1287b991800e"
+
+SRC_URI = "http://pypi.python.org/packages/source/M/M2Crypto/M2Crypto-${PV}.tar.gz \
+           file://0001-setup.py-link-in-sysroot-not-in-host-directories.patch"
+
+SRC_URI[md5sum] = "f93d8462ff7646397a9f77a2fe602d17"
+SRC_URI[sha256sum] = "25b94498505c2d800ee465db0cc1aff097b1615adc3ac042a1c85ceca264fc0a"
+
+S = "${WORKDIR}/M2Crypto-${PV}"
+
+inherit setuptools
+
+SWIG_FEATURES_x86-64 = "-D__x86_64__"
+SWIG_FEATURES ?= ""
+export SWIG_FEATURES
+
+# Get around a problem with swig, but only if the
+# multilib header file exists.
+#
+do_compile_prepend() {
+    if [ "${SITEINFO_BITS}" = "64" ];then
+        bit="64"
+    else
+        bit="32"
+    fi
+
+    if [ -e ${STAGING_INCDIR}/openssl/opensslconf-${bit}.h ] ;then
+        for i in SWIG/_ec.i SWIG/_evp.i; do
+            sed -i -e "s/opensslconf.*\./opensslconf-${bit}\./" "$i"
+        done
+    elif [ -e ${STAGING_INCDIR}/openssl/opensslconf-n${bit}.h ] ;then
+        for i in SWIG/_ec.i SWIG/_evp.i; do
+            sed -i -e "s/opensslconf.*\./opensslconf-n${bit}\./" "$i"
+        done
+    fi
+}
+
+BBCLASSEXTEND = "native"