summaryrefslogtreecommitdiffstats
path: root/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2024.1.0.bb
diff options
context:
space:
mode:
Diffstat (limited to 'dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2024.1.0.bb')
-rw-r--r--dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2024.1.0.bb146
1 files changed, 0 insertions, 146 deletions
diff --git a/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2024.1.0.bb b/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2024.1.0.bb
deleted file mode 100644
index 675d9920..00000000
--- a/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2024.1.0.bb
+++ /dev/null
@@ -1,146 +0,0 @@
1SUMMARY = "OpenVINO(TM) Toolkit - Deep Learning Deployment Toolkit"
2HOMEPAGE = "https://github.com/opencv/dldt"
3DESCRIPTION = "This toolkit allows developers to deploy pre-trained \
4deep learning models through a high-level C++ Inference Engine API \
5integrated with application logic."
6
7SRC_URI = "git://github.com/openvinotoolkit/openvino.git;protocol=https;name=openvino;branch=releases/2024/1;lfs=0 \
8 git://github.com/openvinotoolkit/oneDNN.git;protocol=https;destsuffix=git/src/plugins/intel_cpu/thirdparty/onednn;name=mkl;nobranch=1 \
9 git://github.com/oneapi-src/oneDNN.git;protocol=https;destsuffix=git/src/plugins/intel_gpu/thirdparty/onednn_gpu;name=onednn;nobranch=1 \
10 git://github.com/herumi/xbyak.git;protocol=https;destsuffix=git/thirdparty/xbyak;name=xbyak;branch=master \
11 git://github.com/nlohmann/json.git;protocol=https;destsuffix=git/thirdparty/json/nlohmann_json;name=json;branch=develop \
12 git://github.com/opencv/ade.git;protocol=https;destsuffix=git/thirdparty/ade;name=ade;nobranch=1 \
13 git://github.com/protocolbuffers/protobuf.git;protocol=https;destsuffix=git/thirdparty/protobuf/protobuf;name=protobuf;branch=3.20.x \
14 git://github.com/gflags/gflags.git;protocol=https;destsuffix=git/thirdparty/gflags/gflags;name=gflags;nobranch=1 \
15 git://github.com/madler/zlib.git;protocol=https;destsuffix=git/thirdparty/zlib/zlib;name=zlib;nobranch=1 \
16 git://github.com/openvinotoolkit/mlas.git;protocol=https;destsuffix=git/src/plugins/intel_cpu/thirdparty/mlas;name=mlas;nobranch=1 \
17 git://github.com/nodejs/node-api-headers.git;protocol=https;destsuffix=git/node-api-headers-src;name=node-api-headers;nobranch=1 \
18 git://github.com/nodejs/node-addon-api.git;protocol=https;destsuffix=git/node-addon-api-src;name=node-addon-api;nobranch=1 \
19 git://github.com/openvinotoolkit/telemetry.git;protocol=https;destsuffix=git/thirdparty/telemetry;name=telemetry;nobranch=1;lfs=0 \
20 file://0001-cmake-yocto-specific-tweaks-to-the-build-process.patch \
21 file://0002-cmake-Fix-overloaded-virtual-error.patch \
22 file://0003-protobuf-allow-target-protoc-to-be-built.patch \
23 "
24
25SRCREV_openvino = "f4afc983258bcb2592d999ed6700043fdb58ad78"
26SRCREV_mkl = "26633ae49edd4353a29b7170d9fcef6b2d79f4b3"
27SRCREV_onednn = "4e6ff043c439652fcf6c400ac4e0c81bbac7c71c"
28SRCREV_xbyak = "740dff2e866f3ae1a70dd42d6e8836847ed95cc2"
29SRCREV_json = "9cca280a4d0ccf0c08f47a99aa71d1b0e52f8d03"
30SRCREV_ade = "0e8a2ccdd34f29dba55894f5f3c5179809888b9e"
31SRCREV_protobuf = "fe271ab76f2ad2b2b28c10443865d2af21e27e0e"
32SRCREV_gflags = "e171aa2d15ed9eb17054558e0b3a6a413bb01067"
33SRCREV_zlib = "09155eaa2f9270dc4ed1fa13e2b4b2613e6e4851"
34SRCREV_mlas = "d1bc25ec4660cddd87804fcf03b2411b5dfb2e94"
35SRCREV_node-api-headers = "186e04b5e40e54d7fd1655bc67081cc483f12488"
36SRCREV_node-addon-api = "39a25bf27788ff7a7ea5c64978c4dcd1e7b9d80d"
37SRCREV_telemetry = "58e16c257a512ec7f451c9fccf9ff455065b285b"
38SRCREV_FORMAT = "openvino_mkl_onednn_xbyak_json_ade_protobuf_gflags_zlib_node-api-headers_node-addon-api_mlas_telemetry"
39
40LICENSE = "Apache-2.0 & MIT & BSD-3-Clause & Zlib"
41LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
42 file://thirdparty/xbyak/COPYRIGHT;md5=3c98edfaa50a86eeaef4c6109e803f16 \
43 file://thirdparty/cnpy/LICENSE;md5=689f10b06d1ca2d4b1057e67b16cd580 \
44 file://thirdparty/json/nlohmann_json/LICENSE.MIT;md5=f969127d7b7ed0a8a63c2bbeae002588 \
45 file://thirdparty/ade/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57 \
46 file://thirdparty/gflags/gflags/COPYING.txt;md5=c80d1a3b623f72bb85a4c75b556551df \
47 file://thirdparty/zlib/zlib/LICENSE;md5=b51a40671bc46e961c0498897742c0b8 \
48 file://src/plugins/intel_cpu/thirdparty/mlas/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
49 file://src/plugins/intel_cpu/thirdparty/onednn/LICENSE;md5=3b64000f6e7d52516017622a37a94ce9 \
50 file://src/plugins/intel_gpu/thirdparty/onednn_gpu/LICENSE;md5=3b64000f6e7d52516017622a37a94ce9 \
51 file://node-api-headers-src/LICENSE;md5=6adb2909701d4605b4b2ae1a9b25d8bd \
52 file://node-addon-api-src/LICENSE.md;md5=0492ef29a9d558a3e9660e7accc9ca6a \
53 file://thirdparty/telemetry/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
54"
55
56inherit cmake python3native pkgconfig qemu
57
58S = "${WORKDIR}/git"
59EXTRA_OECMAKE += " \
60 -DCMAKE_CROSSCOMPILING_EMULATOR=${WORKDIR}/qemuwrapper \
61 -DENABLE_OPENCV=OFF \
62 -DENABLE_INTEL_GNA=OFF \
63 -DENABLE_SYSTEM_TBB=ON \
64 -DPYTHON_EXECUTABLE=${PYTHON} \
65 -DCMAKE_BUILD_TYPE=RelWithDebInfo \
66 -DTHREADING=TBB -DTBB_DIR="${STAGING_LIBDIR}/cmake/TBB" \
67 -DTREAT_WARNING_AS_ERROR=FALSE \
68 -DENABLE_DATA=FALSE \
69 -DENABLE_SYSTEM_PUGIXML=TRUE \
70 -DENABLE_OV_ONNX_FRONTEND=FALSE \
71 -DUSE_BUILD_TYPE_SUBFOLDER=OFF \
72 -DENABLE_FUZZING=OFF \
73 -DENABLE_TBBBIND_2_5=OFF \
74 -DCPACK_GENERATOR=RPM \
75 -DENABLE_SYSTEM_FLATBUFFERS=ON \
76 -DENABLE_SYSTEM_SNAPPY=ON \
77 -DFETCHCONTENT_BASE_DIR="${S}" \
78 -DENABLE_INTEL_NPU=OFF \
79 "
80
81DEPENDS += "\
82 flatbuffers-native \
83 pugixml \
84 python3-pybind11 \
85 python3-pybind11-native \
86 qemu-native \
87 snappy \
88 tbb \
89 "
90
91COMPATIBLE_HOST = '(x86_64).*-linux'
92COMPATIBLE_HOST:libc-musl = "null"
93
94PACKAGECONFIG ?= "opencl samples"
95PACKAGECONFIG[opencl] = "-DENABLE_INTEL_GPU=TRUE, -DENABLE_INTEL_GPU=FALSE, virtual/opencl-icd opencl-headers opencl-clhpp,"
96PACKAGECONFIG[python3] = "-DENABLE_PYTHON=ON -DPYTHON_LIBRARY=${PYTHON_LIBRARY} -DPYTHON_INCLUDE_DIR=${PYTHON_INCLUDE_DIR} -DENABLE_PYTHON_PACKAGING=ON, -DENABLE_PYTHON=OFF, patchelf-native, python3 python3-numpy python3-progress"
97PACKAGECONFIG[samples] = "-DENABLE_SAMPLES=ON -DENABLE_COMPILE_TOOL=ON, -DENABLE_SAMPLES=OFF -DENABLE_COMPILE_TOOL=OFF, opencv"
98PACKAGECONFIG[verbose] = "-DVERBOSE_BUILD=1,-DVERBOSE_BUILD=0"
99
100do_configure:prepend() {
101 # Dont set PROJECT_ROOT_DIR
102 sed -i -e 's:\${OpenVINO_SOURCE_DIR}::;' ${S}/src/CMakeLists.txt
103
104 # qemu wrapper that can be used by cmake to run target binaries.
105 qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
106 cat > ${WORKDIR}/qemuwrapper << EOF
107#!/bin/sh
108$qemu_binary "\$@"
109EOF
110 chmod +x ${WORKDIR}/qemuwrapper
111}
112
113do_install:append() {
114 rm -rf ${D}${prefix}/install_dependencies
115 rm -rf ${D}${prefix}/setupvars.sh
116
117 find ${B}/src/plugins/intel_cpu/cross-compiled/ -type f -name *_disp.cpp -exec sed -i -e 's%'"${S}"'%'"${TARGET_DBGSRC_DIR}"'%g' {} +
118}
119
120# Otherwise e.g. ros-openvino-toolkit-dynamic-vino-sample when using dldt-inference-engine uses dldt-inference-engine WORKDIR
121# instead of RSS
122SSTATE_SCAN_FILES:append = " *.cmake"
123
124FILES:${PN} += "\
125 ${libdir}/openvino-${PV}/lib*${SOLIBSDEV} \
126 ${libdir}/openvino-${PV}/plugins.xml \
127 ${libdir}/openvino-${PV}/cache.json \
128 "
129
130# Move inference engine samples into a separate package
131PACKAGES =+ "${PN}-samples"
132
133FILES:${PN}-samples = "${datadir}/openvino \
134 ${bindir} \
135 ${libdir}/libformat_reader.a \
136 ${libdir}/libopencv_c_wrapper.a \
137 "
138
139RDEPENDS:${PN}-samples += "python3-core"
140
141# Package for inference engine python API
142PACKAGES =+ "${PN}-python3"
143
144FILES:${PN}-python3 = "${PYTHON_SITEPACKAGES_DIR}"
145
146UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>(\d+\.\d+\.\d+))$"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2025-07-01 17:03:34 +0000