3 files changed, 101 insertions, 0 deletions

diff --git a/recipes-multimedia/vpl/files/0001-vpl.pc.in-dont-pass-pcfiledir-to-cflags.patch b/recipes-multimedia/vpl/files/0001-vpl.pc.in-dont-pass-pcfiledir-to-cflags.patch
new file mode 100644
index 00000000..f9a568a7
--- /dev/null
+++ b/recipes-multimedia/vpl/files/0001-vpl.pc.in-dont-pass-pcfiledir-to-cflags.patch
@@ -0,0 +1,25 @@
+From ff715f4c543ddabc5c90160d0ae5c5598e8e1289 Mon Sep 17 00:00:00 2001
+From: Markus Volk <f_l_k@t-online.de>
+Date: Thu, 15 Jun 2023 13:43:32 +0200
+Subject: [PATCH] vpl.pc.in: dont pass pcfiledir to cflags
+
+Signed-off-by: Markus Volk <f_l_k@t-online.de>
+
+Upstream-Status: Inappropriate [oe specific]
+---
+ libvpl/pkgconfig/vpl.pc.in | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/libvpl/pkgconfig/vpl.pc.in b/libvpl/pkgconfig/vpl.pc.in
+index aa9b158..b4e85ff 100644
+--- a/libvpl/pkgconfig/vpl.pc.in
++++ b/libvpl/pkgconfig/vpl.pc.in
+@@ -7,6 +7,6 @@ Description: Accelerated video decode, encode, and frame processing capabilities
+ Version: @API_VERSION_MAJOR@.@API_VERSION_MINOR@
+ URL: https://github.com/intel/libvpl
+ 
+-Libs: -L${libdir} -l@OUTPUT_NAME@ @VPL_PKGCONFIG_DEPENDENT_LIBS@
++Libs: -L@CMAKE_INSTALL_PREFIX@/@CMAKE_INSTALL_LIBDIR@ -l@OUTPUT_NAME@ @VPL_PKGCONFIG_DEPENDENT_LIBS@
+ Libs.private: @VPL_PKGCONFIG_PRIVATE_LIBS@
+-Cflags: -I${includedir} -I${includedir}/vpl
++Cflags: -I@CMAKE_INSTALL_PREFIX@/@CMAKE_INSTALL_INCLUDEDIR@ -I@CMAKE_INSTALL_PREFIX@/@CMAKE_INSTALL_INCLUDEDIR@/vpl
diff --git a/recipes-multimedia/vpl/libvpl_2.10.2.bb b/recipes-multimedia/vpl/libvpl_2.10.2.bb
new file mode 100644
index 00000000..04888e97
--- /dev/null
+++ b/recipes-multimedia/vpl/libvpl_2.10.2.bb
@@ -0,0 +1,43 @@
+SUMMARY = "Intel Video Processing Library"
+DESCRIPTION = "Intel Video Processing Library (VPL) provides \
+a single video processing API for encode, decode, and video processing \
+that works across a wide range of accelerators."
+
+HOMEPAGE = "https://github.com/intel/libvpl"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c18ea6bb4786a26bf4eee88a7424a408 \
+                    file://third-party-programs.txt;md5=ddf05049184e74942f45b0ca4cc69b8a"
+
+SRC_URI = "git://github.com/intel/libvpl.git;protocol=https;branch=main \
+           file://0001-vpl.pc.in-dont-pass-pcfiledir-to-cflags.patch \
+            "
+SRCREV = "383b5caac6df614e76ade5a07c4f53be702e9176"
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "libva pkgconfig-native"
+
+PACKAGECONFIG ??= "tools"
+PACKAGECONFIG[tools] = "-DBUILD_TOOLS=ON, -DBUILD_TOOLS=OFF, wayland wayland-native wayland-protocols"
+
+do_install:append() {
+        mkdir -p ${D}${datadir}/VPL/samples
+        mv ${D}${bindir}/sample_* ${D}${datadir}/VPL/samples
+}
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+
+PACKAGES =+ "${PN}-examples"
+
+RREPLACES:${PN} = "onevpl"
+RCONFLICTS:${PN} = "onevpl"
+
+FILES:${PN}-examples = "${datadir}/vpl \
+                       "
+
+FILES_SOLIBSDEV = ""
+FILES:${PN}-dev += "${libdir}/libvpl.so"
+
+FILES:${PN} += " ${datadir}/VPL/samples  \
+                ${libdir}/vpl/libvpl_wayland.so \
+                "
diff --git a/recipes-multimedia/vpl/vpl-gpu-rt_24.1.5.bb b/recipes-multimedia/vpl/vpl-gpu-rt_24.1.5.bb
new file mode 100644
index 00000000..40909a9c
--- /dev/null
+++ b/recipes-multimedia/vpl/vpl-gpu-rt_24.1.5.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Intel(R) oneVPL runtime for Intel GPU accelerated media processing"
+DESCRIPTION = "Intel(R) oneVPL runtime provides an runtime to access hardware-accelerated \
+video decode, encode and filtering on Intel® graphics."
+
+HOMEPAGE = "https://github.com/intel/vpl-gpu-rt"
+BUGTRACKER = "https://github.com/intel/vpl-gpu-rt/issues"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=eb8cb45b9b57dbaa9fcc9adc4230202b"
+
+PE = "1"
+
+# Only for 64 bit
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST:x86-x32 = "null"
+
+DEPENDS += "libdrm libva intel-media-driver libvpl pkgconfig-native"
+RDEPENDS:${PN} += "intel-media-driver"
+
+SRC_URI = "git://github.com/intel/vpl-gpu-rt.git;protocol=https;nobranch=1;lfs=0 \
+          "
+
+SRCREV = "088db9f5a8164525f00685c72f00a4baed97b90a"
+S = "${WORKDIR}/git"
+
+FILES:${PN} += " \
+                ${libdir}/libmfx-gen/enctools.so \
+               "
+
+inherit cmake
+
+RREPLACES:${PN} = "onevpl-intel-gpu"
+RCONFLICTS:${PN} = "onevpl-intel-gpu"