intel-microcode: upgrade 20210216 -> 20210608

Release notes:
https://github.com/intel/Intel-Linux-Processor-Microcode-Data-Files/releases/tag/microcode-20210608

Fixes CVE-2021-24489, CVE-2020-24511, CVE-2020-24512, CVE-2020-24513.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 0 insertions, 68 deletions

diff --git a/recipes-core/microcode/intel-microcode_20210216.bb b/recipes-core/microcode/intel-microcode_20210216.bb
deleted file mode 100644
index 69c8f08c..00000000
--- a/recipes-core/microcode/intel-microcode_20210216.bb
+++ /dev/null
@@ -1,68 +0,0 @@
-SUMMARY = "Intel Processor Microcode Datafile for Linux"
-HOMEPAGE = "http://www.intel.com/"
-DESCRIPTION = "The microcode data file contains the latest microcode\
- definitions for all Intel processors. Intel releases microcode updates\
- to correct processor behavior as documented in the respective processor\
- specification updates. While the regular approach to getting this microcode\
- update is via a BIOS upgrade, Intel realizes that this can be an\
- administrative hassle. The Linux operating system and VMware ESX\
- products have a mechanism to update the microcode after booting.\
- For example, this file will be used by the operating system mechanism\
- if the file is placed in the /etc/firmware directory of the Linux system."
-
-LICENSE = "Intel-Microcode-License"
-LIC_FILES_CHKSUM = "file://license;md5=d8405101ec6e90c1d84b082b0c40c721"
-
-SRC_URI = "git://github.com/intel/Intel-Linux-Processor-Microcode-Data-Files.git;protocol=https;branch=main \
-           "
-
-SRCREV = "4c5f3fdcc7f5d2b6c1bcc11001ed58923db481ab"
-
-DEPENDS = "iucode-tool-native"
-S = "${WORKDIR}/git"
-
-COMPATIBLE_HOST = "(i.86|x86_64).*-linux"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-
-inherit deploy
-
-# Use any of the iucode_tool parameters to filter specific microcodes from the data file
-# For further information, check the iucode-tool's manpage : http://manned.org/iucode-tool
-UCODE_FILTER_PARAMETERS ?= ""
-
-do_compile() {
-        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
-                ${UCODE_FILTER_PARAMETERS} \
-                --overwrite \
-                --write-to=${WORKDIR}/microcode_${PV}.bin \
-                ${S}/intel-ucode/* ${S}/intel-ucode-with-caveats/*
-
-        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
-                ${UCODE_FILTER_PARAMETERS} \
-                --overwrite \
-                --write-earlyfw=${WORKDIR}/microcode_${PV}.cpio \
-                ${S}/intel-ucode/* ${S}/intel-ucode-with-caveats/*
-}
-
-do_install() {
-        install -d ${D}${nonarch_base_libdir}/firmware/intel-ucode/
-        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
-        --write-firmware=${D}${nonarch_base_libdir}/firmware/intel-ucode \
-        ${S}/intel-ucode/* ${S}/intel-ucode-with-caveats/*
-}
-
-do_deploy() {
-        install -d ${DEPLOYDIR}
-        install ${WORKDIR}/microcode_${PV}.cpio ${DEPLOYDIR}/
-        cd ${DEPLOYDIR}
-        rm -f microcode.cpio
-        ln -sf microcode_${PV}.cpio microcode.cpio
-}
-
-addtask deploy before do_build after do_compile
-
-PACKAGES = "${PN}"
-
-FILES_${PN} = "${nonarch_base_libdir}"
-
-UPSTREAM_CHECK_GITTAGREGEX = "^microcode-(?P<pver>(\d+)[a-z]*)$"