cyrus-sasl2: add 2.1.26

I took recipe from OE classic, updated, cleaned and got it build. I use
it only as build dependency - did not checked binaries from ${PN}-bin.

There are RPATH problems to solve:

WARNING: QA Issue: package cyrus-sasl-bin contains bad RPATH
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/sysroots/genericarmv8/usr/lib
in file
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/work/aarch64-oe-linux/cyrus-sasl/2.1.26-r0/packages-split/cyrus-sasl-bin/usr/sbin/saslpasswd2
WARNING: QA Issue: package cyrus-sasl-bin contains bad RPATH
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/sysroots/genericarmv8/usr/lib
in file
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/work/aarch64-oe-linux/cyrus-sasl/2.1.26-r0/packages-split/cyrus-sasl-bin/usr/sbin/pluginviewer
WARNING: QA Issue: package cyrus-sasl-bin contains bad RPATH
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/sysroots/genericarmv8/usr/lib
in file
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/work/aarch64-oe-linux/cyrus-sasl/2.1.26-r0/packages-split/cyrus-sasl-bin/usr/sbin/sasldblistusers2
WARNING: QA Issue: package cyrus-sasl contains bad RPATH
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/sysroots/genericarmv8/usr/lib
in file
/home/hrw/HDD/devel/canonical/aarch64/openembedded/build/tmp-eglibc/work/aarch64-oe-linux/cyrus-sasl/2.1.26-r0/packages-split/cyrus-sasl/usr/lib/sasl2/libsasldb.so.3.0.0

Signed-off-by: Marcin Juszkiewicz <marcin.juszkiewicz@linaro.org>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 42 insertions, 0 deletions

diff --git a/meta-networking/recipes-daemons/cyrus-sasl/cyrus-sasl_2.1.26.bb b/meta-networking/recipes-daemons/cyrus-sasl/cyrus-sasl_2.1.26.bb
new file mode 100644
index 0000000000..44336f0590
--- /dev/null
+++ b/meta-networking/recipes-daemons/cyrus-sasl/cyrus-sasl_2.1.26.bb
@@ -0,0 +1,42 @@
+DESCRIPTION = "Generic client/server library for SASL authentication."
+SECTION = "console/network"
+DEPENDS = "openssl virtual/db"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3f55e0974e3d6db00ca6f57f2d206396"
+
+SRC_URI = "ftp://ftp.cyrusimap.org/cyrus-sasl/cyrus-sasl-${PV}.tar.gz "
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF += "--with-dblib=berkeley \
+                 --with-bdb-libdir=${STAGING_LIBDIR} \
+                 --with-bdb-incdir=${STAGING_INCDIR} \
+                 --without-pam --without-opie --without-des"
+
+do_configure_prepend () {
+    rm -f acinclude.m4 config/libtool.m4
+}
+
+do_compile_prepend () {
+    cd include
+    ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} makemd5.c -o makemd5
+    touch makemd5.o makemd5.lo makemd5
+    cd ..
+}
+
+pkg_postinst_${PN}-bin () {
+    grep cyrus /etc/passwd || adduser --disabled-password --home=/var/spool/mail --ingroup mail -g "Cyrus sasl" cyrus
+    echo "cyrus" | saslpasswd2 -p -c cyrus
+    chgrp mail /etc/sasldb2
+}
+
+SRC_URI[md5sum] = "a7f4e5e559a0e37b3ffc438c9456e425"
+SRC_URI[sha256sum] = "8fbc5136512b59bb793657f36fadda6359cae3b08f01fd16b3d406f1345b7bc3"
+
+PACKAGES =+ "${PN}-bin"
+
+FILES_${PN}           += "${libdir}/sasl2/*.so.*"
+FILES_${PN}-bin       += "${bindir}"
+FILES_${PN}-dev       += "${libdir}/sasl2/*.so ${libdir}/sasl2/*.la"
+FILES_${PN}-dbg       += "${libdir}/sasl2/.debug"
+FILES_${PN}-staticdev += "${libdir}/sasl2/*.a"