summaryrefslogtreecommitdiffstats
path: root/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2022.1.bb
diff options
context:
space:
mode:
Diffstat (limited to 'dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2022.1.bb')
-rw-r--r--dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2022.1.bb141
1 files changed, 0 insertions, 141 deletions
diff --git a/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2022.1.bb b/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2022.1.bb
deleted file mode 100644
index 5814380d..00000000
--- a/dynamic-layers/openembedded-layer/recipes-support/opencv/openvino-inference-engine_2022.1.bb
+++ /dev/null
@@ -1,141 +0,0 @@
1SUMMARY = "OpenVINO(TM) Toolkit - Deep Learning Deployment Toolkit"
2HOMEPAGE = "https://github.com/opencv/dldt"
3DESCRIPTION = "This toolkit allows developers to deploy pre-trained \
4deep learning models through a high-level C++ Inference Engine API \
5integrated with application logic."
6
7SRC_URI = "git://github.com/openvinotoolkit/openvino.git;protocol=https;branch=releases/2022/1;lfs=0 \
8 https://download.01.org/opencv/master/openvinotoolkit/thirdparty/unified/VPU/usb-ma2x8x/firmware_usb-ma2x8x_1875.zip;name=usb_ma2x8x \
9 https://download.01.org/opencv/master/openvinotoolkit/thirdparty/unified/VPU/pcie-ma2x8x/firmware_pcie-ma2x8x_1875.zip;name=pcie_ma2x8x \
10 git://github.com/openvinotoolkit/oneDNN.git;protocol=https;destsuffix=git/src/plugins/intel_cpu/thirdparty/mkl-dnn;name=mkl;nobranch=1 \
11 git://github.com/oneapi-src/oneDNN.git;protocol=https;destsuffix=git/src/plugins/intel_gpu/thirdparty/onednn_gpu;name=onednn;branch=master \
12 git://github.com/herumi/xbyak.git;protocol=https;destsuffix=git/thirdparty/xbyak;name=xbyak;branch=master \
13 git://github.com/pybind/pybind11.git;protocol=https;destsuffix=git/src/bindings/python/thirdparty/pybind11;name=pybind11;branch=master \
14 git://github.com/protocolbuffers/protobuf.git;protocol=https;destsuffix=git/thirdparty/protobuf/protobuf;name=protobuf;branch=3.18.x \
15 git://github.com/nlohmann/json.git;protocol=https;destsuffix=git/thirdparty/json/nlohmann_json;name=json;branch=master \
16 git://github.com/pboettch/json-schema-validator.git;protocol=https;destsuffix=git/thirdparty/json/nlohmann_json_schema_validator;name=jsonschema;branch=main \
17 git://github.com/openvinotoolkit/open_model_zoo.git;protocol=https;destsuffix=git/thirdparty/open_model_zoo;name=omz;branch=releases/2022/1 \
18 file://0001-inference-engine-use-system-installed-packages.patch \
19 file://0002-inference-engine-installation-fixes.patch \
20 "
21
22SRCREV = "cdb9bec7210f8c24fde3e416c7ada820faaaa23e"
23SRCREV_mkl = "82ca2f931c1d588b67d154d873136d4af1ffb3a8"
24SRCREV_onednn = "9e2bf22e51726ad36ddae90c7caf2898d124baa6"
25SRCREV_xbyak = "8d1e41b650890080fb77548372b6236bbd4079f9"
26SRCREV_pybind11 = "d71ba0cb73616c493d35699a8a9283aa64ef0f6b"
27SRCREV_protobuf = "6c6b0778b70f35f93c2f0dee30e5d12ad2a83eea"
28SRCREV_json = "fec56a1a16c6e1c1b1f4e116a20e79398282626c"
29SRCREV_jsonschema = "b1ef8628326cf0b53612f12784fd245e5e4382f1"
30SRCREV_omz = "cf9003a95ddb742aabea341aa1573c3fa25ebbe1"
31
32SRC_URI[usb_ma2x8x.sha256sum] = "e65fcc1c6b0f3e9d814e53022c212ec0a2b83197a9df38badb298fb85ccf3acf"
33SRC_URI[pcie_ma2x8x.sha256sum] = "b11368fec2036d96fb703d2a40b171184fefe89f27e74a988ef1ca34260a2bc5"
34
35LICENSE = "Apache-2.0 & MIT & BSD-3-Clause"
36LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
37 file://thirdparty/xbyak/COPYRIGHT;md5=03532861dad9003cc2c17f14fc7a4efa \
38 file://thirdparty/cnpy/LICENSE;md5=689f10b06d1ca2d4b1057e67b16cd580 \
39 file://thirdparty/protobuf/protobuf/LICENSE;md5=37b5762e07f0af8c74ce80a8bda4266b \
40 file://thirdparty/json/nlohmann_json/LICENSE.MIT;md5=441793d25a658d58d79a1f87516a6ad1 \
41 file://thirdparty/json/nlohmann_json_schema_validator/LICENSE;md5=c441d022da1b1663c70181a32225d006 \
42 file://thirdparty/open_model_zoo/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
43 file://src/plugins/intel_cpu/thirdparty/mkl-dnn/LICENSE;md5=b48e3de3bfd47c27882a0d85b20823f5 \
44 file://src/plugins/intel_gpu/thirdparty/onednn_gpu/LICENSE;md5=b48e3de3bfd47c27882a0d85b20823f5 \
45 file://src/bindings/python/thirdparty/pybind11/LICENSE;md5=774f65abd8a7fe3124be2cdf766cd06f \
46"
47
48inherit cmake python3native
49
50S = "${WORKDIR}/git"
51EXTRA_OECMAKE += " \
52 -DENABLE_OPENCV=OFF \
53 -DOpenCV_DIR=${STAGING_LIBDIR}/cmake \
54 -DENABLE_PLUGIN_RPATH=0 \
55 -DENABLE_INTEL_GNA=OFF \
56 -DPYTHON_EXECUTABLE=${PYTHON} \
57 -DCMAKE_BUILD_TYPE=RelWithDebInfo \
58 -DTHREADING=TBB -DTBB_DIR="${STAGING_LIBDIR}/cmake/TBB" \
59 -DENABLE_SAMPLES=ON \
60 -DTREAT_WARNING_AS_ERROR=FALSE \
61 -DENABLE_DATA=FALSE \
62 -DENABLE_SYSTEM_PUGIXML=TRUE \
63 -DENABLE_SYSTEM_PROTOBUF=TRUE \
64 -DProtobuf_LIBRARIES=protobuf \
65 -DProtobuf_LITE_LIBRARIES=protobuf-lite \
66 -DProtobuf_INCLUDE_DIR=${STAGING_INCDIR} \
67 -DSYSTEM_PROTOC=${STAGING_BINDIR_NATIVE}/protoc \
68 -DENABLE_OV_ONNX_FRONTEND=FALSE \
69 -DUSE_BUILD_TYPE_SUBFOLDER=OFF \
70 "
71
72DEPENDS += "libusb1 \
73 ade \
74 opencv \
75 pugixml \
76 protobuf \
77 protobuf-native \
78 tbb \
79 zlib \
80 "
81
82COMPATIBLE_HOST = '(x86_64).*-linux'
83COMPATIBLE_HOST:libc-musl = "null"
84
85#Disable opencl temporarily. intel-compute-runtime depends on
86#intel-graphics-compiler and vc-intrinsics and these two recipes fail to
87#compile with LLVM13. Enable it after upstream has fixed it.
88#PACKAGECONFIG ?= "vpu opencl"
89PACKAGECONFIG ?= "vpu"
90PACKAGECONFIG[opencl] = "-DENABLE_INTEL_GPU=TRUE -DOpenCL_INCLUDE_DIR=${STAGING_INCDIR} -DOpenCL_LIBRARY=${STAGING_LIBDIR}/libOpenCL.so, -DENABLE_INTEL_GPU=FALSE, ocl-icd opencl-headers opencl-clhpp libva,"
91PACKAGECONFIG[python3] = "-DENABLE_PYTHON=ON -DPYTHON_LIBRARY=${PYTHON_LIBRARY} -DPYTHON_INCLUDE_DIR=${PYTHON_INCLUDE_DIR}, -DENABLE_PYTHON=OFF, python3-cython-native patchelf-native, python3 python3-numpy python3-opencv python3-progress python3-cython"
92PACKAGECONFIG[vpu] = "-DENABLE_INTEL_MYRIAD=ON -DVPU_FIRMWARE_USB-MA2X8X_FILE=../mvnc/usb-ma2x8x.mvcmd -DVPU_FIRMWARE_PCIE-MA2X8X_FILE=../mvnc/pcie-ma2x8x.mvcmd,-DENABLE_INTEL_MYRIAD=OFF,,${PN}-vpu-firmware"
93PACKAGECONFIG[verbose] = "-DVERBOSE_BUILD=1,-DVERBOSE_BUILD=0"
94
95do_install:append() {
96 if ${@bb.utils.contains('PACKAGECONFIG', 'python3', 'true', 'false', d)}; then
97 install -d ${D}${datadir}/openvino
98 mv ${D}/usr/samples/python ${D}${datadir}/openvino/
99
100 install -d ${D}${PYTHON_SITEPACKAGES_DIR}
101 mv ${D}${prefix}/python/${PYTHON_DIR}/openvino ${D}${PYTHON_SITEPACKAGES_DIR}/
102 mv ${D}${prefix}/python/${PYTHON_DIR}/ngraph ${D}${PYTHON_SITEPACKAGES_DIR}/
103
104 rm -rf ${D}${prefix}/python
105 fi
106
107 rm -rf ${D}${prefix}/deployment_tools
108
109 # Remove the samples source directory. We install the built samples.
110 rm -rf ${D}/usr/samples
111}
112
113# Otherwise e.g. ros-openvino-toolkit-dynamic-vino-sample when using dldt-inference-engine uses dldt-inference-engine WORKDIR
114# instead of RSS
115SSTATE_SCAN_FILES:append = " *.cmake"
116
117FILES:${PN}-dev = "${includedir} \
118 ${libdir}/cmake \
119 "
120
121FILES:${PN} += "${libdir}/lib*${SOLIBSDEV} \
122 ${datadir}/openvino \
123 ${libdir}/custom_kernels \
124 ${libdir}/plugins.xml \
125 ${libdir}/cache.json \
126 "
127
128# Move inference engine samples into a separate package
129PACKAGES =+ "${PN}-samples ${PN}-vpu-firmware"
130
131FILES:${PN}-samples = "${datadir}/openvino \
132 ${bindir} \
133 "
134FILES:${PN}-vpu-firmware += "${libdir}/*.mvcmd"
135
136# Package for inference engine python API
137PACKAGES =+ "${PN}-${PYTHON_PN}"
138
139FILES:${PN}-${PYTHON_PN} = "${PYTHON_SITEPACKAGES_DIR}"
140
141UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>(\d+(\.\d+)+))"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-05-05 02:05:37 +0000