openjdk-8: update to latest ga version 242

As OpenJDK-8 is now tagging "ga" versions in addition to the "build"
version the recipes are adapted to use those "ga" versions.

All existing patches got re-applied and renamed. For better handling Hotspot
patches now start at patch number 1001 and jdk patches at 2001.

Furthermore architecture dependent patches are prefixed with the
architecture they apply on.

Following patches/hunks were completely dropped:
- 0002-hotspot-fix-compilation-with-security-flags-enabled.patch
    got backported to hotspot jdk8u
    https://hg.openjdk.java.net/jdk8u/jdk8u/hotspot/rev/c40a28e54185
- 0011-hotspot-backport-patch-to-fix-misuses-of-strncpy-str.patch
    ostream.cpp:112 got fixed in hotspot jdk8u
    https://hg.openjdk.java.net/jdk8u/jdk8u/hotspot/rev/f3108e56b502
- 0014-hotspot-zero-fix-undefined-behaviour-gcc-v8-fix.patch
    got backported to hotspot jdk8u
    https://hg.openjdk.java.net/jdk8u/jdk8u/hotspot/rev/ca4663e58916
- 0018-hotspot-Fix-debug-build-after-8062808-Turn-on-the-Wr.patch
    fixed in hotspot jdk8u
    https://hg.openjdk.java.net/jdk8u/jdk8u/hotspot/rev/32bc598624bd
- 0020-Enable-HotSpot-builds-on-5.x-Linux-kernels.patch
    fixed in hotspot jdk8u
    https://hg.openjdk.java.net/jdk8u/jdk8u/hotspot/rev/5af8ec63c21c
- openjdk8-add-missing-linker-flags.patch
    fixed in hotspot jdk8u
    https://hg.openjdk.java.net/jdk8u/jdk8u/hotspot/rev/f175513c2c3a
- openjdk8-fix-shark-stdc++11.patch
    fixed in hotspot jdk8u
- openjdk8-fix-libpng-neon-build.patch
    fixed in jdk
    https://hg.openjdk.java.net/jdk8u/jdk8u/jdk/rev/5d57817931e1
- aarch64-hotspot-fix-undefined-behaviour-gcc-v8-fix.patch
    got backported to hotspot jdk8u

Following patches were newly added:
- 0011-autoconf-fix-CC-with-arguments-detection.patch
    needed because of jdk8u commit "8038340: Cleanup and fix sysroot and devkit handling on Linux and Solaris"
- 0012-autoconf-NativeCompilation-remove-sysroot.patch
    needed because of jdk8u commit "8038340: Cleanup and fix sysroot and devkit handling on Linux and Solaris"

Signed-off-by: Richard Leitner <richard.leitner@skidata.com>

1 files changed, 61 insertions, 0 deletions

diff --git a/recipes-core/openjdk/openjdk-8_242.bb b/recipes-core/openjdk/openjdk-8_242.bb
new file mode 100644
index 0000000..bc6ce51
--- /dev/null
+++ b/recipes-core/openjdk/openjdk-8_242.bb
@@ -0,0 +1,61 @@
+INC_FILE_SUFFIX = ""
+INC_FILE_SUFFIX_aarch64 = "-aarch64"
+INC_FILE_SUFFIX_armv7a = "-aarch32"
+INC_FILE_SUFFIX_armv7ve = "-aarch32"
+require openjdk-8-release${INC_FILE_SUFFIX}.inc
+require openjdk-8-cross.inc
+
+do_install() {
+    rm -rf ${D}${JDK_HOME}
+    mkdir -p ${D}${JDK_HOME}
+    cp -rp ${B}/images/j2sdk-image/* ${D}${JDK_HOME}
+    chown -R root:root ${D}${JDK_HOME}
+    install -m644 ${WORKDIR}/jvm.cfg  ${D}${JDK_HOME}/jre/lib/${JDK_ARCH}/
+    find ${D}${JDK_HOME} -name "*.debuginfo" -exec rm {} \;
+}
+
+PACKAGES_append = " \
+    ${PN}-demo \
+    ${PN}-source \
+"
+
+FILES_${PN}_append = "\
+    ${JDK_HOME}/bin/[a-z]* \
+    ${JDK_HOME}/lib/[a-z]* \
+    ${JDK_HOME}/jre/bin/[a-z]* \
+    ${JDK_HOME}/jre/lib/[a-z]* \
+    ${JDK_HOME}/LICENSE \
+    ${JDK_HOME}/jre/LICENSE \
+    ${JDK_HOME}/release \
+"
+
+FILES_${PN}-dev_append = "\
+    ${JDK_HOME}/include \
+"
+
+FILES_${PN}-demo = " ${JDK_HOME}/demo ${JDK_HOME}/sample "
+RDEPENDS_${PN}-demo = " ${PN} "
+
+FILES_${PN}-doc_append = "\
+    ${JDK_HOME}/man \
+    ${JDK_HOME}/ASSEMBLY_EXCEPTION \
+    ${JDK_HOME}/THIRD_PARTY_README \
+    ${JDK_HOME}/jre/ASSEMBLY_EXCEPTION \
+    ${JDK_HOME}/jre/THIRD_PARTY_README \
+    ${JDK_HOME}/man \
+"
+
+FILES_${PN}-source = " ${JDK_HOME}/src.zip "
+
+RPROVIDES_${PN} = "java2-runtime"
+
+inherit update-alternatives
+
+ALTERNATIVE_PRIORITY = "100"
+
+ALTERNATIVE_${PN} = "java javac"
+ALTERNATIVE_LINK_NAME[java] = "${bindir}/java"
+ALTERNATIVE_TARGET[java] = "${JDK_HOME}/bin/java"
+
+ALTERNATIVE_LINK_NAME[javac] = "${bindir}/javac"
+ALTERNATIVE_TARGET[javac] = "${JDK_HOME}/bin/javac"