opencl-clang: upgrade 8.0.1 -> 9.0.0

With this upgrade, by default -DPREFERRED_LLVM_VERSION="9.0.0" is set.

Changes can be check here:
https://github.com/intel/opencl-clang

Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 37 insertions, 0 deletions

diff --git a/dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_9.0.0.bb b/dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_9.0.0.bb
new file mode 100644
index 00000000..e4209234
--- /dev/null
+++ b/dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_9.0.0.bb
@@ -0,0 +1,37 @@
+SUMMARY = "Common clang is a thin wrapper library around clang"
+DESCRIPTION = "Common clang has OpenCL-oriented API and is capable \
+ to compile OpenCL C kernels to SPIR-V modules."
+
+LICENSE = "NCSA"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e8a15bf1416762a09ece07e44c79118c"
+
+SRC_URI = "git://github.com/intel/opencl-clang.git;branch=ocl-open-90;protocol=https \
+           file://point-to-correct-llvm-tblgen.patch \
+           "
+
+SRCREV = "6f8c329bea44321aef1a1716dd206c1f7bed23cf"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "clang"
+
+DEPENDS_append_class-target = " opencl-clang-native"
+LDFLAGS_append_class-native = " -fuse-ld=lld"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST_libc-musl = "null"
+
+EXTRA_OECMAKE += "\
+                  -DLLVM_TABLEGEN_EXE=${STAGING_BINDIR_NATIVE}/llvm-tblgen \
+                  -DCMAKE_SKIP_RPATH=TRUE \
+                  "
+
+do_install_append_class-native() {
+        install -d ${D}${bindir}
+        install -m 0755 ${B}/linux_linker/linux_resource_linker ${D}${bindir}/
+}
+
+BBCLASSEXTEND = "native nativesdk"
+
+TOOLCHAIN_class-native = "clang"