summaryrefslogtreecommitdiffstats
path: root/recipes-graphics/intel-gpu-tools/igt-gpu-tools_1.23.bb
diff options
context:
space:
mode:
Diffstat (limited to 'recipes-graphics/intel-gpu-tools/igt-gpu-tools_1.23.bb')
-rw-r--r--recipes-graphics/intel-gpu-tools/igt-gpu-tools_1.23.bb42
1 files changed, 42 insertions, 0 deletions
diff --git a/recipes-graphics/intel-gpu-tools/igt-gpu-tools_1.23.bb b/recipes-graphics/intel-gpu-tools/igt-gpu-tools_1.23.bb
new file mode 100644
index 0000000..ffa4d83
--- /dev/null
+++ b/recipes-graphics/intel-gpu-tools/igt-gpu-tools_1.23.bb
@@ -0,0 +1,42 @@
1require ${COREBASE}/meta/recipes-graphics/xorg-app/xorg-app-common.inc
2
3SUMMARY = "Intel GPU tools"
4DESCRIPTION = "Variety of small tools for testing intel graphics."
5
6LIC_FILES_CHKSUM = "file://COPYING;md5=e4b3dd344780e0400593b21b115a6947"
7
8LICENSE_append = " & ISC"
9
10inherit autotools gtk-doc
11
12SRC_URI = "${XORG_MIRROR}/individual/app/${BP}.tar.xz"
13
14DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 libxv libx11 libxext libxrandr procps libunwind"
15RDEPENDS_${PN} += "bash"
16RDEPENDS_${PN}-tests += "bash"
17
18PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
19
20SRC_URI[md5sum] = "04c1f10d6fd85e079271540b0ea786e9"
21SRC_URI[sha256sum] = "4d4b086c513bace5c23d0889de3f42ac3ebd3d968c64dedae6e28e006a499ad0"
22
23EXTRA_OECONF = "--disable-nouveau --disable-shader-debugger"
24COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
25COMPATIBLE_HOST_libc-musl_class-target = "null"
26
27PACKAGECONFIG ??= ""
28PACKAGECONFIG[audio] = "--enable-audio,--disable-audio,alsa-lib gsl"
29
30gputools_sysroot_preprocess() {
31 rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
32}
33SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
34
35FILES_${PN} += "${libdir}/intel_aubdump.so"
36FILES_${PN}-benchmarks += "${libexecdir}/intel-gpu-tools/benchmarks"
37FILES_${PN}-tests += "\
38 ${libexecdir}/intel-gpu-tools/*\
39 ${datadir}/intel-gpu-tools/1080p-right.png\
40 ${datadir}/intel-gpu-tools/1080p-left.png\
41 ${datadir}/intel-gpu-tools/pass.png\
42 ${datadir}/intel-gpu-tools/test-list.txt"