dlt-daemon: upgrade 2.18.7 -> 2.18.8

317.patch
removed since it is included in 2.18.8

Changelog:
=========
lib: Fix wrong type alert from lgtm
gtest_dlt_daemon_gateway: fix gtest build failed
lib: generate dlt library internal log file
tests: add stdlib to dlt_cpp_extension
dlt_user: Make dlt_init thread safe
remove clang-tidy analyzer warnings: incompatible pointer type
debian: improve debian build package
dlt-control-common: shutdown and close socket
dlt_common: improve function description
gtest: Bring-in changes
gtest: Rework WORKING_DIRECTORY
gtest: Correct data amount in gtest_dlt_common
cmake: Set empty to systemd_SRCS
gtest: Refactor tests/CMakeLists.txt
lib: Add SOCK_CLOEXEC to socket
daemon: Create parent directory for unix socket
cmake: Correct added subdirectories
console: Add cmake options for control and timestamp
tests: Adapt to DLT_DISABLE_MACRO
header: Adapt to DLT_DISABLE_MACRO
include: Refactor CMakeLists.txt
gtest: Change script name to gtest_dlt_daemon_offline_log.sh
daemon: Enable to use FIFO on QNX
tests: Add new test case with given buffer
tests: Enable macro disabling
lib: Add new interfaces with given buffer
Implemention of tests for the dlt-qnx-system module
lib: Add MaxFileSize handling
client: pthread_join for deinit
doc: update initial log level document
dlt-system: Fix memory leak in dlt-system config
dlt_common: remove duplicate stdbool header
dlt-control: Add option to config port
system: use signalfd for dlt-system
console: provides args option to enable send/receive serial header
fix malformed printf format strings (#295)
cmake: Set WITH_LEGACY_INCLUDE_PATH to ON as default (#334)
Make the legacy include path a CMake option (#332)
daemon: Call dlt_daemon_configuration_load() properly (#330)
dlt_user: Use pthread_setname_np() if available (#326)
libdlt: Add legacy include path in exported CMake config file (#327)
lib: Set TYLE to 1 for BOOL type (#320)
file-transfer: Abort file transfer if get serial number failed
dlt_user.c: fixing casting wrong type
dlt-sortbytimestamp: Remove duplicated conditional statements code
dlt-convert: Remove duplicated conditional statements code
doc: Minor fix in dlt_for_developers.md (#321)
dlt-control-common.c: Fix build failure due to out-of-bound write -Werror=stringop-truncation
Extend include path in *.pc file (#319)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 66 insertions, 0 deletions

diff --git a/meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.8.bb b/meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.8.bb
new file mode 100644
index 000000000..c3fa4677e
--- /dev/null
+++ b/meta-oe/recipes-extended/dlt-daemon/dlt-daemon_2.18.8.bb
@@ -0,0 +1,66 @@
+SUMMARY = "Diagnostic Log and Trace"
+DESCRIPTION = "This component provides a standardised log and trace interface, \
+based on the standardised protocol specified in the AUTOSAR standard 4.0 DLT. \
+This component can be used by GENIVI components and other applications as \
+logging facility providing: \
+- the DLT shared library \
+- the DLT daemon, including startup scripts \
+- the DLT daemon adaptors- the DLT client console utilities \
+- the DLT test applications"
+HOMEPAGE = "https://www.genivi.org/"
+SECTION = "console/utils"
+LICENSE = "MPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8184208060df880fe3137b93eb88aeea"
+
+DEPENDS = "zlib gzip-native json-c"
+
+SRC_URI = "git://github.com/GENIVI/${BPN}.git;protocol=https;branch=master \
+           file://0002-Don-t-execute-processes-as-a-specific-user.patch \
+           file://0004-Modify-systemd-config-directory.patch \
+           "
+SRCREV = "1438fcf8c88cd47b20b2984180a8457c3eb9193d"
+
+S = "${WORKDIR}/git"
+
+PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', ' systemd systemd-watchdog systemd-journal dlt-examples dlt-adaptor dlt-console ', '', d)} \
+ udp-connection dlt-system dlt-filetransfer "
+# dlt-dbus
+
+# General options
+PACKAGECONFIG[dlt-examples] = "-DWITH_DLT_EXAMPLES=ON,-DWITH_DLT_EXAMPLES=OFF,,dlt-daemon-systemd"
+
+# Linux options
+PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF -DWITH_DLT_SYSTEM=OFF,systemd"
+PACKAGECONFIG[systemd-watchdog] = "-DWITH_SYSTEMD_WATCHDOG=ON,-DWITH_SYSTEMD_WATCHDOG=OFF,systemd,libsystemd"
+PACKAGECONFIG[systemd-journal] = "-DWITH_SYSTEMD_JOURNAL=ON,-DWITH_SYSTEMD_JOURNAL=OFF,systemd,libsystemd"
+PACKAGECONFIG[dlt-dbus] = "-DWITH_DLT_DBUS=ON,-DWITH_DLT_DBUS=OFF,dbus,dbus-lib"
+PACKAGECONFIG[udp-connection] = "-DWITH_UDP_CONNECTION=ON,-DWITH_UDP_CONNECTION=OFF"
+
+# Command line options
+PACKAGECONFIG[dlt-system] = "-DWITH_DLT_SYSTEM=ON,-DWITH_DLT_SYSTEM=OFF"
+PACKAGECONFIG[dlt-adaptor] = "-DWITH_DLT_ADAPTOR=ON,-DWITH_DLT_ADAPTOR=OFF,,dlt-daemon-systemd"
+PACKAGECONFIG[dlt-filetransfer] = "-DWITH_DLT_FILETRANSFER=ON,-DWITH_DLT_FILETRANSFER=OFF"
+PACKAGECONFIG[dlt-console] = "-DWITH_DLT_CONSOLE=ON,-DWITH_DLT_CONSOLE=OFF,,dlt-daemon-systemd"
+
+inherit autotools gettext cmake pkgconfig systemd
+
+EXTRA_OECMAKE += "-DWITH_EXTENDED_FILTERING=ON -DSYSTEMD_UNITDIR=${systemd_system_unitdir}"
+
+PACKAGES += "${PN}-systemd"
+SYSTEMD_PACKAGES = "${PN} ${PN}-systemd"
+SYSTEMD_SERVICE:${PN} = " ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'dlt.service', '', d)} \
+                          ${@bb.utils.contains('PACKAGECONFIG', 'dlt-system', 'dlt-system.service', '', d)} \
+                          ${@bb.utils.contains('PACKAGECONFIG', 'dlt-dbus', 'dlt-dbus.service', '', d)}"
+SYSTEMD_AUTO_ENABLE:${PN} = "enable"
+SYSTEMD_SERVICE:${PN}-systemd = " \
+    ${@bb.utils.contains('PACKAGECONFIG', 'dlt-adaptor', 'dlt-adaptor-udp.service', '', d)} \
+    ${@bb.utils.contains('PACKAGECONFIG', 'dlt-examples', 'dlt-example-user.service', '', d)} \
+    ${@bb.utils.contains('PACKAGECONFIG', 'dlt-examples dlt-console', 'dlt-receive.service', '', d)} \
+"
+SYSTEMD_AUTO_ENABLE:${PN}-systemd = "disable"
+
+FILES:${PN}-doc += "${datadir}/dlt-filetransfer"
+
+do_install:append() {
+    rm -f ${D}${bindir}/dlt-test-*
+}