linux-intel: refactor and remove iwlwifi modules for out of tree enablement

Create a linux-intel.inc that is shared between standard and rt kernel
for the common bits.

By removing these modules here, we can then build and install the
out of tree modules from the backport-iwlwifi tree.

Move the Autoloading to the kernel module also

Signed-off-by: Saul Wold <sgw@linux.intel.com>

1 files changed, 39 insertions, 0 deletions

diff --git a/common/recipes-kernel/linux/linux-intel.inc b/common/recipes-kernel/linux/linux-intel.inc
new file mode 100644
index 00000000..f3fbd59a
--- /dev/null
+++ b/common/recipes-kernel/linux/linux-intel.inc
@@ -0,0 +1,39 @@
+require recipes-kernel/linux/linux-yocto.inc
+
+SRC_URI = "git://github.com/01org/linux-intel-4.9.git;protocol=https;name=machine;branch=${KBRANCH}; \
+           git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-4.9;destsuffix=${KMETA}"
+
+
+LINUX_VERSION ?= "4.9.30"
+LINUX_VERSION_EXTENSION ?= "-intel-pk-${LINUX_KERNEL_TYPE}"
+
+PV = "${LINUX_VERSION}+git${SRCPV}"
+
+KMETA = "kernel-meta"
+KCONF_BSP_AUDIT_LEVEL = "2"
+
+KERNEL_FEATURES_INTEL_COMMON ?= ""
+
+COMPATIBLE_MACHINE_core2-32-intel-common = "${MACHINE}"
+KMACHINE_core2-32-intel-common = "intel-core2-32"
+KERNEL_FEATURES_append_core2-32-intel-common = "${KERNEL_FEATURES_INTEL_COMMON}"
+
+COMPATIBLE_MACHINE_corei7-64-intel-common = "${MACHINE}"
+KMACHINE_corei7-64-intel-common = "intel-corei7-64"
+KERNEL_FEATURES_append_corei7-64-intel-common = "${KERNEL_FEATURES_INTEL_COMMON}"
+
+COMPATIBLE_MACHINE_i586-nlp-32-intel-common = "${MACHINE}"
+KMACHINE_i586-nlp-32-intel-common = "intel-quark"
+KERNEL_FEATURES_append_i586-nlp-32-intel-common = "features/qat/qat.scc"
+
+# Functionality flags
+KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
+KERNEL_FEATURES_append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "" ,d)}"
+
+do_compile_kernelmodules_append() {
+        rm -rf ${B}/drivers/net/wireless/intel/iwlwifi
+        rm -rf ${B}/net/mac80211
+        rm -rf ${B}/net/wireless
+}
+
+RDEPENDS_kernel-modules += "iwlwifi"