protobuf: update to version 3.5.1

Signed-off-by: Derek Straka <derek@asterius.io>
Signed-off-by: Armin Kuster <akuster808@gmail.com>

1 files changed, 84 insertions, 0 deletions

diff --git a/meta-oe/recipes-devtools/protobuf/protobuf_3.5.1.bb b/meta-oe/recipes-devtools/protobuf/protobuf_3.5.1.bb
new file mode 100644
index 000000000..1ffb79da7
--- /dev/null
+++ b/meta-oe/recipes-devtools/protobuf/protobuf_3.5.1.bb
@@ -0,0 +1,84 @@
+SUMMARY = "Protocol Buffers - structured data serialisation mechanism"
+DESCRIPTION = "Protocol Buffers are a way of encoding structured data in an \
+efficient yet extensible format. Google uses Protocol Buffers for almost \
+all of its internal RPC protocols and file formats."
+HOMEPAGE = "https://github.com/google/protobuf"
+SECTION = "console/tools"
+LICENSE = "BSD-3-Clause"
+
+PACKAGE_BEFORE_PN = "${PN}-compiler ${PN}-lite"
+
+DEPENDS = "zlib"
+DEPENDS_append_class-target  = " protobuf-native"
+RDEPENDS_${PN}-compiler = "${PN}"
+RDEPENDS_${PN}-dev += "${PN}-compiler"
+RDEPENDS_${PN}-ptest = "bash python-protobuf"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=35953c752efc9299b184f91bef540095"
+
+SRCREV = "106ffc04be1abf3ff3399f54ccf149815b287dd9"
+
+PV = "3.5.1+git${SRCPV}"
+
+SRC_URI = "git://github.com/google/protobuf.git;branch=3.5.x \
+           file://run-ptest \
+          "
+
+EXTRA_OECONF += " --with-protoc=echo"
+
+inherit autotools-brokensep pkgconfig ptest
+
+S = "${WORKDIR}/git"
+TEST_SRC_DIR="examples"
+LANG_SUPPORT="cpp python"
+
+do_compile_ptest() {
+        # Modify makefile to use the cross-compiler
+        sed -e "s|c++|${CXX} \$(LDFLAGS)|g" -i "${S}/${TEST_SRC_DIR}/Makefile"
+
+        mkdir -p "${B}/${TEST_SRC_DIR}"
+
+        # Add the location of the cross-compiled header and library files
+        # which haven't been installed yet.
+        cp "${B}/protobuf.pc" "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        sed -e 's|libdir=|libdir=${PKG_CONFIG_SYSROOT_DIR}|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        sed -e 's|Cflags:|Cflags: -I${S}/src|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        sed -e 's|Libs:|Libs: -L${B}/src/.libs|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        export PKG_CONFIG_PATH="${B}/${TEST_SRC_DIR}"
+
+        # Save the pkgcfg sysroot variable, and update it to nothing so
+        # that it doesn't append the sysroot to the beginning of paths.
+        # The header and library files aren't installed to the target
+        # system yet.  So the absolute paths were specified above.
+        save_pkg_config_sysroot_dir=$PKG_CONFIG_SYSROOT_DIR
+        export PKG_CONFIG_SYSROOT_DIR=
+
+        # Compile the tests
+        for lang in ${LANG_SUPPORT}; do
+                oe_runmake -C "${S}/${TEST_SRC_DIR}" ${lang}
+        done
+
+        # Restore the pkgconfig sysroot variable
+        export PKG_CONFIG_SYSROOT_DIR=$save_pkg_config_sysroot_dir
+}
+
+do_install_ptest() {
+        local olddir=`pwd`
+
+        cd "${S}/${TEST_SRC_DIR}"
+        install -d "${D}/${PTEST_PATH}"
+        for i in add_person* list_people*; do
+                if [ -x "$i" ]; then
+                        install "$i" "${D}/${PTEST_PATH}"
+                fi
+        done
+        cp "${S}/${TEST_SRC_DIR}/addressbook_pb2.py" "${D}/${PTEST_PATH}"
+        cd "$olddir"
+}
+
+FILES_${PN}-compiler = "${bindir} ${libdir}/libprotoc${SOLIBS}"
+FILES_${PN}-lite = "${bindir} ${libdir}/libprotobuf-lite${SOLIBS}"
+
+MIPS_INSTRUCTION_SET = "mips"
+
+BBCLASSEXTEND = "native nativesdk"