diff options
author | Adrian Bunk <bunk@stusta.de> | 2019-10-30 12:52:51 +0200 |
---|---|---|
committer | Khem Raj <raj.khem@gmail.com> | 2019-11-01 17:22:52 -0700 |
commit | b20ba29628747c05154f7ee2fa896dbca2a342ec (patch) | |
tree | 51d232fdd382340dcb72cfd8453e7d153e8a3c0f /meta-oe/recipes-support/poco/poco_1.9.0.bb | |
parent | 9529a8f5ce0bc8db9ae3b2b605436db8e69ea95b (diff) | |
download | meta-openembedded-b20ba29628747c05154f7ee2fa896dbca2a342ec.tar.gz |
poco: Upgrade 1.9.0 -> 1.9.4
Removed patch for issue fixed upstream.
Signed-off-by: Adrian Bunk <bunk@stusta.de>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Diffstat (limited to 'meta-oe/recipes-support/poco/poco_1.9.0.bb')
-rw-r--r-- | meta-oe/recipes-support/poco/poco_1.9.0.bb | 100 |
1 files changed, 0 insertions, 100 deletions
diff --git a/meta-oe/recipes-support/poco/poco_1.9.0.bb b/meta-oe/recipes-support/poco/poco_1.9.0.bb deleted file mode 100644 index 70b251034..000000000 --- a/meta-oe/recipes-support/poco/poco_1.9.0.bb +++ /dev/null | |||
@@ -1,100 +0,0 @@ | |||
1 | SUMMARY = "Modern, powerful open source cross-platform C++ class libraries" | ||
2 | DESCRIPTION = "Modern, powerful open source C++ class libraries and frameworks for building network- and internet-based applications that run on desktop, server, mobile and embedded systems." | ||
3 | HOMEPAGE = "http://pocoproject.org/" | ||
4 | SECTION = "libs" | ||
5 | LICENSE = "BSL-1.0" | ||
6 | LIC_FILES_CHKSUM = "file://LICENSE;md5=4267f48fc738f50380cbeeb76f95cebc" | ||
7 | |||
8 | # These dependencies are required by Foundation | ||
9 | DEPENDS = "libpcre zlib" | ||
10 | |||
11 | SRC_URI = " \ | ||
12 | git://github.com/pocoproject/poco.git;branch=poco-${PV} \ | ||
13 | file://0001-Don-t-try-to-install-non-existing-Encodings-testsuit.patch \ | ||
14 | file://0001-Support-of-arch-riscv64-by-Manuel-A.-Fernandez-Monte.patch \ | ||
15 | file://run-ptest \ | ||
16 | " | ||
17 | SRCREV = "daf00da73ab917e4d4581e3aa00c0ee61e0cc58b" | ||
18 | |||
19 | S = "${WORKDIR}/git" | ||
20 | |||
21 | inherit cmake ptest | ||
22 | |||
23 | # By default the most commonly used poco components are built | ||
24 | # Foundation is built anyway and doesn't need to be listed explicitly | ||
25 | # these don't have dependencies outside oe-core | ||
26 | PACKAGECONFIG ??= "XML JSON MongoDB PDF Util Net NetSSL Crypto Data DataSQLite Zip Encodings Redis" | ||
27 | |||
28 | PACKAGECONFIG[XML] = "-DENABLE_XML=ON -DEXPAT_LIBRARY:STRING=expat,-DENABLE_XML=OFF,expat" | ||
29 | PACKAGECONFIG[JSON] = "-DENABLE_JSON=ON,-DENABLE_JSON=OFF" | ||
30 | PACKAGECONFIG[MongoDB] = "-DENABLE_MONGODB=ON,-DENABLE_MONGODB=OFF" | ||
31 | PACKAGECONFIG[PDF] = "-DENABLE_PDF=ON,-DENABLE_PDF=OFF,zlib" | ||
32 | PACKAGECONFIG[Util] = "-DENABLE_UTIL=ON,-DENABLE_UTIL=OFF" | ||
33 | PACKAGECONFIG[Net] = "-DENABLE_NET=ON,-DENABLE_NET=OFF" | ||
34 | PACKAGECONFIG[NetSSL] = "-DENABLE_NETSSL=ON -DOPENSSL_SSL_LIBRARY:STRING=ssl -DOPENSSL_CRYPTO_LIBRARY:STRING=crypto,-DENABLE_NETSSL=OFF,openssl" | ||
35 | PACKAGECONFIG[Crypto] = "-DENABLE_CRYPTO=ON -DOPENSSL_SSL_LIBRARY:STRING=ssl -DOPENSSL_CRYPTO_LIBRARY:STRING=crypto,-DENABLE_CRYPTO=OFF,openssl" | ||
36 | PACKAGECONFIG[Data] = "-DENABLE_DATA=ON,-DENABLE_DATA=OFF" | ||
37 | PACKAGECONFIG[DataSQLite] = "-DENABLE_DATA_SQLITE=ON -DSQLITE3_LIBRARY:STRING=sqlite3,-DENABLE_DATA_SQLITE=OFF,sqlite3" | ||
38 | PACKAGECONFIG[Zip] = "-DENABLE_ZIP=ON,-DENABLE_ZIP=OFF" | ||
39 | PACKAGECONFIG[Encodings] = "-DENABLE_ENCODINGS=ON,-DENABLE_ENCODINGS=OFF" | ||
40 | PACKAGECONFIG[Redis] = "-DENABLE_REDIS=ON,-DENABLE_REDIS=OFF" | ||
41 | |||
42 | # Additional components not build by default, | ||
43 | # they might have dependencies not included in oe-core | ||
44 | # or they don't work on all architectures | ||
45 | PACKAGECONFIG[mod_poco] = "-DENABLE_APACHECONNECTOR=ON,-DENABLE_APACHECONNECTOR=OFF,apr apache2" | ||
46 | PACKAGECONFIG[CppParser] = "-DENABLE_CPPPARSER=ON,-DENABLE_CPPPARSER=OFF" | ||
47 | PACKAGECONFIG[DataMySQL] = "-DENABLE_DATA_MYSQL=ON -DMYSQL_LIB:STRING=mysqlclient_r,-DENABLE_DATA_MYSQL=OFF,mariadb" | ||
48 | PACKAGECONFIG[DataODBC] = "-DENABLE_DATA_ODBC=ON,-DENABLE_DATA_ODBC=OFF,libiodbc" | ||
49 | PACKAGECONFIG[PageCompiler] = "-DENABLE_PAGECOMPILER=ON,-DENABLE_PAGECOMPILER=OFF" | ||
50 | PACKAGECONFIG[PageCompilerFile2Page] = "-DENABLE_PAGECOMPILER_FILE2PAGE=ON,-DENABLE_PAGECOMPILER_FILE2PAGE=OFF" | ||
51 | PACKAGECONFIG[SevenZip] = "-DENABLE_SEVENZIP=ON,-DENABLE_SEVENZIP=OFF" | ||
52 | |||
53 | EXTRA_OECMAKE = "-DCMAKE_BUILD_TYPE=RelWithDebInfo -DPOCO_UNBUNDLED=ON \ | ||
54 | -DZLIB_LIBRARY_RELEASE:STRING=z -DPCRE_LIBRARY:STRING=pcre \ | ||
55 | ${@bb.utils.contains('PTEST_ENABLED', '1', '-DENABLE_TESTS=ON ', '', d)}" | ||
56 | |||
57 | # For the native build we want to use the bundled version | ||
58 | EXTRA_OECMAKE_append_class-native = " -DPOCO_UNBUNDLED=OFF" | ||
59 | |||
60 | # do not use rpath | ||
61 | EXTRA_OECMAKE_append = " -DCMAKE_SKIP_RPATH=ON" | ||
62 | |||
63 | python populate_packages_prepend () { | ||
64 | poco_libdir = d.expand('${libdir}') | ||
65 | pn = d.getVar("PN") | ||
66 | packages = [] | ||
67 | testrunners = [] | ||
68 | |||
69 | def hook(f, pkg, file_regex, output_pattern, modulename): | ||
70 | packages.append(pkg) | ||
71 | testrunners.append(modulename) | ||
72 | |||
73 | do_split_packages(d, poco_libdir, '^libPoco(.*)\.so\..*$', | ||
74 | 'poco-%s', 'Poco %s component', extra_depends='', prepend=True, hook=hook) | ||
75 | |||
76 | d.setVar("RRECOMMENDS_%s" % pn, " ".join(packages)) | ||
77 | d.setVar("POCO_TESTRUNNERS", "\n".join(testrunners)) | ||
78 | } | ||
79 | |||
80 | do_install_ptest () { | ||
81 | cp -rf ${B}/bin/ ${D}${PTEST_PATH} | ||
82 | cp -f ${B}/lib/libCppUnit.so* ${D}${libdir} | ||
83 | cp -rf ${B}/*/testsuite/data ${D}${PTEST_PATH}/bin/ | ||
84 | find "${D}${PTEST_PATH}" -executable -exec chrpath -d {} \; | ||
85 | echo "${POCO_TESTRUNNERS}" > "${D}${PTEST_PATH}/testrunners" | ||
86 | } | ||
87 | |||
88 | PACKAGES_DYNAMIC = "poco-.*" | ||
89 | |||
90 | # "poco" is a metapackage which pulls in all Poco components | ||
91 | ALLOW_EMPTY_${PN} = "1" | ||
92 | |||
93 | # cppunit is only built if tests are enabled | ||
94 | PACKAGES =+ "${PN}-cppunit" | ||
95 | FILES_${PN}-cppunit += "${libdir}/libCppUnit.so*" | ||
96 | ALLOW_EMPTY_${PN}-cppunit = "1" | ||
97 | |||
98 | RDEPENDS_${PN}-ptest += "${PN}-cppunit" | ||
99 | |||
100 | BBCLASSEXTEND = "native" | ||