optee-client: Add support for optee-client imx fork

This also includes some backported gcc 8 fixes from upstream.

Signed-off-by: Peter Griffin <peter.griffin@linaro.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/recipes-security/optee-imx/optee-client_3.2.0.imx.bb b/recipes-security/optee-imx/optee-client_3.2.0.imx.bb
new file mode 100644
index 00000000..2b0bcf48
--- /dev/null
+++ b/recipes-security/optee-imx/optee-client_3.2.0.imx.bb
@@ -0,0 +1,57 @@
+# Copyright (C) 2017-2018 NXP
+
+SUMMARY = "OPTEE Client libs"
+HOMEPAGE = "http://www.optee.org/"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=69663ab153298557a59c67a60a743e5b"
+
+inherit pythonnative systemd
+
+SRCBRANCH = "imx_4.14.78_1.0.0_ga"
+OPTEE_CLIENT_SRC ?= "git://source.codeaurora.org/external/imx/imx-optee-client.git;protocol=https"
+SRC_URI = "${OPTEE_CLIENT_SRC};branch=${SRCBRANCH}"
+
+SRCREV = "d06647d201520ac57f1331e97db6138d63bc2666" 
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+SRC_URI_append = " file://0001-libteec-refactor-_dprintf.patch \
+                   file://tee-supplicant.service"
+
+S = "${WORKDIR}/git"
+SYSTEMD_SERVICE_${PN} = "tee-supplicant.service"
+
+EXTRA_OEMAKE = "CFG_SECURE_DATA_PATH=y"
+
+do_compile () {
+    if [ ${DEFAULTTUNE} = "aarch64" ]; then
+        oe_runmake -C ${S} ARCH=arm64
+    else
+        oe_runmake -C ${S} ARCH=arm
+    fi
+}
+
+do_install () {
+        oe_runmake install
+
+        install -D -p -m0644 ${S}/out/export/lib/libteec.so.1.0 ${D}${libdir}/libteec.so.1.0
+        ln -sf libteec.so.1.0 ${D}${libdir}/libteec.so
+        ln -sf libteec.so.1.0 ${D}${libdir}/libteec.so.1
+
+        install -D -p -m0755 ${S}/out/export/bin/tee-supplicant ${D}${bindir}/tee-supplicant
+
+        cp -a ${S}/out/export/include ${D}/usr/
+
+        sed -i -e s:/etc:${sysconfdir}:g -e s:/usr/bin:${bindir}:g ${WORKDIR}/tee-supplicant.service
+        install -D -p -m0644 ${WORKDIR}/tee-supplicant.service ${D}${systemd_system_unitdir}/tee-supplicant.service
+}
+
+PACKAGES += "tee-supplicant"
+FILES_${PN} += "${libdir}/* ${includedir}/*"
+FILES_tee-supplicant += "${bindir}/tee-supplicant"
+
+INSANE_SKIP_${PN} = "ldflags dev-elf"
+INSANE_SKIP_${PN}-dev = "ldflags dev-elf"
+INSANE_SKIP_tee-supplicant = "ldflags"
+
+COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"