linux-qoriq: upgrade to 4.1

The main features are:
* Linux kernel 4.1.8
* ARM A7 (AARCH32), A53 and A57 (AARCH64), Little Endian (default)
* Power Architecture e500mc, e5500, e6500
* Multicore SMP support and multithread (e6500)
* 32-bit effective kernel addressing [e500mc, e5500, A57]
* 64-bit effective addressing [e6500, A53, A57]
* Huge Pages (hugetlbfs)
* Linux Real-Time (RT) [P4080, B4860, LS1021A]
* Kernel-based Virtual Machine (KVM)
* Libvirt 1.2.19
* Linux Containers (LXC) 1.1.4 function support

Detailed commit log can be found at:
http://git.freescale.com/git/cgit.cgi/ppc/sdk/linux.git/log/?h=sdk-v2.0.x

Signed-off-by: Ting Liu <ting.liu@nxp.com>

1 files changed, 56 insertions, 0 deletions

diff --git a/recipes-kernel/linux/linux-qoriq_4.1.bb b/recipes-kernel/linux/linux-qoriq_4.1.bb
new file mode 100644
index 0000000..87eebbc
--- /dev/null
+++ b/recipes-kernel/linux/linux-qoriq_4.1.bb
@@ -0,0 +1,56 @@
+inherit kernel kernel-arch qoriq_build_64bit_kernel
+require recipes-kernel/linux/linux-dtb.inc
+
+DESCRIPTION = "Linux kernel for Freescale platforms"
+SECTION = "kernel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/linux.git;branch=sdk-v2.0.x \
+    file://modify-defconfig-t1040-nr-cpus.patch \
+    file://fix-the-compile-issue-under-gcc6.patch \
+"
+SRCREV = "bd51baffc04ecc73f933aee1c3a37c8b44b889a7"
+
+KSRC ?= ""
+S = '${@base_conditional("KSRC", "", "${WORKDIR}/git", "${KSRC}", d)}'
+
+DEPENDS_append = " libgcc"
+# not put Images into /boot of rootfs, install kernel-image if needed
+RDEPENDS_kernel-base = ""
+
+KERNEL_CC_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_LD_append = " ${TOOLCHAIN_OPTIONS}"
+
+SCMVERSION ?= "y"
+DELTA_KERNEL_DEFCONFIG ?= ""
+do_configure_prepend() {
+    # copy desired defconfig so we pick it up for the real kernel_do_configure
+    cp ${KERNEL_DEFCONFIG} ${B}/.config
+    
+    # add config fragments
+    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
+        if [ -f "${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
+        elif [ -f "${WORKDIR}/${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
+        elif [ -f "${S}/arch/${ARCH}/configs/${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config \
+                ${S}/arch/${ARCH}/configs/${deltacfg}
+        fi
+    done
+    
+    #add git revision to the local version
+    if [ "${SCMVERSION}" = "y" ]; then
+        # append sdk version if SDK_VERSION is defined
+        sdkversion=''
+        if [ -n "${SDK_VERSION}" ]; then
+            sdkversion="-${SDK_VERSION}"
+        fi
+        head=`git --git-dir=${S}/.git rev-parse --verify --short HEAD 2> /dev/null`
+        printf "%s%s%s" $sdkversion +g $head > ${B}/.scmversion
+    fi
+}
+
+# make everything compatible for the time being
+COMPATIBLE_MACHINE_$MACHINE = "$MACHINE"