intel-gpu-tools: Upgrade to version 1.18

This change updates intel-gpu-tools to 1.18 which is in Intel
graphic stack 2017 Q1 release.

Signed-off-by: Ng, Wei Tee <wei.tee.ng@intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>

1 files changed, 40 insertions, 0 deletions

diff --git a/common/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.18.bb b/common/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.18.bb
new file mode 100644
index 00000000..acdcda52
--- /dev/null
+++ b/common/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.18.bb
@@ -0,0 +1,40 @@
+require ${COREBASE}/meta/recipes-graphics/xorg-app/xorg-app-common.inc
+
+SUMMARY = "Intel GPU tools"
+DESCRIPTION = "Variety of small tools for testing intel graphics."
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4b3dd344780e0400593b21b115a6947"
+
+LICENSE_append = " & ISC"
+
+inherit autotools gtk-doc
+
+DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 libxv libx11 libxext libxrandr procps"
+RDEPENDS_${PN} += "bash"
+RDEPENDS_${PN}-tests += "bash"
+
+PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
+
+SRC_URI[md5sum] = "6a746774c80d5bcfa0aa7f9c20f72190"
+SRC_URI[sha256sum] = "df77f91b5a8bdd590f1128a36b7616bc292f18ecb98e77c9c4467574fb67e4ee"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind,libunwind"
+
+EXTRA_OECONF = "--disable-nouveau --disable-shader-debugger"
+COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
+COMPATIBLE_HOST_libc-musl_class-target = "null"
+
+gputools_sysroot_preprocess() {
+        rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
+}
+SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
+
+FILES_${PN} += "${libdir}/intel_aubdump.so"
+FILES_${PN}-benchmarks += "${libexecdir}/intel-gpu-tools/benchmarks"
+FILES_${PN}-tests += "\
+                ${libexecdir}/intel-gpu-tools/*\
+                ${datadir}/intel-gpu-tools/1080p-right.png\
+                ${datadir}/intel-gpu-tools/1080p-left.png\
+                ${datadir}/intel-gpu-tools/pass.png\
+                ${datadir}/intel-gpu-tools/test-list.txt"