level-zero: upgrade 1.2.3 -> 1.4.1

Release notes:
https://github.com/oneapi-src/level-zero/releases

Highlights:
-    Added support for Level Zero Specification v1.2
-    Fixed a bug that resulted in zeInit failing when multiple drivers
     are discovered and one of them fails to load.
-    Note: API's introduced in v1.2 spec can only be traced with the new
     tracing layer implementation. Driver tracing APIs are deprecated.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 31 insertions, 0 deletions

diff --git a/dynamic-layers/openembedded-layer/recipes-core/levelzero/level-zero_1.4.1.bb b/dynamic-layers/openembedded-layer/recipes-core/levelzero/level-zero_1.4.1.bb
new file mode 100644
index 00000000..67f1d6c5
--- /dev/null
+++ b/dynamic-layers/openembedded-layer/recipes-core/levelzero/level-zero_1.4.1.bb
@@ -0,0 +1,31 @@
+SUMMARY = "oneAPI Level Zero Specification Headers and Loader"
+HOMEPAGE = "https://github.com/oneapi-src/level-zero"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8956dfdba7f8169c4005d1e9753ffddc"
+
+SRC_URI = "git://github.com/oneapi-src/level-zero.git;protocol=https"
+SRCREV = "551dd5810a3cea7a7e26ac4441da31878e804b53"
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "opencl-headers"
+
+UPSTREAM_CHECK_GITTAGREGEX = "^v(?P<pver>(\d+(\.\d+)+))$"
+
+PACKAGES =+ "${PN}-headers ${PN}-samples ${PN}-loader"
+
+do_install:append () {
+        install -d ${D}${bindir} ${D}${libdir}
+        install -m 755 ${B}/bin/zello* ${D}${bindir}
+
+        oe_libinstall -C lib libze_null ${D}${libdir}
+}
+
+
+FILES:${PN}-headers = "${includedir}"
+FILES:${PN}-samples = "${bindir} ${libdir}/libze_null* ${libdir}/libze_validation*"
+FILES:${PN}-loader = "${libdir}"
+
+# PN-loader (non -dev/-dbg/nativesdk- package) contains symlink .so
+INSANE_SKIP:${PN}-loader = "dev-so"
+INSANE_SKIP:${PN}-samples = "dev-so"