1 files changed, 54 insertions, 0 deletions

diff --git a/dynamic-layers/openembedded-layer/recipes-support/opencv/open-model-zoo_2024.0.0.bb b/dynamic-layers/openembedded-layer/recipes-support/opencv/open-model-zoo_2024.0.0.bb
new file mode 100644
index 00000000..495a4786
--- /dev/null
+++ b/dynamic-layers/openembedded-layer/recipes-support/opencv/open-model-zoo_2024.0.0.bb
@@ -0,0 +1,54 @@
+SUMMARY = "OpenVINO(TM) Toolkit - Open Model Zoo repository"
+HOMEPAGE = "https://github.com/opencv/open_model_zoo"
+DESCRIPTION = "This repository includes optimized deep learning \
+models and a set of demos to expedite development of high-performance \
+deep learning inference applications."
+
+SRC_URI = "git://github.com/opencv/open_model_zoo.git;protocol=https;branch=master \
+           file://0001-use-oe-gflags.patch \
+           "
+
+SRCREV = "37f60eb7fe1dcdedc552b2fb184d646723ed5e80"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
+"
+
+inherit cmake
+
+S = "${WORKDIR}/git"
+OECMAKE_SOURCEPATH = "${S}/demos"
+
+DEPENDS += "openvino-inference-engine opencv gflags"
+
+RDEPENDS:${PN} += " \
+                   python3-decorator \
+                   python3-defusedxml \
+                   python3-networkx \
+                   python3-protobuf \
+                   python3-requests \
+                   python3-pyyaml \
+                   python3-numpy \
+                   bash \
+"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST:libc-musl = "null"
+
+EXTRA_OECMAKE += " \
+                 -DENABLE_SAMPLES=ON \
+                 "
+
+do_install(){
+        install -d ${D}${libdir}
+        install -d ${D}${bindir}
+        install -d ${D}${datadir}/openvino/open-model-zoo/tools
+        install -d ${D}${datadir}/openvino/open-model-zoo/demos
+        cp -rf ${WORKDIR}/build/intel64/Release/*.a ${D}${libdir}
+        cp -rf ${WORKDIR}/build/intel64/Release/*_demo* ${D}${bindir}
+        cp -rf ${WORKDIR}/git/models ${D}${datadir}/openvino/open-model-zoo
+        cp -rf ${WORKDIR}/git/demos ${D}${datadir}/openvino/open-model-zoo
+        cp -rf ${WORKDIR}/git/tools/model_tools ${D}${datadir}/openvino/open-model-zoo/tools
+}
+
+FILES:${PN} += "${datadir}/openvino"