1 files changed, 53 insertions, 0 deletions

diff --git a/recipes-multimedia/libva/intel-media-driver_20.4.3.bb b/recipes-multimedia/libva/intel-media-driver_20.4.3.bb
new file mode 100644
index 00000000..dcae5c29
--- /dev/null
+++ b/recipes-multimedia/libva/intel-media-driver_20.4.3.bb
@@ -0,0 +1,53 @@
+SUMMARY = "VA driver for Intel Gen based graphics hardware"
+DESCRIPTION = "Intel Media Driver for VAAPI is a new VA-API (Video Acceleration API) \
+user mode driver supporting hardware accelerated decoding, encoding, \
+and video post processing for GEN based graphics hardware."
+
+HOMEPAGE = "https://github.com/intel/media-driver"
+BUGTRACKER = "https://github.com/intel/media-driver/issues"
+
+LICENSE = "MIT & BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=6aab5363823095ce682b155fef0231f0 \
+                    file://media_driver/media_libvpx.LICENSE;md5=d5b04755015be901744a78cc30d390d4 \
+                    "
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+inherit features_check
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+DEPENDS += "libva gmmlib"
+
+SRC_URI = "git://github.com/intel/media-driver.git;protocol=https;branch=intel-media-20.4 \
+           file://0001-Encode-Fixed-VP9-444-frame-header.patch \
+           file://0001-media_libva-export-packed-YUV-when-VA_EXPORT_SURFACE.patch \
+           file://0002-media-libva-Add-export-AYUV-color-in-vaExportSurface.patch \
+          "
+
+SRCREV = "1daed90e58cb9fb0a0dc6de9697aaad34b114507"
+S = "${WORKDIR}/git"
+
+COMPATIBLE_HOST_x86-x32 = "null"
+
+UPSTREAM_CHECK_GITTAGREGEX = "^intel-media-(?P<pver>(?!600\..*)\d+(\.\d+)+)$"
+
+inherit cmake pkgconfig
+
+MEDIA_DRIVER_ARCH_x86    = "32"
+MEDIA_DRIVER_ARCH_x86-64 = "64"
+
+EXTRA_OECMAKE += " \
+                   -DMEDIA_RUN_TEST_SUITE=OFF \
+                   -DARCH=${MEDIA_DRIVER_ARCH} \
+                   -DMEDIA_BUILD_FATAL_WARNINGS=OFF \
+                  "
+
+CXXFLAGS_append_x86 = " -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE"
+
+do_configure_prepend_toolchain-clang() {
+    sed -i -e '/-fno-tree-pre/d' ${S}/media_driver/cmake/linux/media_compile_flags_linux.cmake
+}
+
+FILES_${PN} += " \
+                 ${libdir}/dri/ \
+                 "