intel-microcode: Update to the 20160714 version

Dates changed in Licence file required CHKSUM update

From the OpenXT Project ( http://openxt.org )
refs: OXT-668

Signed-off-by: Christopher Clark <christopher.clark6@baesystems.com>
Signed-off-by: Tom Zanussi <tom.zanussi@linux.intel.com>

1 files changed, 66 insertions, 0 deletions

diff --git a/common/recipes-core/microcode/intel-microcode_20160714.bb b/common/recipes-core/microcode/intel-microcode_20160714.bb
new file mode 100644
index 00000000..e5047ea3
--- /dev/null
+++ b/common/recipes-core/microcode/intel-microcode_20160714.bb
@@ -0,0 +1,66 @@
+SUMMARY = "Intel Processor Microcode Datafile for Linux"
+HOMEPAGE = "http://www.intel.com/"
+DESCRIPTION = "The microcode data file contains the latest microcode\
+ definitions for all Intel processors. Intel releases microcode updates\
+ to correct processor behavior as documented in the respective processor\
+ specification updates. While the regular approach to getting this microcode\
+ update is via a BIOS upgrade, Intel realizes that this can be an\
+ administrative hassle. The Linux operating system and VMware ESX\
+ products have a mechanism to update the microcode after booting.\
+ For example, this file will be used by the operating system mechanism\
+ if the file is placed in the /etc/firmware directory of the Linux system."
+
+LICENSE = "Intel-Microcode-License"
+LIC_FILES_CHKSUM = "file://microcode.dat;md5=d8c57b35388b4b9f970f5377fcdfc486"
+
+SRC_URI = "http://downloadmirror.intel.com/26156/eng/microcode-${PV}.tgz"
+SRC_URI[md5sum] = "84e4c0530dc38fd7b804daf894b1bdf9"
+SRC_URI[sha256sum] = "f3a9c6fc93275bf1febc26f7c397ac93ed5f109e47fb52932f6dbd5cfdbc840e"
+
+DEPENDS = "iucode-tool-native"
+S = "${WORKDIR}"
+
+COMPATIBLE_HOST = "(i.86|x86_64).*-linux"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+
+# Use any of the iucode_tool parameters to filter specific microcodes from the data file
+# For further information, check the iucode-tool's manpage : http://manned.org/iucode-tool
+UCODE_FILTER_PARAMETERS ?= ""
+
+do_compile() {
+        mkdir -p ${WORKDIR}/ucode/kernel/x86/microcode
+        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
+                ${UCODE_FILTER_PARAMETERS} \
+                --overwrite \
+                --write-to=${WORKDIR}/microcode_${PV}.bin \
+                ${WORKDIR}/microcode.dat
+
+        ${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
+                ${UCODE_FILTER_PARAMETERS} \
+                --overwrite \
+                --write-earlyfw=${WORKDIR}/microcode_${PV}.cpio \
+                ${WORKDIR}/microcode.dat
+}
+
+do_install() {
+        install -d ${D}${base_libdir}/firmware/intel-ucode/
+        install ${WORKDIR}/microcode_${PV}.bin ${D}${base_libdir}/firmware/intel-ucode/
+        cd ${D}${base_libdir}/firmware/intel-ucode/
+        ln -sf microcode_${PV}.bin microcode.bin
+}
+
+do_deploy() {
+        install -d ${DEPLOYDIR}
+        install ${S}/microcode_${PV}.cpio ${DEPLOYDIR}/
+        cd ${DEPLOYDIR}
+        rm -f microcode.cpio
+        ln -sf microcode_${PV}.cpio microcode.cpio
+}
+
+addtask deploy before do_build after do_compile
+
+PACKAGES = "${PN}"
+
+FILES_${PN} = "${base_libdir}"