nftables: Expand PACKAGECONFIG, cleanup build

Fill out PACKAGECONFIG options for json, mini-gmp, readline and xtables
whilst matching existing behaviour. Drop PACKAGECONFIG to weak default.

Fix upstream version matching so the very old 0.099 is rejected as the
newest version.

Drop seemingly redundant ASNEEDED which was added in 5477d5bcb727
("nftables: Upgrade to 0.7") without explanation.

Package python files from libdir not libdir_native; whilst they're the
same thing, building a target package with native variables is odd.

Signed-off-by: Alex Kiernan <alex.kiernan@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 12 insertions, 8 deletions

diff --git a/meta-networking/recipes-filter/nftables/nftables_0.9.3.bb b/meta-networking/recipes-filter/nftables/nftables_0.9.3.bb
index 7302626165..dc04326bc9 100644
--- a/meta-networking/recipes-filter/nftables/nftables_0.9.3.bb
+++ b/meta-networking/recipes-filter/nftables/nftables_0.9.3.bb
@@ -3,9 +3,11 @@ SECTION = "net"
 LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=d1a78fdd879a263a5e0b42d1fc565e79"
 
-DEPENDS = "libmnl libnftnl readline gmp bison-native"
+DEPENDS = "libmnl libnftnl bison-native \
+           ${@bb.utils.contains('PACKAGECONFIG', 'mini-gmp', '', 'gmp', d)}"
 
-UPSTREAM_CHECK_URI = "https://www.netfilter.org/projects/nftables/files/"
+# Ensure we reject the 0.099 version by matching at least two dots
+UPSTREAM_CHECK_REGEX = "nftables-(?P<pver>\d+(\.\d+){2,}).tar.bz2"
 
 SRC_URI = "http://www.netfilter.org/projects/nftables/files/${BP}.tar.bz2 \
            file://0001-update-python3-nftables-reference.patch"
@@ -14,16 +16,18 @@ SRC_URI[sha256sum] = "956b915ce2a7aeaff123e49006be7a0690a0964e96c062703181a36e2e
 
 inherit autotools manpages pkgconfig
 
-PACKAGECONFIG ?= "python"
-PACKAGECONFIG[manpages] = ", --disable-man-doc, asciidoc-native"
-PACKAGECONFIG[python] = "--with-python-bin=${PYTHON}, --with-python-bin="", python3"
+PACKAGECONFIG ??= "python readline"
+PACKAGECONFIG[json] = "--with-json, --without-json, jansson"
+PACKAGECONFIG[manpages] = "--enable-man-doc, --disable-man-doc, asciidoc-native"
+PACKAGECONFIG[mini-gmp] = "--with-mini-gmp, --without-mini-gmp"
+PACKAGECONFIG[python] = "--enable-python --with-python-bin=${PYTHON}, --with-python-bin="", python3"
+PACKAGECONFIG[readline] = "--with-cli=readline, --without-cli, readline"
+PACKAGECONFIG[xtables] = "--with-xtables, --without-xtables, iptables"
 
 inherit ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3native', '', d)}
 
-ASNEEDED = ""
-
 RRECOMMENDS_${PN} += "kernel-module-nf-tables"
 
 PACKAGES =+ "${PN}-python"
-FILES_${PN}-python = "${libdir_native}/${PYTHON_DIR}"
+FILES_${PN}-python = "${libdir}/${PYTHON_DIR}"
 RDEPENDS_${PN}-python = "python3-core python3-json"