qt4: Move BSP related bbappend files to dynamic layer

The Qt4 recipes are now in a specific layer, meta-qt4, so we cannot
append those recipes if the layer is not included.

This moves the bbappend files to the 'qt4-layer' collection, enabling it in
case the collection is available.

Fixes [YOCTO: #8898]

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 28 insertions, 0 deletions

diff --git a/qt4-layer/recipes-qt4/qt4/qt4-imx-support.inc b/qt4-layer/recipes-qt4/qt4/qt4-imx-support.inc
new file mode 100644
index 0000000..0efb564
--- /dev/null
+++ b/qt4-layer/recipes-qt4/qt4/qt4-imx-support.inc
@@ -0,0 +1,28 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/qt4:"
+
+python __anonymous () {
+    families = ['mx6']
+    cur_families = (d.getVar('SOC_FAMILY', True) or '').split(':')
+    if any(map(lambda x: x in cur_families,
+               families)):
+        d.appendVarFlag('do_configure', 'depends', ' virtual/kernel:do_shared_workdir')
+}
+
+SRC_URI_append_mx6 += " \
+        file://0001-Add-support-for-i.MX-codecs-to-phonon.patch \
+        file://0002-i.MX-video-renderer-Allow-v4l-device-from-environmen.patch \
+        file://0003-i.MX6-force-egl-visual-ID-33.patch \
+"
+
+DEPENDS_append_mx6 = " virtual/kernel virtual/libgles2"
+QT_GLFLAGS_mx6 = "-opengl es2 -openvg"
+QT_CONFIG_FLAGS_append_mx6 = " -I${STAGING_KERNEL_DIR}/include/uapi \
+                               -I${STAGING_KERNEL_DIR}/include/ \
+                               -DLINUX=1 -DEGL_API_FB=1 \
+                               -DQT_QPA_EXPERIMENTAL_TOUCHEVENT=1"
+
+# The QT_CONFIG_FLAGS can pollute *.la files with -Dxxx
+do_compile_append_mx6 () {
+    find lib -name "*.la" | xargs -n1 sed -i 's/-D.*=1//g'
+}
+