1 files changed, 41 insertions, 0 deletions

diff --git a/recipes-multimedia/onevpl/onevpl_2022.2.2.bb b/recipes-multimedia/onevpl/onevpl_2022.2.2.bb
new file mode 100644
index 00000000..9e0196c1
--- /dev/null
+++ b/recipes-multimedia/onevpl/onevpl_2022.2.2.bb
@@ -0,0 +1,41 @@
+SUMMARY = "oneAPI Video Processing Library"
+DESCRIPTION = "The oneAPI Video Processing Library (oneVPL) provides \
+a single video processing API for encode, decode, and video processing \
+that works across a wide range of accelerators."
+
+HOMEPAGE = "https://github.com/oneapi-src/oneVPL"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c18ea6bb4786a26bf4eee88a7424a408 \
+                    file://third-party-programs.txt;md5=f43d223f2b736e89abed9660483d0386"
+
+SRC_URI = "git://github.com/oneapi-src/oneVPL.git;protocol=https;branch=master \
+            file://0001-Fix-missing-UYVY-VA_FOURCC-causing-encode-failure.patch \
+            file://0001-Enable-xdg_shell-for-weston10.patch \
+            "
+SRCREV = "15b79165c30fc4a7bf6efdf261a39b128b63b896"
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "libva pkgconfig-native"
+
+PACKAGECONFIG ??= "tools"
+PACKAGECONFIG[tools] = "-DBUILD_TOOLS=ON, -DBUILD_TOOLS=OFF, wayland wayland-native wayland-protocols"
+
+do_install:append() {
+        mkdir -p ${D}${datadir}/oneVPL/samples
+        mv ${D}${bindir}/sample_* ${D}${datadir}/oneVPL/samples
+}
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+
+PACKAGES += "${PN}-examples"
+
+FILES:${PN}-examples = "${datadir}/oneVPL/examples \
+                       "
+
+FILES_SOLIBSDEV = ""
+FILES:${PN}-dev += "${libdir}/libvpl.so"
+
+FILES:${PN} += "${datadir} \
+                ${libdir}/vpl/libvpl_wayland.so \
+                "