diff options
Diffstat (limited to 'recipes-multimedia/gstreamer/gstreamer1.0_1.22.0.imx.bb')
-rw-r--r-- | recipes-multimedia/gstreamer/gstreamer1.0_1.22.0.imx.bb | 103 |
1 files changed, 103 insertions, 0 deletions
diff --git a/recipes-multimedia/gstreamer/gstreamer1.0_1.22.0.imx.bb b/recipes-multimedia/gstreamer/gstreamer1.0_1.22.0.imx.bb new file mode 100644 index 00000000..9201246a --- /dev/null +++ b/recipes-multimedia/gstreamer/gstreamer1.0_1.22.0.imx.bb | |||
@@ -0,0 +1,103 @@ | |||
1 | # This recipe is for the i.MX fork of gstreamer1.0. For ease of | ||
2 | # maintenance, the top section is a verbatim copy of an OE-core | ||
3 | # recipe. The second section customizes the recipe for i.MX. | ||
4 | |||
5 | ########### OE-core copy ################## | ||
6 | # Upstream hash: fb2d28e0315ece6180c87c7047587673024a09f7 | ||
7 | |||
8 | SUMMARY = "GStreamer 1.0 multimedia framework" | ||
9 | DESCRIPTION = "GStreamer is a multimedia framework for encoding and decoding video and sound. \ | ||
10 | It supports a wide range of formats including mp3, ogg, avi, mpeg and quicktime." | ||
11 | HOMEPAGE = "http://gstreamer.freedesktop.org/" | ||
12 | BUGTRACKER = "https://bugzilla.gnome.org/enter_bug.cgi?product=Gstreamer" | ||
13 | SECTION = "multimedia" | ||
14 | LICENSE = "LGPL-2.1-or-later" | ||
15 | |||
16 | DEPENDS = "glib-2.0 glib-2.0-native libxml2 bison-native flex-native" | ||
17 | |||
18 | inherit meson pkgconfig gettext upstream-version-is-even gobject-introspection ptest-gnome | ||
19 | |||
20 | LIC_FILES_CHKSUM = "file://COPYING;md5=69333daa044cb77e486cc36129f7a770 \ | ||
21 | file://gst/gst.h;beginline=1;endline=21;md5=e059138481205ee2c6fc1c079c016d0d" | ||
22 | |||
23 | S = "${WORKDIR}/gstreamer-${PV}" | ||
24 | |||
25 | SRC_URI = "https://gstreamer.freedesktop.org/src/gstreamer/gstreamer-${PV}.tar.xz \ | ||
26 | file://run-ptest \ | ||
27 | file://0001-tests-respect-the-idententaion-used-in-meson.patch \ | ||
28 | file://0002-tests-add-support-for-install-the-tests.patch \ | ||
29 | file://0003-tests-use-a-dictionaries-for-environment.patch;striplevel=3 \ | ||
30 | file://0004-tests-add-helper-script-to-run-the-installed_tests.patch;striplevel=3 \ | ||
31 | " | ||
32 | SRC_URI[sha256sum] = "78d21b5469ac93edafc6d8ceb63bc82f6cbbee94d2f866cca6b9252157ee0a09" | ||
33 | |||
34 | PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)} \ | ||
35 | check \ | ||
36 | debug \ | ||
37 | tools" | ||
38 | |||
39 | PACKAGECONFIG[debug] = "-Dgst_debug=true,-Dgst_debug=false" | ||
40 | PACKAGECONFIG[tracer-hooks] = "-Dtracer_hooks=true,-Dtracer_hooks=false" | ||
41 | PACKAGECONFIG[coretracers] = "-Dcoretracers=enabled,-Dcoretracers=disabled" | ||
42 | PACKAGECONFIG[check] = "-Dcheck=enabled,-Dcheck=disabled" | ||
43 | PACKAGECONFIG[tests] = "-Dtests=enabled -Dinstalled_tests=true,-Dtests=disabled -Dinstalled_tests=false" | ||
44 | PACKAGECONFIG[unwind] = "-Dlibunwind=enabled,-Dlibunwind=disabled,libunwind" | ||
45 | PACKAGECONFIG[dw] = "-Dlibdw=enabled,-Dlibdw=disabled,elfutils" | ||
46 | PACKAGECONFIG[bash-completion] = "-Dbash-completion=enabled,-Dbash-completion=disabled,bash-completion" | ||
47 | PACKAGECONFIG[tools] = "-Dtools=enabled,-Dtools=disabled" | ||
48 | PACKAGECONFIG[setcap] = "-Dptp-helper-permissions=capabilities,,libcap libcap-native" | ||
49 | |||
50 | # TODO: put this in a gettext.bbclass patch | ||
51 | def gettext_oemeson(d): | ||
52 | if d.getVar('USE_NLS') == 'no': | ||
53 | return '-Dnls=disabled' | ||
54 | # Remove the NLS bits if USE_NLS is no or INHIBIT_DEFAULT_DEPS is set | ||
55 | if d.getVar('INHIBIT_DEFAULT_DEPS') and not oe.utils.inherits(d, 'cross-canadian'): | ||
56 | return '-Dnls=disabled' | ||
57 | return '-Dnls=enabled' | ||
58 | |||
59 | EXTRA_OEMESON += " \ | ||
60 | -Ddoc=disabled \ | ||
61 | -Dexamples=disabled \ | ||
62 | -Ddbghelp=disabled \ | ||
63 | ${@gettext_oemeson(d)} \ | ||
64 | " | ||
65 | |||
66 | GIR_MESON_ENABLE_FLAG = "enabled" | ||
67 | GIR_MESON_DISABLE_FLAG = "disabled" | ||
68 | |||
69 | PACKAGES += "${PN}-bash-completion" | ||
70 | |||
71 | # Add the core element plugins to the main package | ||
72 | FILES:${PN} += "${libdir}/gstreamer-1.0/*.so" | ||
73 | FILES:${PN}-dev += "${libdir}/gstreamer-1.0/*.a ${libdir}/gstreamer-1.0/include" | ||
74 | FILES:${PN}-bash-completion += "${datadir}/bash-completion/completions/ ${datadir}/bash-completion/helpers/gst*" | ||
75 | FILES:${PN}-dbg += "${datadir}/gdb ${datadir}/gstreamer-1.0/gdb" | ||
76 | |||
77 | CVE_PRODUCT = "gstreamer" | ||
78 | |||
79 | PTEST_BUILD_HOST_FILES = "" | ||
80 | |||
81 | ########### End of OE-core copy ########### | ||
82 | |||
83 | ########### i.MX overrides ################ | ||
84 | |||
85 | DEFAULT_PREFERENCE = "-1" | ||
86 | |||
87 | LIC_FILES_CHKSUM = " \ | ||
88 | file://LICENSE.txt;md5=69333daa044cb77e486cc36129f7a770 \ | ||
89 | file://gst/gst.h;beginline=1;endline=21;md5=e059138481205ee2c6fc1c079c016d0d \ | ||
90 | " | ||
91 | |||
92 | # Use i.MX fork of GST for customizations | ||
93 | SRC_URI:remove = "https://gstreamer.freedesktop.org/src/gstreamer/gstreamer-${PV}.tar.xz" | ||
94 | SRC_URI:prepend = "${GST1.0_SRC};branch=${SRCBRANCH} " | ||
95 | GST1.0_SRC ?= "gitsm://github.com/nxp-imx/gstreamer.git;protocol=https" | ||
96 | SRCBRANCH = "MM_04.08.00_2305_L6.1.y" | ||
97 | SRCREV = "e39d4ce54e78cb090cf4e5cd56f431c365c5b0f4" | ||
98 | |||
99 | S = "${WORKDIR}/git" | ||
100 | |||
101 | COMPATIBLE_MACHINE = "(imx-nxp-bsp)" | ||
102 | |||
103 | ########### End of i.MX overrides ######### | ||