onevpl: upgrade 2021.6.0 -> 2022.0.3

New in This Release
===================
* Updated mfxvideo++.h to remove deprecation warnings
* Sample* tools select oneVPL 2.x APIs by default
* Sample* tool update to support new GPU features
* Updates to C++ & Python previews:
* AV1 extension buffer support
* new property interface
* Targets Python 3.7
* Updated documentation and build for OpenVINO interop sample
* The libmfx.dll and libmfx.so.2021.1.11 libraries, that had been renamed to libvpl.* have been removed

Release notes:
https://github.com/oneapi-src/oneVPL/releases/tag/v2022.0.0

Signed-off-by: Yew, Chang Ching <chang.ching.yew@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 43 insertions, 0 deletions

diff --git a/recipes-multimedia/onevpl/onevpl_2022.0.3.bb b/recipes-multimedia/onevpl/onevpl_2022.0.3.bb
new file mode 100644
index 00000000..1de48ee6
--- /dev/null
+++ b/recipes-multimedia/onevpl/onevpl_2022.0.3.bb
@@ -0,0 +1,43 @@
+SUMMARY = "oneAPI Video Processing Library"
+DESCRIPTION = "The oneAPI Video Processing Library (oneVPL) provides \
+a single video processing API for encode, decode, and video processing \
+that works across a wide range of accelerators."
+
+HOMEPAGE = "https://github.com/oneapi-src/oneVPL"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c18ea6bb4786a26bf4eee88a7424a408 \
+                    file://third-party-programs.txt;md5=43ed11c52f754dafaa62e2cfdd2bac13"
+
+SRC_URI = "git://github.com/oneapi-src/oneVPL.git;protocol=https;branch=master \
+            file://0001-Fix-basename-build-issue-with-musl_libc.patch \
+            file://0001-samples-Addin-wayland-scanner-auto-generate-on-cmake.patch \
+            file://0002-sample_misc-Addin-basic-wayland-dmabuf-support.patch \
+            file://0003-sample_misc-use-wayland-dmabuf-to-render-nv12.patch \
+            "
+SRCREV = "efc259f8b7ee5c334bca1a904a503186038bbbdd"
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "libva pkgconfig-native"
+
+PACKAGECONFIG ??= "tools"
+PACKAGECONFIG[tools] = "-DBUILD_TOOLS=ON, -DBUILD_TOOLS=OFF, wayland wayland-native wayland-protocols"
+
+do_install:append() {
+        mkdir -p ${D}${datadir}/oneVPL/samples
+        mv ${D}${bindir}/sample_* ${D}${datadir}/oneVPL/samples
+}
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+
+PACKAGES += "${PN}-examples"
+
+FILES:${PN}-examples = "${datadir}/oneVPL/examples \
+                       "
+
+FILES_SOLIBSDEV = ""
+FILES:${PN}-dev += "${libdir}/libvpl.so"
+
+FILES:${PN} += "${datadir} \
+                ${libdir}/oneVPL/libvpl_wayland.so \
+                "