opencl-clang: move to a separate recipe

Since this is managed as a separate repository, build it as a separate
component instead of bundling with LLVM/clang.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 35 insertions, 0 deletions

diff --git a/dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_8.0.0.bb b/dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_8.0.0.bb
new file mode 100644
index 00000000..6599c9b6
--- /dev/null
+++ b/dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_8.0.0.bb
@@ -0,0 +1,35 @@
+SUMMARY = "Common clang is a thin wrapper library around clang"
+DESCRIPTION = "Common clang has OpenCL-oriented API and is capable \
+ to compile OpenCL C kernels to SPIR-V modules."
+
+LICENSE = "NCSA"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e8a15bf1416762a09ece07e44c79118c"
+
+SRC_URI = "git://github.com/intel/opencl-clang.git;branch=ocl-open-80;protocol=https \
+           file://point-to-correct-llvm-tblgen.patch \
+           "
+
+SRCREV = "daf5e4dd718477ae8cf89a283c653939d9182f15"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "clang clang-native"
+
+DEPENDS_append_class-target = " opencl-clang-native"
+LDFLAGS_append_class-native = " -fuse-ld=lld"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST_libc-musl = "null"
+
+EXTRA_OECMAKE += "\
+                  -DLLVM_TABLEGEN_EXE=${STAGING_BINDIR_NATIVE}/llvm-tblgen \
+                  -DCMAKE_SKIP_RPATH=TRUE \
+                  "
+
+do_install_append_class-native() {
+        install -d ${D}${bindir}
+        install -m 0755 ${B}/linux_linker/linux_resource_linker ${D}${bindir}/
+}
+
+BBCLASSEXTEND = "native nativesdk"