intel-gpu-tools: upgrade to 1.21

* Remove the backported patch
* libunwind is a hard dependency now
* Point the SRC_URI to xz file since i-g-t doesn't have the default format tarball.

Part of Intel graphics stack 2017Q4.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
Signed-off-by: California Sullivan <california.l.sullivan@intel.com>

1 files changed, 39 insertions, 0 deletions

diff --git a/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.21.bb b/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.21.bb
new file mode 100644
index 00000000..962f228f
--- /dev/null
+++ b/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.21.bb
@@ -0,0 +1,39 @@
+require ${COREBASE}/meta/recipes-graphics/xorg-app/xorg-app-common.inc
+
+SUMMARY = "Intel GPU tools"
+DESCRIPTION = "Variety of small tools for testing intel graphics."
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4b3dd344780e0400593b21b115a6947"
+
+LICENSE_append = " & ISC"
+
+inherit autotools gtk-doc
+
+SRC_URI = "${XORG_MIRROR}/individual/app/${BP}.tar.xz"
+
+DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 libxv libx11 libxext libxrandr procps libunwind"
+RDEPENDS_${PN} += "bash"
+RDEPENDS_${PN}-tests += "bash"
+
+PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
+
+SRC_URI[md5sum] = "94125e46d528b67b060ba98f3c2e3bee"
+SRC_URI[sha256sum] = "d9af6e7a24cb22e5b6ff8db03a0e6b230f08c17908cedee59e8795d74e18703f"
+
+EXTRA_OECONF = "--disable-nouveau --disable-shader-debugger"
+COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
+COMPATIBLE_HOST_libc-musl_class-target = "null"
+
+gputools_sysroot_preprocess() {
+        rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
+}
+SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
+
+FILES_${PN} += "${libdir}/intel_aubdump.so"
+FILES_${PN}-benchmarks += "${libexecdir}/intel-gpu-tools/benchmarks"
+FILES_${PN}-tests += "\
+                ${libexecdir}/intel-gpu-tools/*\
+                ${datadir}/intel-gpu-tools/1080p-right.png\
+                ${datadir}/intel-gpu-tools/1080p-left.png\
+                ${datadir}/intel-gpu-tools/pass.png\
+                ${datadir}/intel-gpu-tools/test-list.txt"