1 files changed, 58 insertions, 0 deletions

diff --git a/conf/machine/include/imx95-evk.inc b/conf/machine/include/imx95-evk.inc
new file mode 100644
index 000000000..d78745cfc
--- /dev/null
+++ b/conf/machine/include/imx95-evk.inc
@@ -0,0 +1,58 @@
+require conf/machine/include/imx-base.inc
+require conf/machine/include/arm/armv8-2a/tune-cortexa55.inc
+
+MACHINE_FEATURES += "pci wifi bluetooth optee"
+MACHINE_FEATURES:append:use-nxp-bsp = " nxpwifi-all-pcie nxpwifi-all-sdio jailhouse dpdk xen"
+
+KERNEL_DEVICETREE = " \
+    freescale/${KERNEL_DEVICETREE_BASENAME}.dtb \
+"
+
+IMX_DEFAULT_BOOTLOADER:use-nxp-bsp = "u-boot-imx"
+IMX_DEFAULT_BOOTLOADER:use-mainline-bsp = "u-boot-fslc"
+
+LOADADDR = ""
+UBOOT_SUFFIX = "bin"
+UBOOT_MAKE_TARGET = ""
+
+SPL_BINARY = "spl/u-boot-spl.bin"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "${UBOOT_CONFIG_BASENAME}_evk_defconfig,sdcard"
+UBOOT_CONFIG[fspi] = "${UBOOT_CONFIG_BASENAME}_evk_fspi_defconfig"
+
+ATF_PLATFORM = "imx95"
+OEI_CONFIGS = "ddr tcm"
+OEI_CORE   = "m33"
+OEI_SOC    = "mx95"
+OEI_BOARD  ?= "mx95lp5"
+DDR_TYPE   ?= "lpddr5"
+
+IMXBOOT_VARIANTS = "alt jailhouse netc sof"
+
+# Multiple system manager configs by IMXBOOT_VARIANT
+SYSTEM_MANAGER_CONFIG = "${@bb.utils.contains('IMXBOOT_VARIANT', 'alt',       'mx95alt', \
+                            bb.utils.contains('IMXBOOT_VARIANT', 'jailhouse', 'mx95evkjailhouse', \
+                            bb.utils.contains('IMXBOOT_VARIANT', 'netc',      'mx95netc', \
+                            bb.utils.contains('IMXBOOT_VARIANT', 'sof',       'mx95evksof', \
+                                                                              'mx95evk', d), d), d), d)}"
+
+# imx-boot (flash.bin) targets based on UBOOT_CONFIG and IMXBOOT_VARIANT
+IMXBOOT_TARGETS_SD = "${@bb.utils.contains('IMXBOOT_VARIANT', 'alt',       '${IMXBOOT_TARGETS_BASENAME}_alt', \
+                         bb.utils.contains('IMXBOOT_VARIANT', 'jailhouse', '${IMXBOOT_TARGETS_BASENAME}_jailhouse', \
+                         bb.utils.contains('IMXBOOT_VARIANT', 'netc',      '${IMXBOOT_TARGETS_BASENAME}_netc', \
+                         bb.utils.contains('IMXBOOT_VARIANT', 'sof',       '${IMXBOOT_TARGETS_BASENAME}_a55', \
+                                                                           '${IMXBOOT_TARGETS_BASENAME}_all ${IMXBOOT_TARGETS_BASENAME}_a55', d), d), d), d)} \
+"
+
+IMXBOOT_TARGETS = " \
+    ${@bb.utils.contains('UBOOT_CONFIG', 'fspi', '${IMXBOOT_TARGETS_BASENAME}_a55_flexspi', '${IMXBOOT_TARGETS_SD}', d)} \
+"
+
+IMX_BOOT_SOC_TARGET = "iMX95"
+IMX_BOOT_SEEK = "32"
+
+# We have to disable SERIAL_CONSOLE due to auto-serial-console
+SERIAL_CONSOLES = "115200;ttyLP0"
+
+IMX_DEFAULT_BSP = "nxp"