thermald: 1.7.2 -> 1.8

Changes from release notes:

- Support of KBL-G with discrete GPU
- Fast removal of any cooling action which was applied once
temperature is normal
- Android support
- Add Hot trip point, which when reached just calls "suspend"
- Adding new tag "DependsOn" which enable/disable trip based on some other trip
- Polling interval can be configured via thermal xml config
- Per trip PID control
- Simplify RAPL cooling device

Also remove upstreamed patches and add a change to fix build failures.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 35 insertions, 0 deletions

diff --git a/recipes-bsp/thermald/thermald_1.8.bb b/recipes-bsp/thermald/thermald_1.8.bb
new file mode 100644
index 00000000..f7725f31
--- /dev/null
+++ b/recipes-bsp/thermald/thermald_1.8.bb
@@ -0,0 +1,35 @@
+SUMMARY = "Linux thermal daemon"
+
+DESCRIPTION = "Thermal Daemon is a Linux daemon used to prevent the \
+overheating of platforms. This daemon monitors temperature and applies \
+compensation using available cooling methods."
+
+HOMEPAGE = "https://github.com/01org/thermal_daemon"
+
+DEPENDS = "dbus dbus-glib dbus-glib-native libxml2 glib-2.0 glib-2.0-native"
+DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES','systemd','systemd','',d)}"
+DEPENDS_append_libc-musl = " argp-standalone"
+DEPENDS_append_toolchain-clang = " openmp"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ea8831610e926e2e469075b52bf08848"
+
+SRC_URI = "git://github.com/intel/thermal_daemon/ \
+           file://0001-Use-correct-format-specifier-for-size_t.patch \
+           "
+SRCREV = "517c0e5f92d49aeeef3a22b04caf40d588216827"
+S = "${WORKDIR}/git"
+
+inherit pkgconfig autotools systemd
+
+FILES_${PN} += "${datadir}/dbus-1/system-services/*.service"
+
+SYSTEMD_SERVICE_${PN} = "thermald.service"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+CONFFILES_${PN} = " \
+                   ${sysconfdir}/thermald/thermal-conf.xml \
+                   ${sysconfdir}/thermald/thermal-cpu-cdev-order.xml \
+                  "
+
+UPSTREAM_CHECK_URI = "https://github.com/01org/thermal_daemon/releases"