intel-vaapi-driver: 2.2.0 -> 2.3.0

Changes from release notes:

 Bump version to 2.3.0
 Add new PCI ID for KBL and CFL
 Fix frame corruption when there are big MVs in VP8 encoding
 Fix dynamically bitrate resetting in AVC encoding
 Fix build errors when the toolchain doesn't support -fstack-protector
 Fix memory leak issue
 Make sure the achieved bitrate meet the requirement for VP8 encoding
 Optimize VPP on GEN8

Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 33 insertions, 0 deletions

diff --git a/recipes-multimedia/libva/intel-vaapi-driver_2.3.0.bb b/recipes-multimedia/libva/intel-vaapi-driver_2.3.0.bb
new file mode 100644
index 00000000..6ec1745b
--- /dev/null
+++ b/recipes-multimedia/libva/intel-vaapi-driver_2.3.0.bb
@@ -0,0 +1,33 @@
+SUMMARY = "VA driver for Intel G45 & HD Graphics family"
+DESCRIPTION = "intel-vaapi-driver is the VA-API implementation \
+for Intel G45 chipsets and Intel HD Graphics for Intel Core \
+processor family."
+
+HOMEPAGE = "https://github.com/intel/intel-vaapi-driver"
+BUGTRACKER = "https://github.com/intel/intel-vaapi-driver/issues"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=2e48940f94acb0af582e5ef03537800f"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+DEPENDS = "libva libdrm"
+
+SRC_URI = "https://github.com/intel/${BPN}/releases/download/${PV}/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "9d835d1a3f7a9ef394f0f4c348cd4b3e"
+SRC_URI[sha256sum] = "5c2e5deab024a0a6ae81dfe77ef455542a88d824eda7bfd07684337407ecdfe3"
+
+UPSTREAM_CHECK_URI = "https://github.com/intel/intel-vaapi-driver/releases"
+
+inherit autotools pkgconfig distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "x11", "x11", "", d)} \
+                   ${@bb.utils.contains("DISTRO_FEATURES", "opengl wayland", "wayland", "", d)}"
+PACKAGECONFIG[x11] = "--enable-x11,--disable-x11"
+PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland wayland-native virtual/egl"
+
+FILES_${PN} += "${libdir}/dri/*.so"
+FILES_${PN}-dev += "${libdir}/dri/*.la"
+FILES_${PN}-dbg += "${libdir}/dri/.debug"